w_ing2loc.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    w_ing2loc              ../starter/source/restart/ddsplit/w_ing2loc.F
!||--- called by ------------------------------------------------------
!||    ddsplit                ../starter/source/restart/ddsplit/ddsplit.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE w_ing2loc(
     .  ALE_CONNECTIVITY,ELEMID_L,NUMNOD,NODGLOB,NODLOCAL,NUMNOD_L,LEN_IA,NWALE)
      USE ale_connectivity_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NUMNOD, NUMNOD_L,LEN_IA,
     .        nodglob(*),  nodlocal(*), elemid_l(*), nwale
      TYPE(t_ale_connectivity), INTENT(IN) :: ALE_CONNECTIVITY
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J, NI, LEN, IAD1, IAD2
      INTEGER, DIMENSION(:), ALLOCATABLE :: NB_CONNECT, CONNECTED, IAD_CONNECT, ADSKY
 
      ALLOCATE(iad_connect(numnod_l + 1), nb_connect(numnod_l), adsky(numnod_l))
      IF (ale_connectivity%has_nn_connect) THEN
         DO i = 1, numnod_l
            iad1 = ale_connectivity%NN_CONNECT%IAD_CONNECT(nodglob(i))
            iad2 = ale_connectivity%NN_CONNECT%IAD_CONNECT(nodglob(i) + 1) - 1
            nb_connect(i) = 0
            DO j = iad1, iad2
               IF (nodlocal(ale_connectivity%NN_CONNECT%CONNECTED(j)) > 0) THEN
                  nb_connect(i) = nb_connect(i) + 1
               ENDIF
            ENDDO
         ENDDO
 
         iad_connect(1) = 1
         DO i = 2, numnod_l + 1
            iad_connect(i) = iad_connect(i - 1) + nb_connect(i - 1)
         ENDDO
 
         len = iad_connect(numnod_l + 1)
         ALLOCATE(connected(len))
         connected(1:len) = 0
         DO i = 1, numnod_l
            adsky(i) = iad_connect(i)
         ENDDO
         
 
         DO i = 1, numnod_l
            iad1 = ale_connectivity%NN_CONNECT%IAD_CONNECT(nodglob(i))
            iad2 = ale_connectivity%NN_CONNECT%IAD_CONNECT(nodglob(i) + 1) - 1
            DO j = iad1, iad2
               IF (nodlocal(ale_connectivity%NN_CONNECT%CONNECTED(j)) > 0) THEN
                  connected(adsky(i)) = nodlocal(ale_connectivity%NN_CONNECT%CONNECTED(j))
                  adsky(i) = adsky(i) + 1
               ENDIF
            ENDDO
         ENDDO
 
         CALL write_i_c(iad_connect, numnod_l + 1)
         CALL write_i_c(connected, len)
         
         len_ia = len_ia + numnod_l + 1 + len
      ENDIF
 
      IF (ale_connectivity%has_ne_connect) THEN
C     Node - element connectivity
         IF (ALLOCATED(connected)) DEALLOCATE(connected)
         DO i = 1, numnod_l
            iad1 = ale_connectivity%NE_CONNECT%IAD_CONNECT(nodglob(i))
            iad2 = ale_connectivity%NE_CONNECT%IAD_CONNECT(nodglob(i) + 1) - 1
            nb_connect(i) = 0
            DO j = iad1, iad2
               IF (elemid_l(ale_connectivity%NE_CONNECT%CONNECTED(j)) > 0) THEN
                  nb_connect(i) = nb_connect(i) + 1
               ENDIF
            ENDDO
         ENDDO
 
         iad_connect(1) = 1
         DO i = 2, numnod_l + 1
            iad_connect(i) = iad_connect(i - 1) + nb_connect(i - 1)
         ENDDO
 
         len = iad_connect(numnod_l + 1)
         ALLOCATE(connected(len))
 
         DO i = 1, numnod_l
            adsky(i) = iad_connect(i)
         ENDDO
         
 
         DO i = 1, numnod_l
            iad1 = ale_connectivity%NE_CONNECT%IAD_CONNECT(nodglob(i))
            iad2 = ale_connectivity%NE_CONNECT%IAD_CONNECT(nodglob(i) + 1) - 1
            DO j = iad1, iad2
               IF (elemid_l(ale_connectivity%NE_CONNECT%CONNECTED(j)) > 0) THEN
                  connected(adsky(i)) = elemid_l(ale_connectivity%NE_CONNECT%CONNECTED(j))
                  adsky(i) = adsky(i) + 1
               ENDIF
            ENDDO
         ENDDO
 
         CALL write_i_c(iad_connect, numnod_l + 1)
         CALL write_i_c(connected, len)
         
         len_ia = len_ia + numnod_l + 1 + len
      ENDIF 
 
      IF (ALLOCATED(iad_connect)) DEALLOCATE(iad_connect)
      IF (ALLOCATED(connected)) DEALLOCATE(connected)
      IF (ALLOCATED(adsky)) DEALLOCATE(adsky)
      IF (ALLOCATED(nb_connect)) DEALLOCATE(nb_connect)
 
      RETURN
      END