ssort_n4.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    ssort_n4    ../engine/source/elements/solid/solide/ssort_n4.F
!||--- called by ------------------------------------------------------
!||    sfor_n2s4   ../engine/source/elements/solid/solide/sfor_n2s4.F
!||====================================================================
      SUBROUTINE ssort_n4(XI,      YI,     ZI ,   MARGE,    
     .                     X1,     X2,      X3,      X4,
     .                     Y1,     Y2,      Y3,      Y4,
     .                     Z1,     Z2,      Z3,      Z4,
     .                   IFC1,   STIF,     NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT (IN)  :: NEL
      INTEGER, DIMENSION(MVSIZ),INTENT (INOUT) :: IFC1
      my_real, DIMENSION(MVSIZ), INTENT (IN) :: MARGE,
     .                        XI,     YI,     ZI,STIF, 
     .                        x1,     x2,      x3,      x4,
     .                        y1,     y2,      y3,      y4,
     .                        z1,     z2,      z3,      z4
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,K
C                                                                     12
      my_real
     .   RX, RY, RZ, SX, SY, SZ,NX,NY,NZ,BBB,
     .   dx,dy,dz,dd,pene(mvsiz),norm,dmin,dmin1
C----------------------------
         DO i=1,nel
           IF (ifc1(i)>0) cycle
           rx =x2(i)+x3(i)-x1(i)-x4(i)
           ry =y2(i)+y3(i)-y1(i)-y4(i)
           rz =z2(i)+z3(i)-z1(i)-z4(i)
           sx =x3(i)+x4(i)-x1(i)-x2(i)
           sy =y3(i)+y4(i)-y1(i)-y2(i)
           sz =z3(i)+z4(i)-z1(i)-z2(i)
           nx =ry*sz - rz*sy
           ny =rz*sx - rx*sz
           nz =rx*sy - ry*sx
           norm=one/max(em20,sqrt(nx*nx+ny*ny+nz*nz))
           bbb = ((x3(i)-xi(i))*nx + (y3(i)-yi(i))*ny +
     .            (z3(i)-zi(i))*nz)*norm 
           pene(i) = abs(bbb)  
           IF (pene(i)<marge(i).AND.stif(i)>zero) ifc1(i)=2
         ENDDO
C-------if degenerated quad not possible have 1=3 or 2=4
#include "vectorize.inc"
         DO i=1,nel
           IF (ifc1(i)==0) cycle
           dx =x4(i)-x3(i)
           dy =y4(i)-y3(i)
           dz =z4(i)-z3(i)
           dmin = abs(dx)+abs(dy)+abs(dz)
           IF (dmin==zero) THEN
             ifc1(i)=3
             dx =x2(i)-x1(i)
             dy =y2(i)-y1(i)
             dz =z2(i)-z1(i)
             dmin1 = abs(dx)+abs(dy)+abs(dz)
             IF (dmin1==zero) ifc1(i)=0
             cycle
           END IF
           dx =x2(i)-x1(i)
           dy =y2(i)-y1(i)
           dz =z2(i)-z1(i)
           dmin = abs(dx)+abs(dy)+abs(dz)
           IF (dmin==zero) THEN
             ifc1(i)=6
             cycle
           END IF
           dx =x4(i)-x1(i)
           dy =y4(i)-y1(i)
           dz =z4(i)-z1(i)
           dmin = abs(dx)+abs(dy)+abs(dz)
           IF (dmin==zero) THEN
             ifc1(i)=4
             dx =x3(i)-x2(i)
             dy =y3(i)-y2(i)
             dz =z3(i)-z2(i)
             dmin1 = abs(dx)+abs(dy)+abs(dz)
             IF (dmin1==zero) ifc1(i)=0
             cycle
           END IF
           dx =x3(i)-x2(i)
           dy =y3(i)-y2(i)
           dz =z3(i)-z2(i)
           dmin = abs(dx)+abs(dy)+abs(dz)
           IF (dmin==zero) THEN
             ifc1(i)=5
             cycle
           END IF
         ENDDO
C       
      RETURN
      END