tdefo3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    tdefo3   ../engine/source/elements/truss/tdefo3.F
!||--- called by ------------------------------------------------------
!||    tforc3   ../engine/source/elements/truss/tforc3.F
!||====================================================================
      SUBROUTINE tdefo3(
     1   V,       OFFG,    OFF,     NC1,
     2   NC2,     EPS,     AL,      VX1,
     3   VX2,     VY1,     VY2,     VZ1,
     4   VZ2,     EX,      EY,      EZ,
     5   X1,      X2,      Y1,      Y2,
     6   Z1,      Z2,      NEL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER NC1(MVSIZ),NC2(MVSIZ)
      my_real
     .   V(3,*),OFFG(MVSIZ),OFF(MVSIZ),EPS(MVSIZ),AL(MVSIZ),
     .   VX1(MVSIZ),VX2(MVSIZ),VY1(MVSIZ),VY2(MVSIZ),VZ1(MVSIZ),
     .   VZ2(MVSIZ),EX(MVSIZ),EY(MVSIZ),EZ(MVSIZ),X1(MVSIZ),X2(MVSIZ),
     .   y1(mvsiz),y2(mvsiz),z1(mvsiz),z2(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J
      my_real
     .   V1(MVSIZ),V2(MVSIZ),RATIO(MVSIZ),OFF_L
C-----------------------------------------------      
      DO I=1,nel
        vx1(i)=v(1,nc1(i))
        vy1(i)=v(2,nc1(i))
        vz1(i)=v(3,nc1(i))
        vx2(i)=v(1,nc2(i))
        vy2(i)=v(2,nc2(i))
        vz2(i)=v(3,nc2(i))
      ENDDO
c
      DO i=1,nel
        ex(i)=x2(i)-x1(i)
        ey(i)=y2(i)-y1(i)
        ez(i)=z2(i)-z1(i)
      ENDDO
c
      DO i=1,nel
        al(i)=sqrt(ex(i)*ex(i)+ey(i)*ey(i)+ez(i)*ez(i))
      ENDDO
c
      DO i=1,nel
        IF (al(i) /= zero) THEN
          ex(i) = ex(i)/al(i)
          ey(i) = ey(i)/al(i)
          ez(i) = ez(i)/al(i)
        ELSE
          ex(i) = zero
          ey(i) = zero
          ez(i) = zero                    
        ENDIF
      ENDDO
c
      DO i=1,nel
        v1(i)=ex(i)*vx1(i)+ey(i)*vy1(i)+ez(i)*vz1(i)
        v2(i)=ex(i)*vx2(i)+ey(i)*vy2(i)+ez(i)*vz2(i)
      ENDDO
c
      DO i=1,nel
        IF (al(i) /= zero) THEN
          eps(i)= (v2(i)-v1(i))/al(i)     
          ratio(i) = ( (vx2(i)-vx1(i))*(vx2(i)-vx1(i))
     .                +(vy2(i)-vy1(i))*(vy2(i)-vy1(i))
     .                +(vz2(i)-vz1(i))*(vz2(i)-vz1(i)) )
     .               /(al(i)*al(i))
         ELSE
           eps(i)   = zero
           ratio(i) = zero
         ENDIF
      ENDDO
c
      DO i=1,nel
        eps(i)= eps(i) + half*dt1*( eps(i)*eps(i) - ratio(i) )
      ENDDO
c
      off_l = zero
      DO i=1,nel
        off(i) = min(one,abs(offg(i)))
        off(i) = max(zero,off(i))
        off_l  = min(off_l,offg(i))
      ENDDO
c
      IF (off_l < zero) THEN
        DO i=1,nel
         IF (offg(i) < zero) THEN
           eps(i)=zero
         ENDIF
        ENDDO
      ENDIF
C-----------------------------------------------      
      RETURN
      END