in12r.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    in12r    ../starter/source/interfaces/inter3d1/in12r.F
!||--- called by ------------------------------------------------------
!||    inint3   ../starter/source/interfaces/inter3d1/inint3.F
!||====================================================================
      SUBROUTINE in12r(X,FRIGAP,NSV,NSN,FLAG)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NSN,FLAG
      INTEGER NSV(*)
      my_real
     .   x(3,*), frigap(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER II, I
      my_real
     .  xx,yy,zz,xt,yt,zt,xc,yc,zc,xr,yr,zr,teta,cs,sn,xct,yct,zct,
     .  ax,ay,az,bx,by,bz,bn,
     .  s11,s21,s31,s12,s22,s32,s13,s23,s33
      SAVE s11,s21,s31,s12,s22,s32,s13,s23,s33
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
       teta=frigap(4)
       cs=cos(teta)
       sn=sin(teta)
       xt=frigap(5)
       yt=frigap(6)
       zt=frigap(7)
       xc=frigap(8)
       yc=frigap(9)
       zc=frigap(10)
       xr=frigap(12)
       yr=frigap(13)
       zr=frigap(14)
       xct=xc+xt
       yct=yc+yt
       zct=zc+zt
C
       IF(flag==1)THEN
       bn=sqrt(yr**2+zr**2)
        IF(bn<em3)THEN
         s11=one
         s21=zero
         s31=zero
         s12=zero
         s22=cs
         s32=sn
        ELSE
         ax=one-xr*xr
         ay=  -xr*yr
         az=  -xr*zr
         bx=yr*az-zr*ay
         by=zr*ax-xr*az
         bz=xr*ay-yr*ax
         s11=(cs-one)*ax+sn*bx+one
         s21=(cs-one)*ay+sn*by
         s31=(cs-one)*az+sn*bz
         bn=sqrt(s11**2+s21**2+s31**2)
         s11=s11/bn
         s21=s21/bn
         s31=s31/bn
         ax=  -xr*xr
         ay=one-xr*yr
         az=  -xr*zr
         bx=yr*az-zr*ay
         by=zr*ax-xr*az
         bz=xr*ay-yr*ax
         s12=(cs-one)*ax+sn*bx
         s22=(cs-one)*ay+sn*by+one
         s32=(cs-one)*az+sn*bz
         bn=sqrt(s12**2+s22**2+s32**2)
         s12=s12/bn
         s22=s22/bn
         s32=s32/bn
        ENDIF
        s13= s21*s32-s31*s22
        s23= s31*s12-s11*s32
        s33= s11*s22-s21*s12
         bn=sqrt(s13**2+s23**2+s33**2)
         s13=s13/bn
         s23=s23/bn
         s33=s33/bn
C
C TRANSFORMATION TEMPORAIRE POUR TROUVER LES RELATIONS main SECND
        DO ii=1,nsn
         i=nsv(ii)
         xx=x(1,i)-xc
         yy=x(2,i)-yc
         zz=x(3,i)-zc
         x(1,i)=s11*xx+s12*yy+s13*zz+xct
         x(2,i)=s21*xx+s22*yy+s23*zz+yct
         x(3,i)=s31*xx+s32*yy+s33*zz+zct
        ENDDO
       ELSE
C RETOUR COORDONNEES ORIGINALES
        DO ii=1,nsn
         i=nsv(ii)
         xx=x(1,i)-xct
         yy=x(2,i)-yct
         zz=x(3,i)-zct
         x(1,i)=s11*xx+s21*yy+s31*zz+xc
         x(2,i)=s12*xx+s22*yy+s32*zz+yc
         x(3,i)=s13*xx+s23*yy+s33*zz+zc
        ENDDO
        frigap(5)=s11
        frigap(6)=s21
        frigap(7)=s31
        frigap(8)=s12
        frigap(9)=s22
        frigap(10)=s32
        frigap(12)=s13
        frigap(13)=s23
        frigap(14)=s33
       ENDIF
C
      RETURN
      END