int18_law151_init.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    int18_law151_init   ../starter/source/interfaces/int18/int18_law151_init.F
!||--- called by ------------------------------------------------------
!||    lectur              ../starter/source/starter/lectur.F
!||--- uses       -----------------------------------------------------
!||====================================================================
        SUBROUTINE int18_law151_init(S_APPEND_ARRAY,NINTER,NPARI,
     1                               NUMNOD,NUMELS,NGRBRIC,
     2                               MULTI_FVM,IGRBRIC,IPARI,IXS,
     4                               X       ,V       ,MS         ,KINET       ,
     5                               X_APPEND,V_APPEND,MASS_APPEND,KINET_APPEND)
        
!$COMMENT
!       INT18_LAW151_INIT description
!       initialization of array for /INT18 + LAW 151
!       
!       INT18_LAW151_INIT organization :
!       - x/V/MASS_append :
!            * (1:NUMNOD) : classical x/v/mass
!            * (NUMNOD+1:NUMNOD+NUMELS) : phantom node x/v/mass
!       - kinet_append :
!            * (1:NUMNOD) : classical kinet
!            * (NUMNOD+1:NUMNOD+NUMELS) : =0 (no kinet for phantom node)
!$ENDCOMMENT
C-----------------------------------------------
C     M o d u l e s
C-----------------------------------------------   
        USE multi_fvm_mod
        USE groupdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        INTEGER, INTENT(in) :: S_APPEND_ARRAY !< size of append arrays
        INTEGER, INTENT(in) :: NINTER !< number of interface
        INTEGER, INTENT(in) :: NPARI !< size of IPARI
        INTEGER, INTENT(in) :: NUMNOD !< number of node
        INTEGER, INTENT(in) :: NUMELS !< number of solid
        INTEGER, INTENT(in) :: NGRBRIC !< size of IGRBRIC structure
        INTEGER, DIMENSION(NPARI,NINTER), INTENT(in) :: IPARI
        my_real, DIMENSION(3,NUMNOD), INTENT(in) :: x,v
        my_real, DIMENSION(3,S_APPEND_ARRAY), INTENT(inout) :: x_append,v_append
        my_real, DIMENSION(NUMNOD), INTENT(in) :: ms
        INTEGER, DIMENSION(NUMNOD), INTENT(in) :: KINET
        my_real, DIMENSION(S_APPEND_ARRAY), INTENT(inout) :: mass_append
        INTEGER, DIMENSION(S_APPEND_ARRAY), INTENT(inout) :: KINET_APPEND
        INTEGER, DIMENSION(NIXS,NUMELS), INTENT(in) :: IXS
        TYPE(multi_fvm_struct) :: MULTI_FVM
        TYPE (group_)  , DIMENSION(NGRBRIC), INTENT(in) :: igrbric
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        INTEGER :: N,NN,II,JJ
        INTEGER :: ISU1,NSN,NODE_ID,IBRIC
        LOGICAL, DIMENSION(:), ALLOCATABLE :: TAG
C-----------------------------------------------
        ! X/V/MASS extended 
        ! 1:NUMNOD --> classical x/v/mass
        ! numnod+1:numnod+numels --> x/v/mass of phantom nodes(located to the center of 
        !                              the ALE elements)
        ! INT18_GLOBAL_LIST --> true if /INT18 + LAW151 for the NIN interface
        multi_fvm%INT18_GLOBAL_LIST(1:ninter) = .false.
        ALLOCATE(tag(numels))
        tag(1:numels)=.false.
        IF( multi_fvm%IS_INT18_LAW151 ) THEN
            DO n=1,multi_fvm%NUMBER_INT18
                nn = multi_fvm%INT18_LIST(n)
                multi_fvm%INT18_GLOBAL_LIST(nn) = .true.
            ENDDO
!            ! 1:NUMNOD --> classical x/v/mass
            x_append(1:3,1:numnod) = x(1:3,1:numnod)
            v_append(1:3,1:numnod) = v(1:3,1:numnod)
            mass_append(1:numnod) = ms(1:numnod)
            kinet_append(1:numnod) = kinet(1:numnod)
!            ! initialization of phantom nodes
            x_append( 1:3,numnod+1:numnod+numels ) = zero
            v_append( 1:3,numnod+1:numnod+numels ) = zero
            ! KINET : not used for phantom nodes, always equal to 0
            mass_append(numnod+1:numnod+numels) = zero
            kinet_append(numnod+1:numnod+numels) = 0
 
            DO nn=1,multi_fvm%NUMBER_INT18
                n = multi_fvm%INT18_LIST(nn)
                isu1 = ipari(45,n)
                nsn = ipari(5,n)    ! number of secondary nodes 
                DO ii = 1,nsn
                    ibric = igrbric(isu1)%ENTITY(ii) ! id of the phantom element
                    IF(.NOT. tag(ibric)) THEN ! otherwise already done with a previous interface
                      !   mass
                      mass_append(numnod + ibric) = zero
                      !   position
                      DO jj = 2, 9
                        node_id = ixs(jj, ibric) ! id of node of the phantom element
                        x_append(1, numnod + ibric) = x_append(1, numnod + ibric) + one_over_8 * x(1, node_id)
                        x_append(2, numnod + ibric) = x_append(2, numnod + ibric) + one_over_8 * x(2, node_id) 
                        x_append(3, numnod + ibric) = x_append(3, numnod + ibric) + one_over_8 * x(3, node_id)         
                      ENDDO
                      !   velocity
                      v_append(1, numnod + ibric) = multi_fvm%VEL(1, ibric)
                      v_append(2, numnod + ibric) = multi_fvm%VEL(2, ibric)
                      v_append(3, numnod + ibric) = multi_fvm%VEL(3, ibric)
                      tag(ibric)=.true.
                    ENDIF
                ENDDO
            ENDDO
        ENDIF
        IF(ALLOCATED(tag))DEALLOCATE(tag)
 
        RETURN
        END SUBROUTINE int18_law151_init
C===============================================================================