w_icnds10.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    w_icnds10   ../starter/source/restart/ddsplit/w_icnds10.F
!||--- called by ------------------------------------------------------
!||    ddsplit     ../starter/source/restart/ddsplit/ddsplit.F
!||--- calls      -----------------------------------------------------
!||    nlocal      ../starter/source/spmd/node/ddtools.F
!||====================================================================
      SUBROUTINE w_icnds10(ICNDS10,ITAGND,PROC,NODLOCAL,NS10E_L,
     .                     ITABCNDM,NBDDCNDM,NUMNOD_L,LEN_IA,itab)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ICNDS10(3,*),PROC,NS10E_L,ITAGND(*),NODLOCAL(*),LEN_IA,
     .        itabcndm(*),nbddcndm,numnod_l,itab(*)
C-----------------------------------------------
C   F u n c t i o n
C-----------------------------------------------
      INTEGER  NLOCAL
      EXTERNAL nlocal
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER N, NN, K, J, L,P, N_L,N1,N2, ILP,PROCI,NG
      INTEGER ICNDS10_L(3,NS10E_L),IFRONT(NUMNOD_L),NF
C
      proci = proc + 1
C-----only edge in front (>0) is tagged      
      ifront(1:numnod_l)=0
      n_l = 0
      DO n = 1, ns10e
       nn = icnds10(1,n)
       IF(nlocal(nn,proci)==1.AND.itagnd(nn)<=ns10e)THEN
         n1 = icnds10(2,n)
         n2 = icnds10(3,n)
         n_l = n_l + 1
         icnds10_l(1,n_l) = nodlocal(nn)
         icnds10_l(2,n_l) = nodlocal(n1)
         icnds10_l(3,n_l) = nodlocal(n2)
         nf = 0
         DO p = 1, nspmd
          nf = nf +nlocal(nn,p)           
         ENDDO
         IF (nf >1) THEN
          ifront(nodlocal(n1))=1
          ifront(nodlocal(n2))=1
         END IF
         IF (itagnd(nn) <0) icnds10_l(1,n_l)= -icnds10_l(1,n_l)
 100    CONTINUE         
       ENDIF
      ENDDO
      IF (n_l /= ns10e_l) print *,'**error in W_ICNDS10,N_L,NS10E_L=',n_l,ns10e_l
C
      l = 3*n_l
      CALL write_i_c(icnds10_l,l)
      len_ia = len_ia + l
C      
      IF(nbddcndm>0) THEN
          itabcndm(1:numnod_l) = 0
          ilp=0
          DO n = 1, n_l
            n1 = icnds10_l(2,n)
            n2 = icnds10_l(3,n)
            IF(itabcndm(n1)==0.AND.ifront(n1)>0) THEN
              ilp = ilp + 1
              itabcndm(n1) = ilp
            ENDIF
            IF(itabcndm(n2)==0.AND.ifront(n2)>0) THEN
              ilp = ilp + 1
              itabcndm(n2) = ilp
            ENDIF
          END DO
      ENDIF
C
      RETURN
      END