tmax_ipart.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    tmax_ipart             ../engine/source/output/tmax_ipart.F
!||--- called by ------------------------------------------------------
!||    resol_init             ../engine/source/engine/resol_init.F
!||--- uses       -----------------------------------------------------
!||    h3d_mod                ../engine/share/modules/h3d_mod.F
!||    message_mod            ../engine/share/message_module/message_mod.F
!||    names_and_titles_mod   ../common_source/modules/names_and_titles_mod.F
!||    outmax_mod             ../common_source/modules/outmax_mod.F
!||====================================================================
      SUBROUTINE tmax_ipart(IPARG ,IPART ,IPARTS ,IPARTC ,IPARTG ,H3D_DATA)
C-----------------------------------------------
C   M o d u l e s
C----------------------------------------------- 
      USE outmax_mod
      USE h3d_mod
      USE message_mod
      USE names_and_titles_mod, ONLY: ncharkey
C-----------------------------------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "scr17_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, DIMENSION(NPARG,NGROUP) ,INTENT(IN):: IPARG
      INTEGER, DIMENSION(LIPART1,NPART),INTENT(IN):: IPART
      INTEGER ,DIMENSION(NUMELS),INTENT(IN):: IPARTS
      INTEGER ,DIMENSION(NUMELC),INTENT(IN):: IPARTC
      INTEGER ,DIMENSION(NUMELTG),INTENT(IN):: IPARTG
      TYPE(h3d_database) :: H3D_DATA
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J, K, N ,NELC , NELTG , IP , NPRT , IPRT
      INTEGER IH3D,NG,ITY,NFT,IKEY,K_LEN,ID_INPUT,ID,NH3D_P
 
      INTEGER :: NKPART(NPART,3),NOPART(3)
      CHARACTER(LEN=NCHARKEY) :: KEY2
      CHARACTER(LEN=NCHARKEY) :: KEY3
      CHARACTER(LEN=NCHARKEY) :: KEY4
      CHARACTER(LEN=NCHARKEY) :: KEY5
C-----------------------------------------------
C   S o u r c e   L i n e s
C----------------------------------------------- 
C------- IPART_OK(NGROUP,1) for GPS_PART,IPART_OK(NGROUP,2) for GPSRA_PART   
         IF (ALLOCATED(ipart_ok))  DEALLOCATE(ipart_ok)
         ALLOCATE(ipart_ok(ngroup,2))
         ipart_ok = 0
         ncy_gps = 10
         ncy_gpstr = 10
        IF ((lmax_nsig+lmax_nstra)>0) THEN
          IF (lmax_nsig>0) ALLOCATE(igpstag(numnod))
          IF (lmax_nstra>0)ALLOCATE(igpstratag(numnod))
          nkpart(1:npart,1:3) = 0
          nopart(1:3) = 1
          DO id_input=1,h3d_data%N_INPUT_H3D
c         
            key2 = h3d_data%INPUT_LIST(id_input)%KEY2
            key3 = h3d_data%INPUT_LIST(id_input)%KEY3
            key4 = h3d_data%INPUT_LIST(id_input)%KEY4
            key5 = h3d_data%INPUT_LIST(id_input)%KEY5
            IF ( key2=='PART' ) THEN
              id = 3
              nopart(id) = 0
            ELSEIF ( key3=='GPS'.AND. key4=='TMAX') THEN
              id = 1
              nopart(id) = 0
              IF (key5/=' ') READ (key5(3:12),'(I10)',err=100) ncy_gps 
            ELSEIF ( key3=='GPSTRAIN'.AND. key4=='TMAX') THEN
              id = 2
              nopart(id) = 0
              IF (key5/=' ') READ (key5(3:12),'(I10)',err=100) ncy_gpstr 
            ELSE
              id = 0
            END IF
            IF ( id > 0 ) THEN
              nh3d_p = h3d_data%INPUT_LIST(id_input)%NB_PART
              IF (nh3d_p==0) THEN
                nkpart(1:npart,id) = 1
              ELSE
                DO j=1,nh3d_p
                  ip = h3d_data%INPUT_LIST(id_input)%PART_LIST(j)
                  DO k=1,npart
                    IF(ip == ipart(4,k)) nkpart(k,id)=1
                  END DO
                END DO
              END IF
            END IF
          END DO 
c           
          DO id=1,3
            IF ( nopart(id)>0 ) nkpart(1:npart,id)=1
          END DO
          DO id=1,2
            nkpart(1:npart,id)=nkpart(1:npart,3)*nkpart(1:npart,id)
          END DO
          DO ng=1,ngroup
             IF (iparg(8,ng)==1) cycle                                 
             nft=iparg(3,ng)+1
             ity=iparg(5,ng)
C           
             iprt = 0
             SELECT CASE (ity)
               CASE(1)
                 iprt = iparts(nft)
               CASE(3)
                 iprt = ipartc(nft)
               CASE(7)
                 iprt = ipartg(nft)
             END SELECT
             IF(iprt>0) ipart_ok(ng,1:2) = nkpart(iprt,1:2)
          END DO
        END IF
 
      RETURN
100   CALL ancmsg(msgid=277,c1=key2//'/'//key3//'/'//key4//'/'//key5,anmode=aninfo)
      END