ale51_antidiff2.F File Reference

#include "implicit_f.inc"
#include "spmd_c.inc"
#include "com04_c.inc"
#include "com08_c.inc"
#include "vect01_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	ale51_antidiff2 (flux, ale_connect, alph, vol, ixq, flux_vois, n4_vois, itab, itrimat, segvar)

Function/Subroutine Documentation

ale51_antidiff2()

subroutine ale51_antidiff2	(		flux,
		type(t_ale_connectivity), intent(in)	ale_connect,
			alph,
			vol,
		integer, dimension(nixq,numelq)	ixq,
			flux_vois,
		integer, dimension(numelq+nqvois,4)	n4_vois,
		integer, dimension(numnod)	itab,
		integer, intent(in)	itrimat,
		type(t_segvar), intent(in)	segvar )

Definition at line 33 of file ale51_antidiff2.F.

C-----------------------------------------------
C   D e c r i p t i o n
C-----------------------------------------------
C
C ** Warning, this formulation (for volume fractions) using \eta_3 parameter from /UPWIND option is not conservative. 
C It was marked as OBSOLETE. Forget it and use MUSCL instead
C
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
       USE segvar_mod     
       USE ale_connectivity_mod
       USE ale_mod
       use element_mod , only : nixq
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "spmd_c.inc"
#include      "com04_c.inc"
#include      "com08_c.inc"
#include      "vect01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IXQ(NIXQ,NUMELQ),N4_VOIS(NUMELQ+NQVOIS,4),ITAB(NUMNOD)
      INTEGER,INTENT(IN) :: ITRIMAT
      my_real flux(4,*),alph(*),vol(*),flux_vois(numelq+nqvois,6)
      TYPE(t_segvar),INTENT(IN) :: SEGVAR     
      TYPE(t_ale_connectivity), INTENT(IN) :: ALE_CONNECT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,II,K,JV(6),KV(6),IAD2,IAD3
      my_real
     .   vol0,av0,uav0,alphi,ualphi,aaa,ff(6),udt,phi0
C-----------------------------------------------
C   S o u r c e   L i n e s 
C-----------------------------------------------  
      jv = -huge(jv(1))
      kv = -huge(kv(1))
      ff = -huge(ff(1))
C-----------------------------------------------
C     WET SURFACE
C-----------------------------------------------
      IF(dt1 > zero)THEN
        udt = one/dt1
      ELSE
        udt = zero
      ENDIF
C
      DO i=lft,llt
        ii   = i + nft
        iad2 = ale_connect%ee_connect%iad_connect(ii)
        vol0 = vol(i)*udt
        av0  = alph(ii) * vol0
        uav0 = vol0 - av0
        alphi  = zero
        ualphi = zero 
        phi0 = zero  
C-----------------------------------------------
C       adjacent face & total outgoing volume flux 
C-----------------------------------------------
        DO k=1,4
          IF(flux(k,ii) > zero)THEN
            jv(k) = ale_connect%ee_connect%connected(iad2 + k - 1)
            kv(k) = k
            IF(jv(k) == 0)THEN
              jv(k)  = ii
              ff(k)  = alph(ii)*flux(k,ii)
            ELSEIF(jv(k) < 0)THEN
              !case <0 : ebcs (-IVOIS is then segment identifier)               
              ff(k)  = segvar%PHASE_ALPHA(itrimat,-jv(k))  *flux(k,ii)         
            ELSEIF(jv(k) <= numelq)THEN
               iad3 = ale_connect%ee_connect%iad_connect(jv(k))
              IF(ale_connect%ee_connect%connected(iad3 + 1 - 1) == ii) kv(k) = 1
              IF(ale_connect%ee_connect%connected(iad3 + 2 - 1) == ii) kv(k) = 2
              IF(ale_connect%ee_connect%connected(iad3 + 3 - 1) == ii) kv(k) = 3
              IF(ale_connect%ee_connect%connected(iad3 + 4 - 1) == ii) kv(k) = 4
              ff(k)  = alph(jv(k))*flux(k,ii)
            ELSE
              !spmd
              ff(k)  = alph(jv(k))*flux(k,ii)              
            ENDIF
c           outgoing volume flux (estimation)
            alphi  = alphi  + ff(k)
c           initial outgoing flux
            phi0 = phi0 + flux(k,ii) 
          ENDIF
        ENDDO
c       outgoing rest
        ualphi = phi0 - alphi 
C-----------------------------------------------
C       outgoing volume flux by face
C-----------------------------------------------
        IF(alphi > av0.AND.av0 > zero)THEN
C-----------------------------------------------
C         outgoing volume flux > volume
C-----------------------------------------------
          aaa = av0 / alphi
          DO k=1,4
            IF(flux(k,ii) > zero)THEN
              ff(k) = ff(k) * aaa
            ENDIF
          ENDDO
       ELSEIF(ualphi > uav0.AND.uav0 > zero)THEN
 
C-----------------------------------------------
C         outgoing rest > available volume
C-----------------------------------------------
          aaa = uav0/ualphi
          DO k=1,4
            IF(flux(k,ii) > zero)THEN
              ff(k) = flux(k,ii) + (ff(k)-flux(k,ii))*aaa
            ENDIF
          ENDDO
c        ELSE
        ENDIF
C-----------------------------------------------
C         outgoing flux
C-----------------------------------------------
          DO k=1,4
            IF(flux(k,ii) > zero)THEN
              ff(k) = 0.5* (ff(k)*(1.-ale%UPWIND%UPWSM)
     .                    + alph(ii)*flux(k,ii)*(1.+ale%UPWIND%UPWSM))
              flux(k,ii) = ff(k)
              IF(jv(k) < 0)THEN
                !nothing to do
              ELSEIF(jv(k) <= numelq)THEN
                flux(kv(k),jv(k)) = -flux(k,ii)
              ELSE
                flux_vois(ii,k) = flux(k,ii)
                n4_vois(ii,1) = itab(ixq(2,ii))
                n4_vois(ii,2) = itab(ixq(3,ii))
                n4_vois(ii,3) = itab(ixq(4,ii))
                n4_vois(ii,4) = itab(ixq(5,ii))
              ENDIF
            ENDIF
          ENDDO
C-----------------------------------------------
C         incoming volume flux from EBCS
C-----------------------------------------------
          IF(nsegflu > 0)THEN
             iad2 = ale_connect%ee_connect%iad_connect(ii)
            DO k=1,4
              IF(flux(k,ii) < zero .AND. ale_connect%ee_connect%connected(iad2 + k - 1) < 0)THEN
                flux(k,ii) = segvar%PHASE_ALPHA(itrimat,-ale_connect%ee_connect%connected(iad2 + k - 1))*flux(k,ii)
              ENDIF
            ENDDO       
          ENDIF   
C-------------
      enddo! next I
C-----------------------------------------------
      RETURN