stat_node.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    stat_node          ../engine/source/output/sta/stat_node.F
!||--- called by ------------------------------------------------------
!||    genstat            ../engine/source/output/sta/genstat.F
!||--- calls      -----------------------------------------------------
!||    spmd_dstat_vgath   ../engine/source/mpi/output/spmd_stat.F
!||--- uses       -----------------------------------------------------
!||    my_alloc_mod       ../common_source/tools/memory/my_alloc.F90
!||====================================================================
      SUBROUTINE stat_node(X,NUMNOD,ITAB,ITABG,LENG,
     .                    NODGLOB,WEIGHT,NODTAG)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE my_alloc_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "task_c.inc"
#include      "spmd_c.inc"
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ITAB(*), NUMNOD,WEIGHT(*),ITABG(*),LENG,
     .        nodglob(*),nodtag(*)
      my_real
     .   x(3,*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      INTEGER,DIMENSION(:),ALLOCATABLE :: NODTAGLOB
      my_real,DIMENSION(:,:),ALLOCATABLE :: vglob
C-----------------------------------------------
      CALL my_alloc(nodtaglob,leng)
      CALL my_alloc(vglob,3,leng)
C-----------------------------------------------
 
      IF (nspmd > 1) THEN
        CALL spmd_dstat_vgath(x,nodglob,weight,vglob,nodtag,
     .                        nodtaglob)
        IF (ispmd/=0) RETURN
      ENDIF
 
      WRITE(iugeo,'(A)')'/NODE'
      WRITE(iugeo,'(2A)')'#    NODID               XCOOR',
     .         '               YCOOR               ZCOOR'
 
      IF (nspmd == 1) THEN
        DO i=1,numnod
           IF(nodtag(i) /= 0) THEN
            WRITE(iugeo,'(I10,1P3E20.13)')
     .       itab(i),x(1,i),x(2,i),x(3,i)
           END IF
        END DO
      ELSE
        DO i=1,numnodg
          IF(nodtaglob(i) /= 0)
     .      WRITE(iugeo,'(I10,1P3E20.13)')
     .       itabg(i),vglob(1,i),vglob(2,i),vglob(3,i)
        END DO
      ENDIF
C-----------------------------------------------
      DEALLOCATE(nodtaglob)
      DEALLOCATE(vglob)
C-----------------------------------------------
      RETURN
      END