srepiso3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    srepiso3   ../starter/source/elements/solid/solide/srepiso3.F
!||--- called by ------------------------------------------------------
!||    srcoor3    ../starter/source/elements/solid/solide/srcoor3.F
!||    srefsta3   ../starter/source/elements/solid/solide/srefsta3.F
!||====================================================================
      SUBROUTINE srepiso3(
     .   X1   ,X2   ,X3   ,X4   ,X5   ,X6   ,X7   ,X8   ,  
     .   Y1   ,Y2   ,Y3   ,Y4   ,Y5   ,Y6   ,Y7   ,Y8   ,  
     .   Z1   ,Z2   ,Z3   ,Z4   ,Z5   ,Z6   ,Z7   ,Z8   ,  
     .   RX   ,RY   ,RZ   ,SX   ,SY   ,SZ   ,TX   ,TY   ,
     .   TZ   ,F1X  ,F1Y  ,F1Z  ,F2X  ,F2Y  ,F2Z  )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
C     REAL
      my_real
     .   x1(*), x2(*), x3(*), x4(*), x5(*), x6(*), x7(*), x8(*),
     .   y1(*), y2(*), y3(*), y4(*), y5(*), y6(*), y7(*), y8(*),  
     .   z1(*), z2(*), z3(*), z4(*), z5(*), z6(*), z7(*), z8(*),  
     .   rx(*) ,ry(*) ,rz(*) ,sx(*) ,sy(*) ,sz(*) ,tx(*) ,ty(*) ,tz(*),
     .   f1x(*),f1y(*),f1z(*),f2x(*),f2y(*),f2z(*)
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "vect01_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real
     .   X17 , X28 , X35 , X46, Y17 , Y28 , Y35 , Y46, 
     .   Z17 , Z28 , Z35 , Z46, A17 , A28 , B17 , B28 , C17 , C28 
C=======================================================================
C     Repere isoparametrique
C
      DO i=lft,llt
        f1x(i) = x2(i)+x3(i)-x1(i)-x4(i)                                     
        f1y(i) = y2(i)+y3(i)-y1(i)-y4(i)                                     
        f1z(i) = z2(i)+z3(i)-z1(i)-z4(i)                                     
        f2x(i) = x3(i)+x4(i)-x1(i)-x2(i)                                     
        f2y(i) = y3(i)+y4(i)-y1(i)-y2(i)                                     
        f2z(i) = z3(i)+z4(i)-z1(i)-z2(i)                                     
      ENDDO
      DO i=lft,llt
        x17 = x7(i) - x1(i)
        x28 = x8(i) - x2(i)
        x35 = x5(i) - x3(i)
        x46 = x6(i) - x4(i)
        y17 = y7(i) - y1(i)
        y28 = y8(i) - y2(i)
        y35 = y5(i) - y3(i)
        y46 = y6(i) - y4(i)
        z17 = z7(i) - z1(i)
        z28 = z8(i) - z2(i)
        z35 = z5(i) - z3(i)
        z46 = z6(i) - z4(i)
C
        a17 = x17 + x46
        a28 = x28 + x35
        b17 = y17 + y46
        b28 = y28 + y35
        c17 = z17 + z46
        c28 = z28 + z35
C
        rx(i) = x17 + x28 - x35 - x46
        ry(i) = y17 + y28 - y35 - y46
        rz(i) = z17 + z28 - z35 - z46
        sx(i) = a17 + a28
        sy(i) = b17 + b28
        sz(i) = c17 + c28
        tx(i) = a17 - a28
        ty(i) = b17 - b28
        tz(i) = c17 - c28
      ENDDO
C-------------
      RETURN
      END SUBROUTINE srepiso3