agrad2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    agrad2                 ../starter/source/ale/ale2d/agrad2.F
!||--- called by ------------------------------------------------------
!||    matini                 ../starter/source/materials/mat_share/matini.F
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE agrad2(IXQ,X,ALE_CONNECTIVITY,GRAD,NEL)
C-----------------------------------------------
C   D e s c r i p t i on
C-----------------------------------------------
C This subroutine is calculating 2D gradient on faces
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE ale_connectivity_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "vect01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER,INTENT(IN) :: IXQ(7,NUMELQ),NEL
      my_real, INTENT(IN) :: x(3,numnod)
      my_real,INTENT(INOUT) :: grad(nel,4)
      TYPE(t_ale_connectivity), INTENT(INOUT) :: ALE_CONNECTIVITY
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, II, IE, IV1, IV2, IV3, IV4, IAD1
      my_real  y1(mvsiz),  y2(mvsiz),  y3(mvsiz),  y4(mvsiz),
     .         z1(mvsiz),  z2(mvsiz),  z3(mvsiz),  z4(mvsiz),
     .         yc(mvsiz),  zc(mvsiz), 
     .         n1y(mvsiz), n2y(mvsiz), n3y(mvsiz), n4y(mvsiz),
     .         n1z(mvsiz), n2z(mvsiz), n3z(mvsiz), n4z(mvsiz),
     .         dd1(mvsiz), dd2(mvsiz), dd3(mvsiz), dd4(mvsiz), 
     .         d1y(mvsiz), d2y(mvsiz), d3y(mvsiz), d4y(mvsiz),
     .         d1z(mvsiz), d2z(mvsiz), d3z(mvsiz), d4z(mvsiz)
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
 
C ---- COORDINATES -----------------------------
      DO i=lft,llt
        ii=i+nft
        
          y1(i)=x(2,ixq(2,ii))
        z1(i)=x(3,ixq(2,ii))
 
        y2(i)=x(2,ixq(3,ii))
        z2(i)=x(3,ixq(3,ii))
 
        y3(i)=x(2,ixq(4,ii))
        z3(i)=x(3,ixq(4,ii))
 
        y4(i)=x(2,ixq(5,ii))
        z4(i)=x(3,ixq(5,ii))
      END DO
 
C ---- NORMAL VECTORS ON FACES------------------
      DO i=lft,llt
        n1y(i)= (z2(i)-z1(i))
        n1z(i)=-(y2(i)-y1(i))
 
        n2y(i)= (z3(i)-z2(i))
        n2z(i)=-(y3(i)-y2(i))
 
        n3y(i)= (z4(i)-z3(i))
        n3z(i)=-(y4(i)-y3(i))
 
        n4y(i)= (z1(i)-z4(i))
        n4z(i)=-(y1(i)-y4(i))
 
        yc(i) = (y1(i)+y2(i)+y3(i)+y4(i))
        zc(i) = (z1(i)+z2(i)+z3(i)+z4(i))
      END DO
 
      IF(n2d == 1)THEN
        DO i=lft,llt
          n1y(i)= n1y(i)*(y1(i)+y2(i))*0.5
          n1z(i)= n1z(i)*(y1(i)+y2(i))*0.5
          n2y(i)= n2y(i)*(y2(i)+y3(i))*0.5
          n2z(i)= n2z(i)*(y2(i)+y3(i))*0.5
          n3y(i)= n3y(i)*(y3(i)+y4(i))*0.5
          n3z(i)= n3z(i)*(y3(i)+y4(i))*0.5
          n4y(i)= n4y(i)*(y1(i)+y4(i))*0.5
          n4z(i)= n4z(i)*(y1(i)+y4(i))*0.5
        END DO
      ENDIF
      
C ---- DISTANCES BETWEEN ELEMS (*4.)------------
      DO i=lft,llt
        ie =nft+i
        iad1 = ale_connectivity%ee_connect%iad_connect(ie)
        iv1 = ale_connectivity%ee_connect%connected(iad1 + 1 - 1)
        iv2 = ale_connectivity%ee_connect%connected(iad1 + 2 - 1)
        iv3 = ale_connectivity%ee_connect%connected(iad1 + 3 - 1)
        iv4 = ale_connectivity%ee_connect%connected(iad1 + 4 - 1)
        
        IF(iv1 <= 0) iv1=ie
        IF(iv2 <= 0) iv2=ie
        IF(iv3 <= 0) iv3=ie
        IF(iv4 <= 0) iv4=ie
 
        d1y(i) = - yc(i)+x(2,ixq(2,iv1))+x(2,ixq(3,iv1))+x(2,ixq(4,iv1))+x(2,ixq(5,iv1))
        d1z(i) = - zc(i)+x(3,ixq(2,iv1))+x(3,ixq(3,iv1))+x(3,ixq(4,iv1))+x(3,ixq(5,iv1))
 
        d2y(i) = - yc(i)+x(2,ixq(2,iv2))+x(2,ixq(3,iv2))+x(2,ixq(4,iv2))+x(2,ixq(5,iv2))
        d2z(i) = - zc(i)+x(3,ixq(2,iv2))+x(3,ixq(3,iv2))+x(3,ixq(4,iv2))+x(3,ixq(5,iv2))
 
        d3y(i) = - yc(i)+x(2,ixq(2,iv3))+x(2,ixq(3,iv3))+x(2,ixq(4,iv3))+x(2,ixq(5,iv3))
        d3z(i) = - zc(i)+x(3,ixq(2,iv3))+x(3,ixq(3,iv3))+x(3,ixq(4,iv3))+x(3,ixq(5,iv3))
 
        d4y(i) = - yc(i)+x(2,ixq(2,iv4))+x(2,ixq(3,iv4))+x(2,ixq(4,iv4))+x(2,ixq(5,iv4))
        d4z(i) = - zc(i)+x(3,ixq(2,iv4))+x(3,ixq(3,iv4))+x(3,ixq(4,iv4))+x(3,ixq(5,iv4))
      END DO
 
      DO i=lft,llt
        dd1(i)=d1y(i)**2+d1z(i)**2
        dd2(i)=d2y(i)**2+d2z(i)**2
        dd3(i)=d3y(i)**2+d3z(i)**2
        dd4(i)=d4y(i)**2+d4z(i)**2
      END DO
 
C ---- GRADIENT * SURFACE-----------------------
      DO i=lft,llt
        grad(i,1)= four*(d1y(i)*n1y(i)+d1z(i)*n1z(i)) / max(em15,dd1(i))
        grad(i,2)= four*(d2y(i)*n2y(i)+d2z(i)*n2z(i)) / max(em15,dd2(i))
        grad(i,3)= four*(d3y(i)*n3y(i)+d3z(i)*n3z(i)) / max(em15,dd3(i))
        grad(i,4)= four*(d4y(i)*n4y(i)+d4z(i)*n4z(i)) / max(em15,dd4(i))
      END DO
C-----------------------------------------------      
      RETURN
      END