cheequb.f

Go to the documentation of this file.

*> \brief \b CHEEQUB
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download CHEEQUB + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cheequb.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cheequb.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cheequb.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE CHEEQUB( UPLO, N, A, LDA, S, SCOND, AMAX, WORK, INFO )
*
*       .. Scalar Arguments ..
*       INTEGER            INFO, LDA, N
*       REAL               AMAX, SCOND
*       CHARACTER          UPLO
*       ..
*       .. Array Arguments ..
*       COMPLEX            A( LDA, * ), WORK( * )
*       REAL               S( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CHEEQUB computes row and column scalings intended to equilibrate a
*> Hermitian matrix A (with respect to the Euclidean norm) and reduce
*> its condition number. The scale factors S are computed by the BIN
*> algorithm (see references) so that the scaled matrix B with elements
*> B(i,j) = S(i)*A(i,j)*S(j) has a condition number within a factor N of
*> the smallest possible condition number over all possible diagonal
*> scalings.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          = 'U':  Upper triangle of A is stored;
*>          = 'L':  Lower triangle of A is stored.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A. N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA,N)
*>          The N-by-N Hermitian matrix whose scaling factors are to be
*>          computed.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A. LDA >= max(1,N).
*> \endverbatim
*>
*> \param[out] S
*> \verbatim
*>          S is REAL array, dimension (N)
*>          If INFO = 0, S contains the scale factors for A.
*> \endverbatim
*>
*> \param[out] SCOND
*> \verbatim
*>          SCOND is REAL
*>          If INFO = 0, S contains the ratio of the smallest S(i) to
*>          the largest S(i). If SCOND >= 0.1 and AMAX is neither too
*>          large nor too small, it is not worth scaling by S.
*> \endverbatim
*>
*> \param[out] AMAX
*> \verbatim
*>          AMAX is REAL
*>          Largest absolute value of any matrix element. If AMAX is
*>          very close to overflow or very close to underflow, the
*>          matrix should be scaled.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension (2*N)
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*>          > 0:  if INFO = i, the i-th diagonal element is nonpositive.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complexHEcomputational
*
*> \par References:
*  ================
*>
*>  Livne, O.E. and Golub, G.H., "Scaling by Binormalization", \n
*>  Numerical Algorithms, vol. 35, no. 1, pp. 97-120, January 2004. \n
*>  DOI 10.1023/B:NUMA.0000016606.32820.69 \n
*>  Tech report version: http://citeseerx.ist.psu.edu/viewdoc/summary?doi=10.1.1.3.1679
*>
*  =====================================================================
      SUBROUTINE cheequb( UPLO, N, A, LDA, S, SCOND, AMAX, WORK, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, N
      REAL               AMAX, SCOND
      CHARACTER          UPLO
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * ), WORK( * )
      REAL               S( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e0, zero = 0.0e0 )
      INTEGER            MAX_ITER
      parameter( max_iter = 100 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, ITER
      REAL               AVG, STD, TOL, C0, C1, C2, T, U, SI, D, BASE,
     $                   SMIN, SMAX, SMLNUM, BIGNUM, SCALE, SUMSQ
      LOGICAL            UP
      COMPLEX            ZDUM
*     ..
*     .. External Functions ..
      REAL               SLAMCH
      LOGICAL            LSAME
      EXTERNAL           lsame, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           classq, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, int, log, max, min, real, sqrt
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function Definitions ..
      cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF ( .NOT. ( lsame( uplo, 'U' ) .OR. lsame( uplo, 'L' ) ) ) THEN
         info = -1
      ELSE IF ( n .LT. 0 ) THEN
         info = -2
      ELSE IF ( lda .LT. max( 1, n ) ) THEN
         info = -4
      END IF
      IF ( info .NE. 0 ) THEN
         CALL xerbla( 'CHEEQUB', -info )
         RETURN
      END IF
 
      up = lsame( uplo, 'U' )
      amax = zero
*
*     Quick return if possible.
*
      IF ( n .EQ. 0 ) THEN
         scond = one
         RETURN
      END IF
 
      DO i = 1, n
         s( i ) = zero
      END DO
 
      amax = zero
      IF ( up ) THEN
         DO j = 1, n
            DO i = 1, j-1
               s( i ) = max( s( i ), cabs1( a( i, j ) ) )
               s( j ) = max( s( j ), cabs1( a( i, j ) ) )
               amax = max( amax, cabs1( a( i, j ) ) )
            END DO
            s( j ) = max( s( j ), cabs1( a( j, j ) ) )
            amax = max( amax, cabs1( a( j, j ) ) )
         END DO
      ELSE
         DO j = 1, n
            s( j ) = max( s( j ), cabs1( a( j, j ) ) )
            amax = max( amax, cabs1( a( j, j ) ) )
            DO i = j+1, n
               s( i ) = max( s( i ), cabs1( a( i, j ) ) )
               s( j ) = max( s( j ), cabs1( a( i, j ) ) )
               amax = max( amax, cabs1( a( i, j ) ) )
            END DO
         END DO
      END IF
      DO j = 1, n
         s( j ) = 1.0e0 / s( j )
      END DO
 
      tol = one / sqrt( 2.0e0 * n )
 
      DO iter = 1, max_iter
         scale = 0.0e0
         sumsq = 0.0e0
*        beta = |A|s
         DO i = 1, n
            work( i ) = zero
         END DO
         IF ( up ) THEN
            DO j = 1, n
               DO i = 1, j-1
                  work( i ) = work( i ) + cabs1( a( i, j ) ) * s( j )
                  work( j ) = work( j ) + cabs1( a( i, j ) ) * s( i )
               END DO
               work( j ) = work( j ) + cabs1( a( j, j ) ) * s( j )
            END DO
         ELSE
            DO j = 1, n
               work( j ) = work( j ) + cabs1( a( j, j ) ) * s( j )
               DO i = j+1, n
                  work( i ) = work( i ) + cabs1( a( i, j ) ) * s( j )
                  work( j ) = work( j ) + cabs1( a( i, j ) ) * s( i )
               END DO
            END DO
         END IF
 
*        avg = s^T beta / n
         avg = 0.0e0
         DO i = 1, n
            avg = avg + real( s( i )*work( i ) )
         END DO
         avg = avg / n
 
         std = 0.0e0
         DO i = n+1, 2*n
            work( i ) = s( i-n ) * work( i-n ) - avg
         END DO
         CALL classq( n, work( n+1 ), 1, scale, sumsq )
         std = scale * sqrt( sumsq / n )
 
         IF ( std .LT. tol * avg ) GOTO 999
 
         DO i = 1, n
            t = cabs1( a( i, i ) )
            si = s( i )
            c2 = ( n-1 ) * t
            c1 = real( ( n-2 ) * ( work( i ) - t*si ) )
            c0 = real( -(t*si)*si + 2*work( i )*si - n*avg )
            d = c1*c1 - 4*c0*c2
 
            IF ( d .LE. 0 ) THEN
               info = -1
               RETURN
            END IF
            si = -2*c0 / ( c1 + sqrt( d ) )
 
            d = si - s( i )
            u = zero
            IF ( up ) THEN
               DO j = 1, i
                  t = cabs1( a( j, i ) )
                  u = u + s( j )*t
                  work( j ) = work( j ) + d*t
               END DO
               DO j = i+1,n
                  t = cabs1( a( i, j ) )
                  u = u + s( j )*t
                  work( j ) = work( j ) + d*t
               END DO
            ELSE
               DO j = 1, i
                  t = cabs1( a( i, j ) )
                  u = u + s( j )*t
                  work( j ) = work( j ) + d*t
               END DO
               DO j = i+1,n
                  t = cabs1( a( j, i ) )
                  u = u + s( j )*t
                  work( j ) = work( j ) + d*t
               END DO
            END IF
 
            avg = avg + real( ( u + work( i ) ) * d / n )
            s( i ) = si
         END DO
      END DO
 
 999  CONTINUE
 
      smlnum = slamch( 'SAFEMIN' )
      bignum = one / smlnum
      smin = bignum
      smax = zero
      t = one / sqrt( avg )
      base = slamch( 'b' )
      U = ONE / LOG( BASE )
      DO I = 1, N
         S( I ) = BASE ** INT( U * LOG( S( I ) * T ) )
         SMIN = MIN( SMIN, S( I ) )
         SMAX = MAX( SMAX, S( I ) )
      END DO
      SCOND = MAX( SMIN, SMLNUM ) / MIN( SMAX, BIGNUM )
*
      END