dxyzsrg.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    dxyzsrg        ../starter/source/output/anim/dxyzsrg.F
!||--- called by ------------------------------------------------------
!||    genani1        ../starter/source/output/anim/genani1.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE dxyzsrg (NESRG,IGRSURF,BUFSF)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE groupdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NESRG
      my_real
     .  bufsf(*)
      TYPE (SURF_)   , DIMENSION(NSURF)   :: IGRSURF
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER N, ADRBUF
      INTEGER INOE, I, J, K, IDG, ITER
      my_real xg,yg,zg,a,b,c,rot(9),
     1        dgr,an,bn,cn,
     2        xln,yln,zln,nxl,nyl,nzl,normn
      my_real
     1   ncor(3,384),
     2   xa,xb,xc,la,lb,lc,
     3   xx,yy,zz,xl,yl,zl,e,d
      my_real
     1   xx0,yy0,zz0,
     2   x0(6),y0(6),z0(6),dx0(6),dy0(6),dz0(6),dx1(6),dy1(6),dz1(6)
      REAL R4
      DATA dx0/ 0., 0., 0., 0., 0., 0./
      DATA dy0/ 1.,-1., 0., 0., 0., 0./
      DATA dz0/ 0., 0.,-1., 1., 1.,-1./
      DATA dx1/ 1., 1., 1., 1., 0., 0./
      DATA dy1/ 0., 0., 0., 0., 1., 1./
      DATA dz1/ 0., 0., 0., 0., 0., 0./
      DATA x0 /-3.5,-3.5,-3.5,-3.5,-3.5, 3.5/
      DATA y0 /-3.5, 3.5,-3.5, 3.5,-3.5,-3.5/
      DATA z0 /-3.5, 3.5, 3.5,-3.5,-3.5, 3.5/
C-----------------------------------------------
      DO 200 n=1,nsurf
       IF (igrsurf(n)%TYPE/=101) GOTO 200
       adrbuf=igrsurf(n)%IAD_BUFR
C-------------------------------------------------------
c      Parametres de l'ellipsoide.
C-------------------------------------------------------
       dgr=bufsf(adrbuf+36)
       idg=dgr
       xg=bufsf(adrbuf+4)
       yg=bufsf(adrbuf+5)
       zg=bufsf(adrbuf+6)
       a =bufsf(adrbuf+1)
       b =bufsf(adrbuf+2)
       c =bufsf(adrbuf+3)
       DO i=1,9
        rot(i)=bufsf(adrbuf+7+i-1)
       END DO
C-------------------------------------------------------
C      - Calcul des noeuds sur le cube A,B,C
C-------------------------------------------------------
       inoe=0
       DO i = 1,6
        xx0 = x0(i)
        yy0 = y0(i)
        zz0 = z0(i)
        DO j = 1,8
          xl = xx0
          yl = yy0
          zl = zz0
          DO k = 1,8
            inoe=inoe+1
            ncor(1,inoe) = a*xl * third
            ncor(2,inoe) = b*yl * third
            ncor(3,inoe) = c*zl * third            
            xl = xl + dx0(i)
            yl = yl + dy0(i)
            zl = zl + dz0(i)
          ENDDO
          xx0 = xx0 + dx1(i)
          yy0 = yy0 + dy1(i)
          zz0 = zz0 + dz1(i)
        ENDDO
       ENDDO
C-------------------------------------------------------
C      - Projection radiale sur l'ellipsoide.
C      - Passage au repere global.
C-------------------------------------------------------
       an=a**idg
       bn=b**idg
       cn=c**idg
       inoe=0
       DO i=1,384
        inoe=inoe+1
        xl=ncor(1,inoe)
        yl=ncor(2,inoe)
        zl=ncor(3,inoe)
C
        xln=xl**idg
        yln=yl**idg
        zln=zl**idg
        e=abs(xln)/an+abs(yln)/bn+abs(zln)/cn
        e=exp(log(e)/dgr)
        xl=xl/e
        yl=yl/e
        zl=zl/e
C
        xx =rot(1)*xl+rot(4)*yl+rot(7)*zl
        yy =rot(2)*xl+rot(5)*yl+rot(8)*zl
        zz =rot(3)*xl+rot(6)*yl+rot(9)*zl
        ncor(1,inoe)=xx+xg
        ncor(2,inoe)=yy+yg
        ncor(3,inoe)=zz+zg
       END DO
C-------------------------------------------------------
C      Ecriture des noeuds.
C-------------------------------------------------------
       inoe=0
       DO i=1,384
        inoe=inoe+1
        r4 = ncor(1,inoe)
        CALL write_r_c(r4,1)
        r4 = ncor(2,inoe)
        CALL write_r_c(r4,1)
        r4 = ncor(3,inoe)
        CALL write_r_c(r4,1)
       END DO
C-------------------------------------------------------
 200   CONTINUE
C-------------------------------------------------------
      RETURN
      END