check_pthickfail.F File Reference

#include "implicit_f.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	check_pthickfail (elbuf_str, mat_param, iparg, geo, ipm, stack, igeo, nummat, numgeo, ngroup, nparg, npropmi, npropgi, npropg)

Function/Subroutine Documentation

check_pthickfail()

subroutine check_pthickfail	(	type (elbuf_struct_), dimension(ngroup)	elbuf_str,
		type (matparam_struct_), dimension(nummat), intent(inout)	mat_param,
		integer, dimension(nparg,ngroup), intent(in)	iparg,
		dimension(npropg,numgeo), intent(in)	geo,
		integer, dimension(npropmi,nummat), intent(in)	ipm,
		type (stack_ply)	stack,
		integer, dimension(npropgi,numgeo), intent(in)	igeo,
		integer, intent(in)	nummat,
		integer, intent(in)	numgeo,
		integer, intent(in)	ngroup,
		integer, intent(in)	nparg,
		integer, intent(in)	npropmi,
		integer, intent(in)	npropgi,
		integer, intent(in)	npropg )

Definition at line 33 of file check_pthickfail.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE mat_elem_mod    
      USE stack_mod
      USE message_mod         
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: IPARG(NPARG,NGROUP),NPROPG,
     .                       IPM(NPROPMI,NUMMAT),IGEO(NPROPGI,NUMGEO),
     .                       NUMMAT,NUMGEO,NGROUP,NPARG,NPROPMI,NPROPGI
      my_real, INTENT(IN) :: geo(npropg,numgeo)
      TYPE (ELBUF_STRUCT_) ,DIMENSION(NGROUP) :: ELBUF_STR
      TYPE (STACK_PLY) :: STACK
      TYPE (MATPARAM_STRUCT_) ,DIMENSION(NUMMAT) ,INTENT(INOUT) :: MAT_PARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: NG,ITY,IGTYP,PID,NLAY,IFL,NFAIL,NPTTOT,IL,
     .           IMAT,ISUBSTACK,IPTHKLY,PROP_ID,MAT_ID
      my_real :: p_thickg,p_thickfail,pthkly
c
      !===============================================================================
      ! CHECK PTHICKFAIL VALUE FOR SHELL PROPERTIES
      !===============================================================================
      ! Loop over groups
      DO ng = 1,ngroup
c
        ! Group parameters
        igtyp     = iparg(38,ng) ! -> Property type 
        pid       = iparg(62,ng) ! -> Property internal ID 
        isubstack = iparg(71,ng) ! -> Substack number
c
        ! Check group property
        IF ((igtyp ==  1).OR.(igtyp ==  9).OR.(igtyp == 10).OR.(igtyp == 11).OR.
     .      (igtyp == 16).OR.(igtyp == 17).OR.(igtyp == 51).OR.(igtyp == 52)) THEN 
c 
          ! Property parameters
          p_thickg = geo(42,pid) ! -> Global Pthickfail parameter of the property
          prop_id  = igeo(1,pid) ! -> Property user ID
          nlay     = elbuf_str(ng)%NLAY ! -> Number of layers
          ipthkly  = 1 + 4*nlay ! -> Address of PTHKFAIL for PLYs
          npttot   = 0
          DO il = 1,nlay
            npttot = npttot + elbuf_str(ng)%BUFLY(il)%NPTT
          ENDDO
c
          ! Loop over layers 
          DO il = 1,nlay
c              
            ! Layer parameters                                         
            nfail = elbuf_str(ng)%BUFLY(il)%NFAIL ! -> Number of failure criteria
            imat  = elbuf_str(ng)%BUFLY(il)%IMAT  ! -> Material internal ID 
            IF ((igtyp == 51).OR.(igtyp == 52)) THEN 
              pthkly = stack%GEO(ipthkly + il,isubstack) ! -> Pthickfail parameter for ply
            ENDIF
            mat_id = ipm(1,imat) ! -> Material user ID
c
            ! Loop over failure criteria
            DO ifl = 1,nfail
c
              ! Recover criterion PTHKFAIL value
              p_thickfail = mat_param(imat)%FAIL(ifl)%PTHK
c
              ! Check conflicts between failure criteria and property value
              !   -> For 1 layer properties, check between global and failure criterion value
              IF (nlay == 1) THEN  
                IF (((p_thickfail > zero).AND.(p_thickg < zero)).OR.
     .              ((p_thickfail < zero).AND.(p_thickg > zero))) THEN 
                  CALL ancmsg(msgid=3029,
     .                        msgtype=msgwarning,
     .                        anmode=aninfo_blind_1,
     .                        i1=prop_id, 
     .                        r1=p_thickg,
     .                        i2=mat_id,    
     .                        r2=p_thickfail,
     .                        prmod=msg_cumu)
                ENDIF
              !   -> For multiple layer properties with 1 intg. point, check for failure criteria value
              ELSEIF (nlay == npttot) THEN
                IF (p_thickfail /= zero) THEN 
                  CALL ancmsg(msgid=3030,
     .                        msgtype=msgwarning,
     .                        anmode=aninfo_blind_1,
     .                        i1=prop_id, 
     .                        i2=igtyp,
     .                        prmod=msg_cumu)                  
                ENDIF
              !   -> For multiple layer properties with several intg. points, check between ply and failure criterion value
              ELSE
                IF (((p_thickfail > zero).AND.(pthkly < zero)).OR.
     .              ((p_thickfail < zero).AND.(pthkly > zero))) THEN 
                  CALL ancmsg(msgid=3031,
     .                        msgtype=msgwarning,
     .                        anmode=aninfo_blind_1,
     .                        i1=prop_id, 
     .                        i2=il,
     .                        r1=pthkly,
     .                        i3=mat_id,    
     .                        r2=p_thickfail,
     .                        prmod=msg_cumu)
                ENDIF                
              ENDIF
            ENDDO 
          ENDDO
        ENDIF
      ENDDO 
c
      ! Printing out warning messages
      CALL ancmsg(msgid=3029,
     .            msgtype=msgwarning,
     .            anmode=aninfo_blind_1,
     .            prmod=msg_print)
      CALL ancmsg(msgid=3030,
     .            msgtype=msgwarning,
     .            anmode=aninfo_blind_1,
     .            prmod=msg_print)
      CALL ancmsg(msgid=3031,
     .            msgtype=msgwarning,
     .            anmode=aninfo_blind_1,
     .            prmod=msg_print)
      !===============================================================================
c