stat_truss_mp.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    stat_truss_mp   ../engine/source/output/sta/stat_truss_mp.F
!||--- called by ------------------------------------------------------
!||    genstat         ../engine/source/output/sta/genstat.F
!||--- calls      -----------------------------------------------------
!||    my_orders       ../common_source/tools/sort/my_orders.c
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod    ../common_source/modules/mat_elem/elbufdef_mod.F90
!||    my_alloc_mod    ../common_source/tools/memory/my_alloc.F90
!||====================================================================
      SUBROUTINE stat_truss_mp(ITAB   ,IPART     ,IXT   ,IPARTT   ,IPART_STATE,
     .                         NODTAG ,STAT_INDXT,IPARG ,ELBUF_TAB,IDEL       )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE elbufdef_mod
      USE my_alloc_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "scr16_c.inc"
#include      "scr17_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ITAB(*),IPART(LIPART1,*),IXT(NIXT,*),IPARTT(*),
     .        ipart_state(*),nodtag(*),stat_indxt(*),iparg(nparg,*)
      INTEGER IDEL
      TYPE (ELBUF_STRUCT_), DIMENSION(NGROUP), TARGET :: ELBUF_TAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,N,JJ,IPRT0,IPRT,K,II
      INTEGER NG,NEL,NFT,LFT,LLT,ITY,IOFF
      INTEGER WORK(70000)
      INTEGER,DIMENSION(:,:),ALLOCATABLE :: CLEF
      INTEGER,DIMENSION(:),ALLOCATABLE :: NP
C
      TYPE(g_bufel_)  ,POINTER :: GBUF     
C-----------------------------------------------
      CALL my_alloc(np,5*numelt)
      CALL my_alloc(clef,2,numelt)
C-----------------------------------------------
C     TRUSS
C-----------------------------------------------
      jj = 0
      ii = 0
      IF (numelt /= 0) THEN
c
        DO ng=1,ngroup
          ity = iparg(5,ng)
          IF (ity == 4) THEN
            nel = iparg(2,ng)
            nft = iparg(3,ng)
            gbuf => elbuf_tab(ng)%GBUF   
            lft=1
            llt=nel
c
            DO i=lft,llt
              n  = i + nft
              iprt=ipartt(n)
              IF (ipart_state(iprt) /= 0) THEN
c
                np(jj+1) = ixt(nixt,n)
                np(jj+2) = itab(ixt(2,n))
                np(jj+3) = itab(ixt(3,n))
                np(jj+4) = iprt
                np(jj+5) = iabs(nint(gbuf%OFF(i)))
c
                ii = ii + 1
c
                jj = jj + 5
c
                stat_numelt =stat_numelt+1
                clef(1,stat_numelt)=iprt
                clef(2,stat_numelt)=ixt(nixt,n)
c
                nodtag(ixt(2,n))=1
                nodtag(ixt(3,n))=1
              ENDIF ! IF (IPART_STATE(IPRT) /= 0)
            ENDDO ! DO I=LFT,LLT
          ENDIF ! IF (ITY == 4)
        ENDDO ! DO NG=1,NGROUP
      ENDIF ! IF (NUMELT /= 0)
C----
      DO n=1,stat_numelt
        stat_indxt(n)=n
      ENDDO
      CALL my_orders(0,work,clef,stat_indxt,stat_numelt,2)
C----
      iprt0=0
      DO n=1,stat_numelt
        k=stat_indxt(n)
        jj=5*(k-1)
        iprt=np(jj+4)
        ioff=np(jj+5)
        IF (idel==0 .OR. (idel==1 .AND. ioff >= 1)) THEN
          IF (iprt /= iprt0) THEN
            WRITE(iugeo,'(A,I10)')'/TRUSS/',ipart(4,iprt)
            WRITE(iugeo,'(A)')
     .    '#TRUSS_ID       NOD1      NOD2'
            iprt0=iprt
          ENDIF
          WRITE(iugeo,'(3I10)') np(jj+1),np(jj+2),np(jj+3)
        ENDIF !IF (IDEL)
      ENDDO ! DO N=1,STAT_NUMELT
C----
C-----------------------------------------------
      DEALLOCATE(np)
      DEALLOCATE(clef)
C-----------------------------------------------
      RETURN
      END