tshgeodel3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C-----------------------------------------------
!||====================================================================
!||    tshgeodel3    ../engine/source/elements/thickshell/solidec/tshgeodel3.F
!||--- called by ------------------------------------------------------
!||    s16forc3      ../engine/source/elements/thickshell/solide16/s16forc3.F
!||    s6cforc3      ../engine/source/elements/thickshell/solide6c/s6cforc3.f
!||    s8cforc3      ../engine/source/elements/thickshell/solide8c/s8cforc3.F
!||    scforc3       ../engine/source/elements/thickshell/solidec/scforc3.F
!||--- uses       -----------------------------------------------------
!||    dt_mod        ../engine/source/modules/dt_mod.F
!||    message_mod   ../engine/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE tshgeodel3(NGL, OFFG ,VOLG ,AREA, VOLG0 ,L_SH,GEO ,NNOD,DT,NEL)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE dt_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "mvsiz_p.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "param_c.inc"
#include      "scr17_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(IN)  :: NNOD,NEL
      INTEGER ,DIMENSION(MVSIZ) ,INTENT(IN)  :: NGL
      my_real, DIMENSION(NPROPG) , INTENT(IN)  :: geo 
      my_real, DIMENSION(NEL) , INTENT(IN)  :: volg0 
      my_real, DIMENSION(MVSIZ) , INTENT(IN)  :: volg,area,l_sh ! L_SH=L_MAX**2
      my_real, DIMENSION(NEL) , INTENT(INOUT)  :: offg 
      TYPE(dt_), INTENT(INOUT) :: DT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,ICOUNT,LIST(MVSIZ)
      my_real
     .   tet_colla(mvsiz),def_v(mvsiz),aps_r(mvsiz),
     .   c_min,al,vdefmin,vdefmax,aspmax,colmin,c_max,gdel
C---------------------------------------------
      vdefmin = geo(190)
      vdefmax = geo(191)
      aspmax  = geo(192)
      colmin  = geo(193)
C-----
      gdel=vdefmin+vdefmax+aspmax+colmin
      IF(gdel==zero.AND.dt%IDEL_BRICK==0) RETURN
C-----
      IF(dt%BRICK_DEL_DEFV_MAX>zero .AND. (dt%BRICK_DEL_DEFV_MAX<vdefmax 
     .   .OR.vdefmax==zero) ) vdefmax = dt%BRICK_DEL_DEFV_MAX 
      IF(dt%BRICK_DEL_ASP_MAX>zero .AND. ( dt%BRICK_DEL_ASP_MAX<aspmax 
     .   .OR.aspmax==zero) ) aspmax = dt%BRICK_DEL_ASP_MAX 
      c_min = one
      c_max = one
C--- penta6      
      IF (nnod ==6) THEN
       c_max = fourth*sqr3
       c_min = one/c_max
      END IF
C
      IF ((vdefmin+vdefmax) >zero) THEN
        DO i=1,nel
          IF (offg(i)==zero) cycle
          def_v(i) = volg(i)/volg0(i)
        END DO
      END IF
      IF (vdefmin >zero) THEN
       icount = 0
       DO i=1,nel
        IF (offg(i)==zero) cycle
        IF (def_v(i) < vdefmin) THEN
         offg(i) = zero
         icount=icount+1
         list(icount)=i
        END IF
       END DO
       IF (icount > 0) THEN
#include "lockon.inc"
          WRITE(iout,1001)
          WRITE(istdo,1001)
        DO j=1,icount
          i=list(j)
          WRITE(iout,'(6X,I10,1PG20.13)')ngl(i),def_v(i)
          WRITE(istdo,'(6X,I10,1PG20.13)')ngl(i),def_v(i)
        ENDDO
         WRITE(iout,*)
         WRITE(istdo,*)
#include "lockoff.inc"
         idel7nok = 1
       END IF !(ICOUNT > 0) THEN
      END IF 
C       
      IF (vdefmax >zero) THEN
       icount = 0
       DO i=1,nel
        IF (offg(i)==zero) cycle
        IF (def_v(i) > vdefmax) THEN
         offg(i) = zero
         icount=icount+1
         list(icount)=i
        END IF
       END DO
        IF (icount > 0) THEN
#include "lockon.inc"
          WRITE(iout,1002)
          WRITE(istdo,1002)
         DO j=1,icount
          i=list(j)
          WRITE(iout,'(6X,I10,1PG20.13)')ngl(i),def_v(i)
          WRITE(istdo,'(6X,I10,1PG20.13)')ngl(i),def_v(i)
         ENDDO
         WRITE(iout,*)
         WRITE(istdo,*)
#include "lockoff.inc"
         idel7nok = 1
        END IF !(ICOUNT > 0) THEN
      END IF 
C--- Hexa : APS_r=lmax/lmin lmax~sqrt(L_SH); lmin~A/lmax  -> 
C---        APS_r~lmax^2/A    
        IF (aspmax>zero) THEN
          icount = 0
          DO i=1,nel
           IF (offg(i)==zero) cycle
           aps_r(i) = c_max*l_sh(i)/area(i)
           IF (aps_r(i) > aspmax) THEN
            offg(i) = zero
            icount=icount+1
            list(icount)=i
           END IF
          END DO
          IF (icount > 0) THEN
#include "lockon.inc"
              WRITE(iout,1003)
              WRITE(istdo,1003)
            DO j=1,icount
              i=list(j)
              WRITE(iout,'(6X,I10,1PG20.13)')ngl(i),aps_r(i)
              WRITE(istdo,'(6X,I10,1PG20.13)')ngl(i),aps_r(i)
            ENDDO
             WRITE(iout,*)
             WRITE(istdo,*)
#include "lockoff.inc"
            idel7nok = 1
          END IF !(ICOUNT > 0) THEN
        END IF
C
C---        TET_c =1/ASP_r
        IF (colmin>zero) THEN
          icount = 0
          DO i=1,nel
           IF (offg(i)==zero) cycle
           tet_colla(i) = c_min *area(i)/l_sh(i)
           IF (tet_colla(i) < colmin) THEN
            offg(i) = zero
            icount=icount+1
            list(icount)=i
           END IF
          END DO
          IF (icount > 0) THEN
#include "lockon.inc"
             WRITE(iout,1004)
             WRITE(istdo,1004)
           DO j=1,icount
             i=list(j)
             WRITE(iout,'(6X,I10,1PG20.13)')ngl(i),tet_colla(i)
             WRITE(istdo,'(6X,I10,1PG20.13)')ngl(i),tet_colla(i)
           ENDDO
            WRITE(iout,*)
            WRITE(istdo,*)
#include "lockoff.inc"
            idel7nok = 1
          END IF !(ICOUNT > 0) THEN
        END IF
C
      RETURN
 1001 FORMAT(/
     .    'THE FOLLOWING THICK-SHELL ELEMENTS WILL BE DELETED BY MINIMUM VOLUME RATIO' /)
 1002 FORMAT(/
     .    'THE FOLLOWING THICK-SHELL ELEMENTS WILL BE DELETED BY MAXIMUM VOLUME RATIO' /)
 1003 FORMAT(/
     .    'THE FOLLOWING THICK-SHELL ELEMENTS WILL BE DELETED BY MAXIMUM ASPECT RATIO' /)
 1004 FORMAT(/
     .    'THE FOLLOWING THICK-SHELL ELEMENTS WILL BE DELETED BY MINIMUM COLLAPSE RATIO' /)
      END