stherm.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    stherm             ../engine/source/elements/solid/solide/stherm.F
!||--- called by ------------------------------------------------------
!||    sforc3             ../engine/source/elements/solid/solide/sforc3.F
!||    szforc3            ../engine/source/elements/solid/solidez/szforc3.F
!||--- uses       -----------------------------------------------------
!||    matparam_def_mod   ../common_source/modules/mat_elem/matparam_def_mod.F90
!||====================================================================
      SUBROUTINE stherm(MAT_PARAM,
     1   VOL,     NC1,     NC2,     NC3,     NC4,     
     2   NC5,     NC6,     NC7,     NC8,     PX1,
     3   PX2,     PX3,     PX4,     PY1,
     4   PY2,     PY3,     PY4,     PZ1,
     5   PZ2,     PZ3,     PZ4,     DT1,
     6   TEMPNC,  TEMPEL,  HEAT,    FPHI,
     7   OFFG,    OFF,     PARTSAV, IPARTS,
     8   VOL0,    NEL,     NUMNOD ,THEACCFACT)
!-----------------------------------------------
!   m o d u l e s
!-----------------------------------------------
      use matparam_def_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: NUMNOD
      INTEGER NC1(MVSIZ),NC2(MVSIZ),NC3(MVSIZ),NC4(MVSIZ),
     .        NC5(MVSIZ),NC6(MVSIZ),NC7(MVSIZ),NC8(MVSIZ)
      INTEGER IPARTS(*)
      my_real :: DT1
      my_real ,INTENT(IN) :: THEACCFACT
      my_real ,INTENT(IN) :: HEAT(MVSIZ)
      my_real :: tempnc(numnod)
      my_real :: tempel(nel) 
      my_real :: off(nel)
      my_real :: offg(nel)
      my_real :: vol(nel)
      my_real :: vol0(nel)
      my_real :: px1(*), px2(*), px3(*), px4(*), 
     .           py1(*), py2(*), py3(*), py4(*),
     .           pz1(*), pz2(*), pz3(*), pz4(*)
      my_real :: fphi(mvsiz,8)
      my_real :: partsav(npsav,*)
      type (matparam_struct_)   ,intent(in) :: mat_param
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,M
      my_real AS, BS, KC, PHIX, PHIY, PHIZ, A, B, RHOCP, T0
!==============================================================================
      as    = mat_param%THERM%AS    !< thermal conductivity coefficient A for solid phase
      bs    = mat_param%THERM%BS    !< thermal conductivity coefficient B for solid phase
      rhocp = mat_param%THERM%RHOCP
      t0    = mat_param%THERM%TINI
C 
C     calculate thermal flux  
C      
      DO i=1,nel
        IF(off(i)==zero.OR.offg(i)<=zero) cycle
        phix =  tempnc(nc1(i))*px1(i) + tempnc(nc2(i))*px2(i)  +
     .          tempnc(nc3(i))*px3(i) + tempnc(nc4(i))*px4(i)  -
     .          tempnc(nc5(i))*px3(i) - tempnc(nc6(i))*px4(i)  -
     .          tempnc(nc7(i))*px1(i) - tempnc(nc8(i))*px2(i)       
        
        phiy =  tempnc(nc1(i))*py1(i) + tempnc(nc2(i))*py2(i)  +
     .          tempnc(nc3(i))*py3(i) + tempnc(nc4(i))*py4(i)  -
     .          tempnc(nc5(i))*py3(i) - tempnc(nc6(i))*py4(i)  -
     .          tempnc(nc7(i))*py1(i) - tempnc(nc8(i))*py2(i)
      
        phiz =  tempnc(nc1(i))*pz1(i) + tempnc(nc2(i))*pz2(i)  +
     .          tempnc(nc3(i))*pz3(i) + tempnc(nc4(i))*pz4(i)  -
     .          tempnc(nc5(i))*pz3(i) - tempnc(nc6(i))*pz4(i)  -
     .          tempnc(nc7(i))*pz1(i) - tempnc(nc8(i))*pz2(i)          
C
        kc = (as + bs*tempel(i))*vol(i)*dt1*theaccfact
        phix = kc*phix
        phiy = kc*phiy
        phiz = kc*phiz         
C
C       ! nodal thermal force
C
        a = one_over_8 * heat(i)
        b = phix*px1(i) + phiy*py1(i) + pz1(i)*phiz        
        fphi(i,1) = a - b
        fphi(i,7) = a + b
        b = phix*px2(i) + phiy*py2(i) + pz2(i)*phiz
        fphi(i,2) = a - b
        fphi(i,8) = a + b
        b = phix*px3(i) + phiy*py3(i) + pz3(i)*phiz
        fphi(i,3) = a - b
        fphi(i,5) = a + b
        b = phix*px4(i) + phiy*py4(i) + pz4(i)*phiz
        fphi(i,4) = a - b 
        fphi(i,6) = a + b
      ENDDO
C  
      DO i=1,nel
        IF (off(i)==zero.OR.offg(i)<=zero) cycle
        m = iparts(i)
        partsav(28,m) = partsav(28,m) + rhocp*vol0(i)*(tempel(i)-t0) + heat(i)
      ENDDO
!-----------
      RETURN
      END