scortho3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    scortho3   ../starter/source/elements/thickshell/solidec/scortho3.F
!||--- called by ------------------------------------------------------
!||    sccoor3    ../starter/source/elements/thickshell/solidec/sccoor3.F
!||====================================================================
      SUBROUTINE scortho3(
     .      X1   ,X2   ,X3   ,X4   ,X5   ,X6   ,X7   ,X8,         
     .      Y1   ,Y2   ,Y3   ,Y4   ,Y5   ,Y6   ,Y7   ,Y8,         
     .      Z1   ,Z2   ,Z3   ,Z4   ,Z5   ,Z6   ,Z7   ,Z8,         
     .      RX   ,RY   ,RZ   ,SX   ,SY   ,SZ   ,TX   ,TY   ,TZ   ,   
     .      E1X  ,E1Y  ,E1Z  ,E2X  ,E2Y  ,E2Z  ,E3X  ,E3Y  ,E3Z  )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
C     REAL
      my_real
     .   x1(*), x2(*), x3(*), x4(*), x5(*), x6(*), x7(*), x8(*),
     .   y1(*), y2(*), y3(*), y4(*), y5(*), y6(*), y7(*), y8(*),  
     .   z1(*), z2(*), z3(*), z4(*), z5(*), z6(*), z7(*), z8(*),  
     .   rx(*) ,ry(*) ,rz(*) ,sx(*) ,sy(*) ,sz(*) ,tx(*) ,ty(*) ,tz(*),
     .   e1x(*),e1y(*),e1z(*),e2x(*),e2y(*),e2z(*),e3x(*),e3y(*),e3z(*)
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "vect01_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real
     .   X17(MVSIZ) , X28(MVSIZ) , X35(MVSIZ) , X46(MVSIZ),
     .   Y17(MVSIZ) , Y28(MVSIZ) , Y35(MVSIZ) , Y46(MVSIZ),
     .   z17(mvsiz) , z28(mvsiz) , z35(mvsiz) , z46(mvsiz),
     .   a17(mvsiz) , a28(mvsiz) ,
     .   b17(mvsiz) , b28(mvsiz) ,
     .   c17(mvsiz) , c28(mvsiz) ,
     .   det,c1,c2 
C-----------------------------------------------
      DO 10 i=lft,llt
      x17(i)=x7(i)-x1(i)
      x28(i)=x8(i)-x2(i)
      x35(i)=x5(i)-x3(i)
      x46(i)=x6(i)-x4(i)
      y17(i)=y7(i)-y1(i)
      y28(i)=y8(i)-y2(i)
      y35(i)=y5(i)-y3(i)
      y46(i)=y6(i)-y4(i)
      z17(i)=z7(i)-z1(i)
      z28(i)=z8(i)-z2(i)
      z35(i)=z5(i)-z3(i)
      z46(i)=z6(i)-z4(i)
 10   CONTINUE
      DO 20 i=lft,llt
      rx(i)=x17(i)+x28(i)-x35(i)-x46(i)
      ry(i)=y17(i)+y28(i)-y35(i)-y46(i)
      rz(i)=z17(i)+z28(i)-z35(i)-z46(i)
      a17(i)=x17(i)+x46(i)
      a28(i)=x28(i)+x35(i)
      b17(i)=y17(i)+y46(i)
      b28(i)=y28(i)+y35(i)
      c17(i)=z17(i)+z46(i)
      c28(i)=z28(i)+z35(i)
 20   CONTINUE
      DO 30 i=lft,llt
      sx(i)=a17(i)+a28(i)
      sy(i)=b17(i)+b28(i)
      sz(i)=c17(i)+c28(i)
      tx(i)=a17(i)-a28(i)
      ty(i)=b17(i)-b28(i)
      tz(i)=c17(i)-c28(i)
 30   CONTINUE
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      DO 100 i=lft,llt
C
       e3x(i) = ty(i) * rz(i) - tz(i) * ry(i) 
       e3y(i) = tz(i) * rx(i) - tx(i) * rz(i) 
       e3z(i) = tx(i) * ry(i) - ty(i) * rx(i) 
C
       det = sqrt(e3x(i)*e3x(i) + e3y(i)*e3y(i) + e3z(i)*e3z(i))
       IF ( det/=zero) det = one / det
       e3x(i) = e3x(i) * det
       e3y(i) = e3y(i) * det
       e3z(i) = e3z(i) * det
C
       c1=sqrt(tx(i)*tx(i)+ty(i)*ty(i)+tz(i)*tz(i))
       c2=sqrt(rx(i)*rx(i)+ry(i)*ry(i)+rz(i)*rz(i))
       e1x(i)=tx(i)*c2 +(ry(i) * e3z(i) - rz(i) * e3y(i))*c1  
       e1y(i)=ty(i)*c2 +(rz(i) * e3x(i) - rx(i) * e3z(i))*c1  
       e1z(i)=tz(i)*c2 +(rx(i) * e3y(i) - ry(i) * e3x(i))*c1
       det = sqrt(e1x(i)*e1x(i) + e1y(i)*e1y(i) + e1z(i)*e1z(i))
       IF ( det/=zero) det = one / det
       e1x(i) = e1x(i)*det
       e1y(i) = e1y(i)*det
       e1z(i) = e1z(i)*det
C
       e2x(i) = e3y(i) * e1z(i) - e3z(i) * e1y(i)
       e2y(i) = e3z(i) * e1x(i) - e3x(i) * e1z(i)
       e2z(i) = e3x(i) * e1y(i) - e3y(i) * e1x(i)
 100  CONTINUE
c~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
      RETURN
      END