spsym_alloc.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    spsym_alloc   ../engine/source/elements/sph/spsym_alloc.F
!||--- called by ------------------------------------------------------
!||    sphprep       ../engine/source/elements/sph/sphprep.F
!||--- calls      -----------------------------------------------------
!||    my_barrier    ../engine/source/system/machine.F
!||--- uses       -----------------------------------------------------
!||    message_mod   ../engine/share/message_module/message_mod.F
!||    sphbox        ../engine/share/modules/sphbox.F
!||====================================================================
      SUBROUTINE spsym_alloc(
     1    X, ISPCOND ,ISPSYM  ,XFRAME  ,XSPSYM   ,
     2    VSPSYM  ,WSP2SORT,DMAX,ITASK   ,WSMCOMP,
     3    MYSPATRUE,SPBUF,KXSP)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE sphbox
      USE message_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "sphcom.inc"
#include      "param_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER KXSP(NISP,*),ISPSYM(NSPCOND,*),WSP2SORT(*), ITASK,
     .   ISPCOND(NISPCOND,*)
      my_real
     .   x(3,*) ,xframe(nxframe,*) ,dmax,myspatrue,spbuf(nspbuf,*)
      TYPE (SPSYM_STRUCT) :: XSPSYM,VSPSYM,WSMCOMP
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER K,N,IS,IC,NC,NS,INOD,NSPHSYM_L,IERROR
      my_real
     .       XI,YI,ZI,DI,
     .       ox,oy,oz,nx,ny,nz,
     .       dd,dm,dk,dl,spalinr
C-----------------------------------------------
C new construction of ghost particles is necessary.
       spalinr=sqrt(one + myspatrue)
 
C      NSPHSYM=0 initialise dans sphprep
       nsphsymr=0
C
C Comptage des particules symetriques pour allocation des tableaux
C
      DO nc=1,nspcond
        is=ispcond(3,nc)
        ic=ispcond(2,nc)
        ox=xframe(10,is)
        oy=xframe(11,is)
        oz=xframe(12,is)
        nx=xframe(3*(ic-1)+1,is)
        ny=xframe(3*(ic-1)+2,is)
        nz=xframe(3*(ic-1)+3,is)
C
        DO ns=1+itask,nsp2sort,nthread
         n=wsp2sort(ns)
         inod  =kxsp(3,n)
         xi =x(1,inod)
         yi =x(2,inod)
         zi =x(3,inod)
         di  =spbuf(1,n)
C DMAX : max diametre sur le domaine
         dm=di+dmax
C------
C        Recherche si condition active en X.
         dd=(xi-ox)*nx+(yi-oy)*ny+(zi-oz)*nz
         IF (dd<=spalinr*dm) THEN
#include "lockon.inc"
           nsphsym=nsphsym+1
           nsphsym_l = nsphsym
           ispsym(nc,n)= nsphsym_l
#include "lockoff.inc"
         ELSE
C          not symetrized at this time.
           ispsym(nc,n)=-1
         ENDIF
        ENDDO
C
C Particules symetriques de particules remotes
C
        DO ns = itask+1,nsphr,nthread
         xi =xsphr(3,ns)
         yi =xsphr(4,ns)
         zi =xsphr(5,ns)
         di =xsphr(2,ns)
C DMAX : max diametre sur le domaine
         dm=di+dmax
C------
C        Recherche si condition active en X.
         dd=(xi-ox)*nx+(yi-oy)*ny+(zi-oz)*nz
         IF (dd<=spalinr*dm) THEN
#include "lockon.inc"
           nsphsym=nsphsym+1
           nsphsymr=nsphsymr+1
           nsphsym_l = nsphsym
#include "lockoff.inc"
           ispsymr(nc,ns)= nsphsym_l
         ELSE
C          not symetrized at this time.
           ispsymr(nc,ns)=-1
         END IF
        END DO
      END DO
C
      CALL my_barrier
C
      IF (itask==0) THEN  
        IF(ALLOCATED(xspsym%BUF)) DEALLOCATE(xspsym%BUF)
        ALLOCATE(xspsym%BUF(3*nsphsym),stat=ierror)
        IF(ierror==0) xspsym%BUF = 0
        IF(ALLOCATED(vspsym%BUF)) DEALLOCATE(vspsym%BUF)
        ALLOCATE(vspsym%BUF(3*nsphsym),stat=ierror)
        IF(ierror==0) vspsym%BUF = 0
        IF(ALLOCATED(wsmcomp%BUF)) DEALLOCATE(wsmcomp%BUF)
        ALLOCATE(wsmcomp%BUF(6*nsphsym),stat=ierror)
        IF(ierror==0) wsmcomp%BUF = 0     
      ENDIF
C-------------------------------------------
      RETURN
      END