write_sensors.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    write_sensors          ../starter/source/tools/sensor/write_sensors.F
!||--- called by ------------------------------------------------------
!||    ddsplit                ../starter/source/restart/ddsplit/ddsplit.F
!||--- calls      -----------------------------------------------------
!||    fretitl                ../starter/source/starter/freform.F
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE write_sensors(SENSORS,NUMNOD,NODLOCAL)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE sensor_mod , ONLY : sensors_, sensor_str_,
     .                        isenbuf, lsenbuf, nsenparr, nsenpari
      USE write_mod, ONLY : write_integer
      USE names_and_titles_mod , ONLY : nchartitle
      USE python_funct_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include "implicit_f.inc"
#include "scr17_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(IN) :: NUMNOD
      INTEGER ,DIMENSION(NUMNOD) ,INTENT(IN) :: NODLOCAL
      TYPE (SENSORS_) ,TARGET ,INTENT(IN) :: SENSORS
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,ISEN,LEN,IAD,NFIX,NPARI,NPARR,NVAR,N1,N2,TYP
      INTEGER, DIMENSION(LTITR) :: ITITLE
      INTEGER, DIMENSION(:), ALLOCATABLE :: LTEMP
      my_real, DIMENSION(:), ALLOCATABLE :: rbuf
      CHARACTER(LEN = nchartitle) :: TITLE
      TYPE (SENSOR_STR_) ,POINTER :: SENSOR
C=======================================================================
      IF (sensors%NSENSOR > 0) THEN
        nfix = 11
c
        DO isen=1,sensors%NSENSOR
          sensor => sensors%SENSOR_TAB(isen)
          typ   = sensor%TYPE
          npari = sensor%NPARI
          nparr = sensor%NPARR
          nvar  = sensor%NVAR
          title = sensor%TITLE
          ALLOCATE (ltemp(npari))
          ltemp(1:npari) = sensor%IPARAM(1:npari)
c         update node system number after renumbering for sensors using nodes
          IF (typ == 2) THEN   ! /sens/disp
            n1 = nodlocal(sensor%IPARAM(1))
            n2 = nodlocal(sensor%IPARAM(2))
            ltemp(1) = n1
            ltemp(2) = n2
          ELSE IF (typ == 9) THEN  ! /sens/vel
            n1 = nodlocal(sensor%IPARAM(1))
            ltemp(1) = n1
          ELSE IF (typ == 13) THEN  ! /sens/work
            n2 = sensor%IPARAM(2)
            n1 = nodlocal(sensor%IPARAM(1))
            IF (n2 > 0) THEN
              n2 = nodlocal(sensor%IPARAM(2))
            END IF
            ltemp(1) = n1
            ltemp(2) = n2
          ELSE IF (typ == 15) THEN  ! /sens/dist_surf
            ltemp(1) = nodlocal(sensor%IPARAM(1))
            IF (sensor%IPARAM(2) == 0) THEN
              ltemp(3) = nodlocal(sensor%IPARAM(3))
              ltemp(4) = nodlocal(sensor%IPARAM(4))
              ltemp(5) = nodlocal(sensor%IPARAM(5))
            END IF
          END IF
c
          len = nfix + npari + nparr + nvar
          ALLOCATE (rbuf(len) )
c
          iad = 0
          rbuf(iad+1) = sensor%TYPE
          rbuf(iad+2) = sensor%SENS_ID
          rbuf(iad+3) = sensor%STATUS
          rbuf(iad+4) = sensor%TCRIT
          rbuf(iad+5) = sensor%TMIN
          rbuf(iad+6) = sensor%TDELAY
          rbuf(iad+7) = sensor%TSTART
          rbuf(iad+8) = sensor%VALUE
          rbuf(iad+9) = sensor%NPARI
          rbuf(iad+10)= sensor%NPARR
          rbuf(iad+11)= sensor%NVAR
          iad = iad + nfix
c
          IF (npari > 0) THEN
            DO i = 1,npari
              rbuf(iad+i) = ltemp(i)
            END DO
            iad = iad + npari
          END IF
          IF (nparr > 0) THEN
            DO i = 1,nparr
              rbuf(iad+i) = sensor%RPARAM(i)
            END DO
            iad = iad + nparr
          END IF
          IF (nvar > 0) THEN
            DO i = 1,nvar
              rbuf(iad+i) = sensor%VAR(i)
            END DO
            iad = iad + nvar
          END IF
c
          CALL write_db(rbuf,len)
          DEALLOCATE(rbuf)
          DEALLOCATE(ltemp)
c
c         write sensor title
          CALL fretitl(title,ititle,ltitr)
          CALL write_i_c(ititle,ltitr)
c
          IF (typ==29.OR.typ==30.OR.typ==31)THEN
            CALL write_i_c(sensor%INTEGER_USERPARAM,nsenpari)
            CALL write_i_c(sensor%INTEGER_USERBUF,isenbuf)
 
            CALL write_db(sensor%FLOAT_USERPARAM,nsenparr)
            CALL write_db(sensor%FLOAT_USERBUF,lsenbuf)
          ENDIF
          IF(typ == 40) THEN
            CALL write_integer(sensor%PYTHON_FUNCTION_ID)
          ENDIF
c
        END DO
c---------------------------------------
c       Write Logical sensor index array
c---------------------------------------
 
        CALL write_integer(sensors%LOGICAL_SENSOR_COUNT)
        CALL write_i_c(sensors%LOGICAL_SENSORS_LIST,sensors%LOGICAL_SENSOR_COUNT)
 
c---------------------------------------
c       Write spmd/PON exchange arrays
c---------------------------------------
 
        CALL write_dpdb(sensors%FSAV,12*6*sensors%SFSAV)
        CALL write_i_c(sensors%TABSENSOR,sensors%STABSEN)
      END IF
c-----------
      RETURN
      END