w_rwall.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    w_rwall     ../starter/source/restart/ddsplit/w_rwall.F
!||--- called by ------------------------------------------------------
!||    ddsplit     ../starter/source/restart/ddsplit/ddsplit.F
!||--- calls      -----------------------------------------------------
!||    nlocal      ../starter/source/spmd/node/ddtools.F
!||====================================================================
      SUBROUTINE w_rwall(NPRW   ,LPRW     ,RWL   ,
     +                   CEP     ,CEL     ,NODLOCAL,PROC  ,
     +                   NSLAW_L,NESLAW_L ,NUMNOD_L,LEN_IA)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------  
 
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
       INTEGER  PROC, LEN_IA, NSLAW_L, NESLAW_L,  NUMNOD_L,
     .          LPRW(*), NPRW(*), 
     .          cep(*), cel(*), nodlocal(*)
       my_real
     .          rwl(nrwlp,*)
C-----------------------------------------------
C   F u n c t i o n
C-----------------------------------------------
      INTEGER  NLOCAL
      EXTERNAL NLOCAL    
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER NSL, I, K, KK, N, NN, N1, N2, N3, N4, IE, NE, ITY, ILW,
     .        ILP, NSL_L, NE_L, IR, MSR
      INTEGER, DIMENSION(:),ALLOCATABLE :: LPRW_L, NPRW_L
C
      IF(nrwall>0) THEN
        ALLOCATE(nprw_l(nnprw*nrwall))
        DO n = 1, nrwall
          nprw_l(n) = 0
          DO kk = 1, nnprw-1
            nprw_l(kk*nrwall+n) = nprw(kk*nrwall+n)
          ENDDO
          n3 = 2*nrwall+n
          msr = nprw(n3)
          IF(msr/=0) THEN
            IF(nlocal(msr,proc+1)==1) THEN
              nprw_l(n3) = nodlocal(msr)
            ELSE
C noeud non present sur le proc, MSR a 0 pour eviter les comms.
              nprw_l(n3) = 0
            ENDIF
          ENDIF
        ENDDO
C
        IF(nslaw_l+neslaw_l>0) THEN
          ALLOCATE(lprw_l(nslaw_l+neslaw_l))
          k = 0
          ilp = 0
          DO n = 1, nrwall
            n2=n +nrwall
            n3=n2+nrwall
            n4=n3+nrwall
            nsl=nprw(n)
            ity=nprw(n4)
            nsl_l = 0
            DO kk = 1, nsl
              nn = lprw(k+kk)
              IF(nlocal(nn,proc+1)==1)THEN
                nsl_l = nsl_l + 1
                lprw_l(ilp+nsl_l) = nodlocal(nn)
              ENDIF
            ENDDO
            ilp = ilp + nsl_l
            k = k + nsl
            nprw_l(n) = nsl_l
            IF(ity==-1)THEN
              ne = nint(rwl(8,n))
              ne_l = 0
              IF(ne/=0) THEN
                DO kk = 1, ne
                  ie = lprw(k+kk)/10
                  ir = lprw(k+kk)-10*ie
                  IF(cep(ie)==proc)THEN
                    ne_l = ne_l+1
                    lprw_l(ilp+ne_l) = cel(ie)*10+ir
                  ENDIF
                ENDDO
                ilp = ilp + ne_l
                k = k + ne
              ENDIF
            ENDIF
          ENDDO
        ENDIF
C
        CALL write_i_c(nprw_l,nnprw*nrwall)
        CALL write_i_c(lprw_l,nslaw_l+neslaw_l)
        len_ia = len_ia + nnprw*nrwall + nslaw_l+neslaw_l
        IF(nslaw_l+neslaw_l>0)DEALLOCATE(lprw_l)
        DEALLOCATE(nprw_l)
C
      ENDIF
C
      RETURN
      END