w_dampvrel.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    w_dampvrel     ../starter/source/restart/ddsplit/w_dampvrel.F
!||--- called by ------------------------------------------------------
!||    ddsplit        ../starter/source/restart/ddsplit/ddsplit.F
!||--- calls      -----------------------------------------------------
!||    nlocal         ../starter/source/spmd/node/ddtools.F
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE w_dampvrel(DAMPR,IGRNOD,IDAMP_VREL_L,NDAMP_VREL_L,LEN_IA,
     .                      NGRNOD,NDAMP,NRDAMP,NSPMD)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE groupdef_mod     
C---------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NDAMP_VREL_L,NGRNOD,NDAMP,NRDAMP,NSPMD
      INTEGER, INTENT(IN) :: IDAMP_VREL_L(NDAMP)
      INTEGER, INTENT(INOUT) :: LEN_IA
      my_real, INTENT(IN) :: dampr(nrdamp,ndamp)
      TYPE (GROUP_),DIMENSION(NGRNOD),INTENT(IN) :: IGRNOD
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER  NLOCAL
      EXTERNAL nlocal 
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,IGR,PROC,PMAIN,CPT
      INTEGER FR_DAMP_VREL(NSPMD+2,NDAMP_VREL_L),ID_DAMP_VREL(NDAMP_VREL_L)
C----------------------------------------------- 
C
      pmain = 1
      cpt = 0
      DO i=1,ndamp
        IF (idamp_vrel_l(i) > 0) THEN
          cpt = cpt+1  
          id_damp_vrel(cpt) = i    
        ENDIF      
      ENDDO        
C
      fr_damp_vrel(1:nspmd+2,1:ndamp_vrel_l) = 0
      DO i=1,ndamp_vrel_l
        igr   = nint(dampr(2,id_damp_vrel(i)))
C--     Tag of procs having nodes in damping                 
        DO proc = 1,nspmd
          DO j = 1,igrnod(igr)%NENTITY
            IF (nlocal(igrnod(igr)%ENTITY(j),proc)==1) THEN
              fr_damp_vrel(proc,i) = 1   
            ENDIF        
          ENDDO 
        ENDDO
C--     Find main proc for damping (smallest proc id)          
        DO proc = 1,nspmd
          IF (fr_damp_vrel(proc,i) == 1) THEN
            pmain =  proc
            exit
          ENDIF   
        ENDDO
        fr_damp_vrel(nspmd+1,i) = 0 ! Not used for now
        fr_damp_vrel(nspmd+2,i) = pmain
      ENDDO
C
      CALL write_i_c(id_damp_vrel,ndamp_vrel_l)
      len_ia = len_ia + ndamp_vrel_l
C      
      CALL write_i_c(fr_damp_vrel,ndamp_vrel_l*(nspmd+2)) 
      len_ia = len_ia + ndamp_vrel_l*(nspmd+2)
C                
! --------------------------------------
      RETURN
      END