tfcum3p.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    tfcum3p   ../engine/source/elements/truss/tfcum3p.F
!||--- called by ------------------------------------------------------
!||    tforc3    ../engine/source/elements/truss/tforc3.F
!||====================================================================
      SUBROUTINE tfcum3p(
     1   FOR,     STI,     FSKY,    FSKYV,
     2   IADT,    FX1,     FX2,     FY1,
     3   FY2,     FZ1,     FZ2,     OFFG,
     4   OFF,     NC1,     NC2,     EX,
     5   EY,      EZ,      NEL,     NFT)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "parit_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: NFT
      my_real
     .   FSKYV(LSKY,8),FSKY(8,LSKY),FOR(*),STI(*),
     .   FX1(MVSIZ),FY1(MVSIZ),FZ1(MVSIZ),
     .   fx2(mvsiz),fy2(mvsiz),fz2(mvsiz),
     .   offg(mvsiz),off(mvsiz),ex(mvsiz),ey(mvsiz),
     .   ez(mvsiz)
      INTEGER IADT(2,*),NC1(MVSIZ),NC2(MVSIZ)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,II,K,J
      my_real
     .   f11(mvsiz),f21(mvsiz),f31(mvsiz),off_l
C-----------------------------------------------      
      DO i=1,nel
        f11(i)=ex(i)*for(i)
        f21(i)=ey(i)*for(i)
        f31(i)=ez(i)*for(i)
      ENDDO
c
      off_l=zero
      DO i=1,nel
        IF (off(i) < one) offg(i) = off(i)
        off_l = min(off_l,offg(i))
      ENDDO
c
      IF (off_l < zero) THEN
        DO i=1,nel
          IF(offg(i) < zero) THEN
            f11(i)=zero
            f21(i)=zero
            f31(i)=zero
            sti(i)=zero
          ENDIF
        ENDDO
      ENDIF
C-------------------------
C     ASSEMBLE
C-------------------------
      IF (ivector == 1) THEN
#include "vectorize.inc"
        DO i=1,nel
          ii = i+nft
          k = iadt(1,ii)
          fskyv(k,1)=f11(i)
          fskyv(k,2)=f21(i)
          fskyv(k,3)=f31(i)
          fskyv(k,7)=sti(i)
          fx1(i) = -f11(i)
          fy1(i) = -f21(i)
          fz1(i) = -f31(i)
          k = iadt(2,ii)
          fskyv(k,1)=-f11(i)
          fskyv(k,2)=-f21(i)
          fskyv(k,3)=-f31(i)
          fskyv(k,7)=sti(i)
          fx2(i) = f11(i)
          fy2(i) = f21(i)
          fz2(i) = f31(i)
        ENDDO
      ELSE
        DO i=1,nel
         ii = i+nft
         k = iadt(1,ii)
         fsky(1,k)=f11(i)
         fsky(2,k)=f21(i)
         fsky(3,k)=f31(i)
         fsky(7,k)=sti(i)
         fx1(i) = -f11(i)
         fy1(i) = -f21(i)
         fz1(i) = -f31(i)
         k = iadt(2,ii)
         fsky(1,k)=-f11(i)
         fsky(2,k)=-f21(i)
         fsky(3,k)=-f31(i)
         fsky(7,k)=sti(i)
         fx2(i) = f11(i)
         fy2(i) = f21(i)
         fz2(i) = f31(i)
        ENDDO
      ENDIF
C-----------------------------------------------        
      RETURN
      END