w_iloadp.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    w_iloadp    ../starter/source/restart/ddsplit/w_iloadp.F
!||--- called by ------------------------------------------------------
!||    ddsplit     ../starter/source/restart/ddsplit/ddsplit.F
!||--- calls      -----------------------------------------------------
!||====================================================================
      SUBROUTINE w_iloadp(
     .  ILOADP,LLOADP,NODLOCAL,PROC,LLLOADP_L,LEN_IA,P,CEP, ITAB,
     .  NUMCONV,NUMRADIA,NFXFLUX)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(IN) :: NUMCONV
      INTEGER ,INTENT(IN) :: NUMRADIA
      INTEGER ,INTENT(IN) :: NFXFLUX
      INTEGER PROC, LEN_IA, LLLOADP_L,P,
     .        iloadp(sizloadp,*), lloadp(*),nodlocal(*),
     .        cep(*)
      INTEGER,INTENT(IN) :: ITAB(NUMNOD)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J, IAD, IADL, NL, N, NLL, NN, IGRTMP(SIZLOADP,NLOADP),
     .        LGRTMP(LLLOADP_L),OFF,N1,N2,N3,N4
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      off = numelc+numeltg+numels+numelq+numelt+numelp+numelr+numelx+nconld+numconv+numradia+nfxflux
      iadl = 1
      DO i = 1, nloadp
        nl = iloadp(1,i)
        iad= iloadp(4,i)
        DO j = 1, sizloadp
          igrtmp(j,i) = iloadp(j,i)
        ENDDO
        nll = 0
        DO j = 1, nl/4
          n1= lloadp(iad+(j-1)*4)
          n2= lloadp(iad+(j-1)*4+1)
          n3= lloadp(iad+(j-1)*4+2)
          n4= lloadp(iad+(j-1)*4+3)
          IF(cep(j+off)==proc) THEN
            lgrtmp(iadl+nll) = nodlocal(n1)
            lgrtmp(iadl+nll+1) = nodlocal(n2)
            lgrtmp(iadl+nll+2) = nodlocal(n3)
            IF (n4 == 0) THEN
              lgrtmp(iadl+nll+3) = 0
            ELSE
              lgrtmp(iadl+nll+3) = nodlocal(n4)
            ENDIF
            nll = nll + 4
          ENDIF
        ENDDO
        igrtmp(1,i) = nll
        igrtmp(4,i) = iadl
        iadl = iadl+nll
        off = off + nl/4
      ENDDO
 
      CALL write_i_c(igrtmp,sizloadp*nloadp)
      CALL write_i_c(lgrtmp,llloadp_l)
      len_ia = len_ia + sizloadp*nloadp + iadl-1
 
      RETURN
      END