write_th.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    write_th   ../engine/source/output/th/write_th.F
!||--- called by ------------------------------------------------------
!||    hist2      ../engine/source/output/th/hist2.F
!||--- calls      -----------------------------------------------------
!||    wrtdes     ../engine/source/output/th/wrtdes.F
!||--- uses       -----------------------------------------------------
!||    th_mod     ../engine/share/modules/th_mod.F
!||====================================================================
        SUBROUTINE write_th(N,NSPMD,NN,NVAR,ITTYP,
     1                      ELTYPE_STRUCT,WA_ELTYPE_P0)
        USE th_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        INTEGER, INTENT(in) :: N,NSPMD,NN,NVAR,ITTYP
        TYPE(th_wa_real), INTENT(in) ::WA_ELTYPE_P0
        TYPE(th_proc_type), INTENT(in) :: ELTYPE_STRUCT
!       -*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-**-*-*-*-*-*-*-*-*-*-*-*-*
!       N : integer ; current TH group 
!       NSPMD : integer ; number of MPI domains
!       NN : integer, number of element group
!       NVAR : integer ; number of value per element group
!       ITTYP : integer ; type of TH group
!       -*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-*-**-*-*-*-*-*-*-*-*-*-*-*-*
C-----------------------------------------------
C   L o c a l  V a r i a b l e s
C-----------------------------------------------
        LOGICAL :: BOOL
        INTEGER :: I,J,K,II,IJK,LOCAL_SIZE
        INTEGER :: NEXT,CURRENT,SIZE_N
        INTEGER :: CURRENT_J,REST
        my_real, DIMENSION(:), ALLOCATABLE :: wa_local
!       ----------------------------------------
!$COMMENT
!       WRITE_TH_COQ description
!       write all the values for shell element
!       and for a given group N by the PROC0
!       
!       WRITE_TH_COQ organization :
!        * loop over the NSPMD processor and:
!           - check if a processor must write its values (SIZE_N>0)
!           - compute the number of group for a given processor (REST)
!           - compute the position in the th file(current_j)
!           - initialization of the written values WA_LOCAL with the position CURRENT_J + J
!        * write the WA_LOCAL values 
!$ENDCOMMENT
 
!       allocation + initialization of local array
        ALLOCATE( wa_local(nn*nvar) )
        wa_local(1:nn*nvar) = zero
 
 
 
        DO i=1,nspmd
            local_size = eltype_struct%TH_PROC(i)%TH_ELM_SIZE
            bool=.true.
            DO k=1,local_size
                IF(bool.EQV..true.) THEN
                    IF(eltype_struct%TH_PROC(i)%TH_ELM(k,2)==n) THEN
                        bool=.false.
                        ijk=k
                    ENDIF
                ENDIF
            ENDDO
            IF(bool.EQV..false.) THEN
                current = eltype_struct%TH_PROC(i)%TH_ELM(ijk,1) !   index of the current proc and N
                next = eltype_struct%TH_PROC(i)%TH_ELM(ijk+1,1)  !   index of the next proc and N
                size_n = next-current   !   nbr of WA element of the current proc and for the current N
!                IF( SIZE_N>0 ) THEN     !   if SIZE_N>0, must write some data
                rest = size_n / (nvar+1)    ! nbr of th group for the current proc
                ii = 0
                DO k=1,rest
                    current_j = nint(wa_eltype_p0%WA_REAL( current+k*(nvar+1) ) ) ! the position in WA_LOCAL for the current TH 
                    DO j=1,nvar   
                        ii = ii + 1   
                        wa_local(current_j+j) = wa_eltype_p0%WA_REAL(current+ii)                
                    ENDDO
                    ii = ii + 1  ! skip the NVAR+1 value = the position in WA_LOCAL
                ENDDO
!                ENDIF
            ENDIF
        ENDDO
 
!       write the data
        CALL wrtdes(wa_local,wa_local,nn*nvar,ittyp,1)
!       deallocation
        DEALLOCATE( wa_local )
 
!       ----------------------------------------
        RETURN
        END SUBROUTINE write_th
!       ----------------------------------------