volp_lfluid.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    volp_lfluid        ../engine/source/airbag/volp_lfluid.F
!||--- called by ------------------------------------------------------
!||    monvol0            ../engine/source/airbag/monvol0.F
!||--- uses       -----------------------------------------------------
!||    finter_mixed_mod   ../engine/source/tools/finter_mixed.F90
!||    output_mod         ../common_source/modules/output/output_mod.f90
!||    python_funct_mod   ../common_source/modules/python_mod.F90
!||====================================================================
      SUBROUTINE volp_lfluid(IVOLU, RVOLU, VOL, FSAV, NPC, TF, PMAIN, OUTPUT,PYTHON, NFUNCT)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE python_funct_mod
      USE finter_mixed_mod
      USE output_mod , ONLY : output_
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com06_c.inc"
#include      "com08_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NPC(*),IVOLU(*), PMAIN
      my_real tf(*), rvolu(*), fsav(*), vol
      TYPE(OUTPUT_),INTENT(INOUT) :: OUTPUT
      TYPE(python_), intent(inout) :: PYTHON
      INTEGER, intent(in) :: NFUNCT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER IFUNCT
 
      my_real p0, vol0,  area, veps, vinc, pold, pext, vold, pres, q,  qold, dv,   xfun
      my_real scalef, bulk, pmax, gmass, dmass, rhoi
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
 
      !pressure calculation
      pext = rvolu(3)
      vol0 = rvolu(4)
      vinc = rvolu(5)
      pold = rvolu(12)
      vold = rvolu(16)
      veps = rvolu(17)
      area = rvolu(18)
      qold = rvolu(23)
      gmass = rvolu(20)
      rhoi = rvolu(34)
 
C   BULK
      ifunct = ivolu(21)
      scalef = rvolu(35)
      IF(ifunct == 0) THEN
         bulk = scalef    
      ELSE
         bulk = scalef * finter_mixed(python,nfunct,ifunct,tt,npc,tf)
      ENDIF
 
C   FLUID MASS IN
      ifunct = ivolu(22)
      scalef = rvolu(36)
      IF(ifunct == 0) THEN
         dmass = scalef * dt1
      ELSE
         dmass = scalef * finter_mixed(python,nfunct,ifunct,tt,npc,tf) * dt1
      ENDIF 
      gmass = gmass + dmass
      rvolu(54)=rvolu(54)+dmass
 
C   FLUID MASS OUT (time)
      ifunct = ivolu(23)
      scalef = rvolu(37)
      IF(ifunct == 0) THEN
         dmass = scalef * dt1
      ELSE
         dmass = scalef * finter_mixed(python,nfunct,ifunct,tt,npc,tf) * dt1
      ENDIF 
      gmass = gmass - dmass
 
C   FLUID MASS OUT (pressure)
      ifunct = ivolu(24)
      scalef = rvolu(38)
      IF(ifunct == 0) THEN
         dmass = scalef * dt1
      ELSE
         dmass = scalef * finter_mixed(python,nfunct,ifunct,pold,npc,tf) * dt1
      ENDIF 
      gmass = gmass - dmass
 
C   P0
      ifunct = ivolu(25)
      scalef = rvolu(39)
      IF(ifunct == 0) THEN
         p0 = scalef    
      ELSE
         p0 = scalef * finter_mixed(python,nfunct,ifunct,tt,npc,tf)
      ENDIF
 
C   PMAX
      ifunct = ivolu(26)
      scalef = rvolu(40)
      IF(ifunct == 0) THEN
         pmax = scalef    
      ELSE
         pmax = scalef * finter_mixed(python,nfunct,ifunct,tt,npc,tf)
      ENDIF
 
      vol0 = gmass / rhoi
      vol = vol + veps
      xfun = (vol0-vinc)/(vol-vinc)
      pres = bulk * max(zero,log(xfun)) + p0
      pres = min(pres,pmax)
      q = zero
 
      IF (ispmd+1==pmain) THEN
        dv=vol-vold
        output%TH%WFEXT=output%TH%WFEXT+(half*(q+qold+pres+pold))*dv
        fsav(1)=gmass
        fsav(2)=vol
        fsav(3)=pres
        fsav(4)=area
        fsav(5)=zero
        fsav(6)=zero
        fsav(7)=zero
        fsav(8)=zero
        fsav(9)=zero
        fsav(10)=zero
        fsav(11)=zero
        fsav(12)=zero
        fsav(13)=zero
        fsav(14)=zero
        fsav(15)=rvolu(54)
        fsav(16)=zero
      ENDIF
C
      rvolu(16)=vol
      rvolu(12)=pres
      rvolu(20)=gmass
      rvolu(23)=q
C
      RETURN
      END