surf_area.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    surf_area   ../engine/source/output/th/surf_area.F
!||--- called by ------------------------------------------------------
!||    hist2       ../engine/source/output/th/hist2.F
!||====================================================================
      SUBROUTINE surf_area(X, NN, SURF_NODES, AREA, NUMNOD, N2D)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER,INTENT(IN) :: NN,NUMNOD
      INTEGER,INTENT(IN) :: SURF_NODES(NN,4) !< FACE NODES (NN FACES, 3D:4nodes, 2D:2nodes only are used)
      my_real,INTENT(IN) ::  x(3,numnod)     !< coordinates x,y,z for each node
      my_real,INTENT(INOUT) :: area          !< surface area
      INTEGER,INTENT(IN) :: N2D              !0:3D, 1:2d-axi 2:2d-plane
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,NOD1,NOD2,NOD3,NOD4
      my_real :: x13, y13, z13, x24, y24, z24,n1, n2, n3
      my_real :: y12, z12
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      area = zero
      IF(n2d == 0)THEN
        DO i=1,nn
           nod1=surf_nodes(i,1)
           nod2=surf_nodes(i,2)
           nod3=surf_nodes(i,3)
           nod4=surf_nodes(i,4)
           x13= x(1,nod3)-x(1,nod1)
           y13= x(2,nod3)-x(2,nod1)
           z13= x(3,nod3)-x(3,nod1)
           x24= x(1,nod4)-x(1,nod2)
           y24= x(2,nod4)-x(2,nod2)
           z24= x(3,nod4)-x(3,nod2)
           n1 = y13*z24-y24*z13
           n2 = z13*x24-z24*x13
           n3 = x13*y24-x24*y13
           area = area + sqrt(n1*n1+n2*n2+n3*n3)
        ENDDO
        area = area * half
      ELSE
        !2D case
        DO i=1,nn
           nod1=surf_nodes(i,1)
           nod2=surf_nodes(i,2)
           !vector N1-N2 (2d:0,y,z)
           y12= x(2,nod1)-x(2,nod2)
           z12= x(3,nod1)-x(3,nod2)
           area = area + sqrt(y12*y12+z12*z12)
        ENDDO
      ENDIF
C-----------------------------------------------
      RETURN
      END