q4coor2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    q4rcoor2   ../starter/source/elements/solid_2d/quad4/q4coor2.F
!||--- called by ------------------------------------------------------
!||    q4init2    ../starter/source/elements/solid_2d/quad4/q4init2.F
!||====================================================================
      SUBROUTINE q4rcoor2(X,IXQ,NGL  ,MXT   ,
     .         PID, IX1, IX2, IX3, IX4,
     .         Y1, Y2, Y3, Y4,
     .         Z1, Z2, Z3, Z4,YAVG,Y234,Y124,
     .         SY, SZ, TY, TZ, E1Y, E1Z , E2Y, E2Z)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "vect01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IXQ(NIXQ,*), NGL(*), MXT(*), PID(*)
      INTEGER IX1(*), IX2(*), IX3(*), IX4(*)
      my_real
     .   X(3,*),E1Y(*),E1Z(*),E2Y(*),E2Z(*)
      my_real
     .   y1(*), y2(*), y3(*), y4(*),
     .   z1(*), z2(*), z3(*), z4(*),yavg(*),y234(*),y124(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real
     .   SY(MVSIZ) ,SZ(MVSIZ) ,
     .   TY(MVSIZ) ,TZ(MVSIZ), SUMA,CT,CS
C--------------------------------------------------
C     CONNECTIVITES ET MATERIEL
C--------------------------------------------------
      DO i=lft,llt
        mxt(i)=ixq(1,i)
        ix1(i)=ixq(2,i)
        ix2(i)=ixq(3,i)
        ix3(i)=ixq(4,i)
        ix4(i)=ixq(5,i)
        pid(i)=ixq(6,i)
        ngl(i)=ixq(nixq,i)
      END DO
C
C----------------------------
C     COORDONNEES NOEUDS    |
C----------------------------
      DO i=lft,llt
        y1(i)=x(2,ix1(i))
        z1(i)=x(3,ix1(i))
        y2(i)=x(2,ix2(i))
        z2(i)=x(3,ix2(i))
        y3(i)=x(2,ix3(i))
        z3(i)=x(3,ix3(i))
        y4(i)=x(2,ix4(i))
        z4(i)=x(3,ix4(i))
      END DO
      DO i=lft,llt
         yavg(i) = fourth*(y1(i)+y2(i)+y3(i)+y4(i))
         y234(i)=y2(i)+y3(i)+y4(i)
         y124(i)=y1(i)+y2(i)+y4(i)
      END DO
C---------------------------------------
C     REPERE LOCAL (ISOPARAMETRIQUE)
C---------------------------------------
      DO i=lft,llt
        sy(i)=half*(y2(i)+y3(i)-y1(i)-y4(i))
        sz(i)=half*(z2(i)+z3(i)-z1(i)-z4(i))
        ty(i)=half*(y3(i)+y4(i)-y1(i)-y2(i))
        tz(i)=half*(z3(i)+z4(i)-z1(i)-z2(i))
      END DO
C-----------
C     REPERE CONVECTE ORTHOGONALISE 
C     full integ: Same than the shell 
C-----------
      DO i=lft,llt
        ct = ty(i)*ty(i)+tz(i)*tz(i)
        cs = sy(i)*sy(i)+sz(i)*sz(i)
        IF(cs /= zero) THEN
          suma = sqrt(ct/max(em20,cs))
          e1y(i) = sy(i)*suma + tz(i)
          e1z(i) = sz(i)*suma - ty(i)
        ELSEIF(ct /= zero)THEN
          suma = sqrt(cs/max(em20,ct))
          e1y(i) = sy(i) + tz(i)*suma
          e1z(i) = sz(i) - ty(i)*suma
        END IF 
        suma=sqrt(e1y(i)**2+e1z(i)**2)
        suma=one/max(suma,em20)
        e1y(i)=e1y(i)*suma
        e1z(i)=e1z(i)*suma
        e2y(i)=-e1z(i)
        e2z(i)= e1y(i)
      ENDDO
c
      RETURN
      END