cunbdb.f

Go to the documentation of this file.

*> \brief \b CUNBDB
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download CUNBDB + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cunbdb.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cunbdb.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cunbdb.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE CUNBDB( TRANS, SIGNS, M, P, Q, X11, LDX11, X12, LDX12,
*                          X21, LDX21, X22, LDX22, THETA, PHI, TAUP1,
*                          TAUP2, TAUQ1, TAUQ2, WORK, LWORK, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          SIGNS, TRANS
*       INTEGER            INFO, LDX11, LDX12, LDX21, LDX22, LWORK, M, P,
*      $                   Q
*       ..
*       .. Array Arguments ..
*       REAL               PHI( * ), THETA( * )
*       COMPLEX            TAUP1( * ), TAUP2( * ), TAUQ1( * ), TAUQ2( * ),
*      $                   WORK( * ), X11( LDX11, * ), X12( LDX12, * ),
*      $                   X21( LDX21, * ), X22( LDX22, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CUNBDB simultaneously bidiagonalizes the blocks of an M-by-M
*> partitioned unitary matrix X:
*>
*>                                 [ B11 | B12 0  0 ]
*>     [ X11 | X12 ]   [ P1 |    ] [  0  |  0 -I  0 ] [ Q1 |    ]**H
*> X = [-----------] = [---------] [----------------] [---------]   .
*>     [ X21 | X22 ]   [    | P2 ] [ B21 | B22 0  0 ] [    | Q2 ]
*>                                 [  0  |  0  0  I ]
*>
*> X11 is P-by-Q. Q must be no larger than P, M-P, or M-Q. (If this is
*> not the case, then X must be transposed and/or permuted. This can be
*> done in constant time using the TRANS and SIGNS options. See CUNCSD
*> for details.)
*>
*> The unitary matrices P1, P2, Q1, and Q2 are P-by-P, (M-P)-by-
*> (M-P), Q-by-Q, and (M-Q)-by-(M-Q), respectively. They are
*> represented implicitly by Householder vectors.
*>
*> B11, B12, B21, and B22 are Q-by-Q bidiagonal matrices represented
*> implicitly by angles THETA, PHI.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER
*>          = 'T':      X, U1, U2, V1T, and V2T are stored in row-major
*>                      order;
*>          otherwise:  X, U1, U2, V1T, and V2T are stored in column-
*>                      major order.
*> \endverbatim
*>
*> \param[in] SIGNS
*> \verbatim
*>          SIGNS is CHARACTER
*>          = 'O':      The lower-left block is made nonpositive (the
*>                      "other" convention);
*>          otherwise:  The upper-right block is made nonpositive (the
*>                      "default" convention).
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows and columns in X.
*> \endverbatim
*>
*> \param[in] P
*> \verbatim
*>          P is INTEGER
*>          The number of rows in X11 and X12. 0 <= P <= M.
*> \endverbatim
*>
*> \param[in] Q
*> \verbatim
*>          Q is INTEGER
*>          The number of columns in X11 and X21. 0 <= Q <=
*>          MIN(P,M-P,M-Q).
*> \endverbatim
*>
*> \param[in,out] X11
*> \verbatim
*>          X11 is COMPLEX array, dimension (LDX11,Q)
*>          On entry, the top-left block of the unitary matrix to be
*>          reduced. On exit, the form depends on TRANS:
*>          If TRANS = 'N', then
*>             the columns of tril(X11) specify reflectors for P1,
*>             the rows of triu(X11,1) specify reflectors for Q1;
*>          else TRANS = 'T', and
*>             the rows of triu(X11) specify reflectors for P1,
*>             the columns of tril(X11,-1) specify reflectors for Q1.
*> \endverbatim
*>
*> \param[in] LDX11
*> \verbatim
*>          LDX11 is INTEGER
*>          The leading dimension of X11. If TRANS = 'N', then LDX11 >=
*>          P; else LDX11 >= Q.
*> \endverbatim
*>
*> \param[in,out] X12
*> \verbatim
*>          X12 is COMPLEX array, dimension (LDX12,M-Q)
*>          On entry, the top-right block of the unitary matrix to
*>          be reduced. On exit, the form depends on TRANS:
*>          If TRANS = 'N', then
*>             the rows of triu(X12) specify the first P reflectors for
*>             Q2;
*>          else TRANS = 'T', and
*>             the columns of tril(X12) specify the first P reflectors
*>             for Q2.
*> \endverbatim
*>
*> \param[in] LDX12
*> \verbatim
*>          LDX12 is INTEGER
*>          The leading dimension of X12. If TRANS = 'N', then LDX12 >=
*>          P; else LDX11 >= M-Q.
*> \endverbatim
*>
*> \param[in,out] X21
*> \verbatim
*>          X21 is COMPLEX array, dimension (LDX21,Q)
*>          On entry, the bottom-left block of the unitary matrix to
*>          be reduced. On exit, the form depends on TRANS:
*>          If TRANS = 'N', then
*>             the columns of tril(X21) specify reflectors for P2;
*>          else TRANS = 'T', and
*>             the rows of triu(X21) specify reflectors for P2.
*> \endverbatim
*>
*> \param[in] LDX21
*> \verbatim
*>          LDX21 is INTEGER
*>          The leading dimension of X21. If TRANS = 'N', then LDX21 >=
*>          M-P; else LDX21 >= Q.
*> \endverbatim
*>
*> \param[in,out] X22
*> \verbatim
*>          X22 is COMPLEX array, dimension (LDX22,M-Q)
*>          On entry, the bottom-right block of the unitary matrix to
*>          be reduced. On exit, the form depends on TRANS:
*>          If TRANS = 'N', then
*>             the rows of triu(X22(Q+1:M-P,P+1:M-Q)) specify the last
*>             M-P-Q reflectors for Q2,
*>          else TRANS = 'T', and
*>             the columns of tril(X22(P+1:M-Q,Q+1:M-P)) specify the last
*>             M-P-Q reflectors for P2.
*> \endverbatim
*>
*> \param[in] LDX22
*> \verbatim
*>          LDX22 is INTEGER
*>          The leading dimension of X22. If TRANS = 'N', then LDX22 >=
*>          M-P; else LDX22 >= M-Q.
*> \endverbatim
*>
*> \param[out] THETA
*> \verbatim
*>          THETA is REAL array, dimension (Q)
*>          The entries of the bidiagonal blocks B11, B12, B21, B22 can
*>          be computed from the angles THETA and PHI. See Further
*>          Details.
*> \endverbatim
*>
*> \param[out] PHI
*> \verbatim
*>          PHI is REAL array, dimension (Q-1)
*>          The entries of the bidiagonal blocks B11, B12, B21, B22 can
*>          be computed from the angles THETA and PHI. See Further
*>          Details.
*> \endverbatim
*>
*> \param[out] TAUP1
*> \verbatim
*>          TAUP1 is COMPLEX array, dimension (P)
*>          The scalar factors of the elementary reflectors that define
*>          P1.
*> \endverbatim
*>
*> \param[out] TAUP2
*> \verbatim
*>          TAUP2 is COMPLEX array, dimension (M-P)
*>          The scalar factors of the elementary reflectors that define
*>          P2.
*> \endverbatim
*>
*> \param[out] TAUQ1
*> \verbatim
*>          TAUQ1 is COMPLEX array, dimension (Q)
*>          The scalar factors of the elementary reflectors that define
*>          Q1.
*> \endverbatim
*>
*> \param[out] TAUQ2
*> \verbatim
*>          TAUQ2 is COMPLEX array, dimension (M-Q)
*>          The scalar factors of the elementary reflectors that define
*>          Q2.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK. LWORK >= M-Q.
*>
*>          If LWORK = -1, then a workspace query is assumed; the routine
*>          only calculates the optimal size of the WORK array, returns
*>          this value as the first entry of the WORK array, and no error
*>          message related to LWORK is issued by XERBLA.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit.
*>          < 0:  if INFO = -i, the i-th argument had an illegal value.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complexOTHERcomputational
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  The bidiagonal blocks B11, B12, B21, and B22 are represented
*>  implicitly by angles THETA(1), ..., THETA(Q) and PHI(1), ...,
*>  PHI(Q-1). B11 and B21 are upper bidiagonal, while B21 and B22 are
*>  lower bidiagonal. Every entry in each bidiagonal band is a product
*>  of a sine or cosine of a THETA with a sine or cosine of a PHI. See
*>  [1] or CUNCSD for details.
*>
*>  P1, P2, Q1, and Q2 are represented as products of elementary
*>  reflectors. See CUNCSD for details on generating P1, P2, Q1, and Q2
*>  using CUNGQR and CUNGLQ.
*> \endverbatim
*
*> \par References:
*  ================
*>
*>  [1] Brian D. Sutton. Computing the complete CS decomposition. Numer.
*>      Algorithms, 50(1):33-65, 2009.
*>
*  =====================================================================
      SUBROUTINE cunbdb( TRANS, SIGNS, M, P, Q, X11, LDX11, X12, LDX12,
     $                   X21, LDX21, X22, LDX22, THETA, PHI, TAUP1,
     $                   TAUP2, TAUQ1, TAUQ2, WORK, LWORK, INFO )
*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          SIGNS, TRANS
      INTEGER            INFO, LDX11, LDX12, LDX21, LDX22, LWORK, M, P,
     $                   q
*     ..
*     .. Array Arguments ..
      REAL               PHI( * ), THETA( * )
      COMPLEX            TAUP1( * ), TAUP2( * ), TAUQ1( * ), TAUQ2( * ),
     $                   work( * ), x11( ldx11, * ), x12( ldx12, * ),
     $                   x21( ldx21, * ), x22( ldx22, * )
*     ..
*
*  ====================================================================
*
*     .. Parameters ..
      REAL               REALONE
      PARAMETER          ( REALONE = 1.0e0 )
      COMPLEX            ONE
      parameter( one = (1.0e0,0.0e0) )
*     ..
*     .. Local Scalars ..
      LOGICAL            COLMAJOR, LQUERY
      INTEGER            I, LWORKMIN, LWORKOPT
      REAL               Z1, Z2, Z3, Z4
*     ..
*     .. External Subroutines ..
      EXTERNAL           caxpy, clarf, clarfgp, cscal, xerbla
      EXTERNAL           clacgv
*
*     ..
*     .. External Functions ..
      REAL               SCNRM2
      LOGICAL            LSAME
      EXTERNAL           scnrm2, lsame
*     ..
*     .. Intrinsic Functions
      INTRINSIC          atan2, cos, max, min, sin
      INTRINSIC          cmplx, conjg
*     ..
*     .. Executable Statements ..
*
*     Test input arguments
*
      info = 0
      colmajor = .NOT. lsame( trans, 'T' )
      IF( .NOT. lsame( signs, 'O' ) ) THEN
         z1 = realone
         z2 = realone
         z3 = realone
         z4 = realone
      ELSE
         z1 = realone
         z2 = -realone
         z3 = realone
         z4 = -realone
      END IF
      lquery = lwork .EQ. -1
*
      IF( m .LT. 0 ) THEN
         info = -3
      ELSE IF( p .LT. 0 .OR. p .GT. m ) THEN
         info = -4
      ELSE IF( q .LT. 0 .OR. q .GT. p .OR. q .GT. m-p .OR.
     $         q .GT. m-q ) THEN
         info = -5
      ELSE IF( colmajor .AND. ldx11 .LT. max( 1, p ) ) THEN
         info = -7
      ELSE IF( .NOT.colmajor .AND. ldx11 .LT. max( 1, q ) ) THEN
         info = -7
      ELSE IF( colmajor .AND. ldx12 .LT. max( 1, p ) ) THEN
         info = -9
      ELSE IF( .NOT.colmajor .AND. ldx12 .LT. max( 1, m-q ) ) THEN
         info = -9
      ELSE IF( colmajor .AND. ldx21 .LT. max( 1, m-p ) ) THEN
         info = -11
      ELSE IF( .NOT.colmajor .AND. ldx21 .LT. max( 1, q ) ) THEN
         info = -11
      ELSE IF( colmajor .AND. ldx22 .LT. max( 1, m-p ) ) THEN
         info = -13
      ELSE IF( .NOT.colmajor .AND. ldx22 .LT. max( 1, m-q ) ) THEN
         info = -13
      END IF
*
*     Compute workspace
*
      IF( info .EQ. 0 ) THEN
         lworkopt = m - q
         lworkmin = m - q
         work(1) = lworkopt
         IF( lwork .LT. lworkmin .AND. .NOT. lquery ) THEN
            info = -21
         END IF
      END IF
      IF( info .NE. 0 ) THEN
         CALL xerbla( 'xORBDB', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Handle column-major and row-major separately
*
      IF( colmajor ) THEN
*
*        Reduce columns 1, ..., Q of X11, X12, X21, and X22
*
         DO i = 1, q
*
            IF( i .EQ. 1 ) THEN
               CALL cscal( p-i+1, cmplx( z1, 0.0e0 ), x11(i,i), 1 )
            ELSE
               CALL cscal( p-i+1, cmplx( z1*cos(phi(i-1)), 0.0e0 ),
     $                     x11(i,i), 1 )
               CALL caxpy( p-i+1, cmplx( -z1*z3*z4*sin(phi(i-1)),
     $                     0.0e0 ), x12(i,i-1), 1, x11(i,i), 1 )
            END IF
            IF( i .EQ. 1 ) THEN
               CALL cscal( m-p-i+1, cmplx( z2, 0.0e0 ), x21(i,i), 1 )
            ELSE
               CALL cscal( m-p-i+1, cmplx( z2*cos(phi(i-1)), 0.0e0 ),
     $                     x21(i,i), 1 )
               CALL caxpy( m-p-i+1, cmplx( -z2*z3*z4*sin(phi(i-1)),
     $                     0.0e0 ), x22(i,i-1), 1, x21(i,i), 1 )
            END IF
*
            theta(i) = atan2( scnrm2( m-p-i+1, x21(i,i), 1 ),
     $                 scnrm2( p-i+1, x11(i,i), 1 ) )
*
            IF( p .GT. i ) THEN
               CALL clarfgp( p-i+1, x11(i,i), x11(i+1,i), 1, taup1(i) )
            ELSE IF ( p .EQ. i ) THEN
               CALL clarfgp( p-i+1, x11(i,i), x11(i,i), 1, taup1(i) )
            END IF
            x11(i,i) = one
            IF ( m-p .GT. i ) THEN
               CALL clarfgp( m-p-i+1, x21(i,i), x21(i+1,i), 1,
     $                       taup2(i) )
            ELSE IF ( m-p .EQ. i ) THEN
               CALL clarfgp( m-p-i+1, x21(i,i), x21(i,i), 1,
     $                       taup2(i) )
            END IF
            x21(i,i) = one
*
            IF ( q .GT. i ) THEN
               CALL clarf( 'L', p-i+1, q-i, x11(i,i), 1,
     $                     conjg(taup1(i)), x11(i,i+1), ldx11, work )
               CALL clarf( 'L', m-p-i+1, q-i, x21(i,i), 1,
     $                     conjg(taup2(i)), x21(i,i+1), ldx21, work )
            END IF
            IF ( m-q+1 .GT. i ) THEN
               CALL clarf( 'L', p-i+1, m-q-i+1, x11(i,i), 1,
     $                     conjg(taup1(i)), x12(i,i), ldx12, work )
               CALL clarf( 'L', m-p-i+1, m-q-i+1, x21(i,i), 1,
     $                     conjg(taup2(i)), x22(i,i), ldx22, work )
            END IF
*
            IF( i .LT. q ) THEN
               CALL cscal( q-i, cmplx( -z1*z3*sin(theta(i)), 0.0e0 ),
     $                     x11(i,i+1), ldx11 )
               CALL caxpy( q-i, cmplx( z2*z3*cos(theta(i)), 0.0e0 ),
     $                     x21(i,i+1), ldx21, x11(i,i+1), ldx11 )
            END IF
            CALL cscal( m-q-i+1, cmplx( -z1*z4*sin(theta(i)), 0.0e0 ),
     $                  x12(i,i), ldx12 )
            CALL caxpy( m-q-i+1, cmplx( z2*z4*cos(theta(i)), 0.0e0 ),
     $                  x22(i,i), ldx22, x12(i,i), ldx12 )
*
            IF( i .LT. q )
     $         phi(i) = atan2( scnrm2( q-i, x11(i,i+1), ldx11 ),
     $                  scnrm2( m-q-i+1, x12(i,i), ldx12 ) )
*
            IF( i .LT. q ) THEN
               CALL clacgv( q-i, x11(i,i+1), ldx11 )
               IF ( i .EQ. q-1 ) THEN
                  CALL clarfgp( q-i, x11(i,i+1), x11(i,i+1), ldx11,
     $                          tauq1(i) )
               ELSE
                  CALL clarfgp( q-i, x11(i,i+1), x11(i,i+2), ldx11,
     $                          tauq1(i) )
               END IF
               x11(i,i+1) = one
            END IF
            IF ( m-q+1 .GT. i ) THEN
               CALL clacgv( m-q-i+1, x12(i,i), ldx12 )
               IF ( m-q .EQ. i ) THEN
                  CALL clarfgp( m-q-i+1, x12(i,i), x12(i,i), ldx12,
     $                          tauq2(i) )
               ELSE
                  CALL clarfgp( m-q-i+1, x12(i,i), x12(i,i+1), ldx12,
     $                          tauq2(i) )
               END IF
            END IF
            x12(i,i) = one
*
            IF( i .LT. q ) THEN
               CALL clarf( 'R', p-i, q-i, x11(i,i+1), ldx11, tauq1(i),
     $                     x11(i+1,i+1), ldx11, work )
               CALL clarf( 'R', m-p-i, q-i, x11(i,i+1), ldx11, tauq1(i),
     $                     x21(i+1,i+1), ldx21, work )
            END IF
            IF ( p .GT. i ) THEN
               CALL clarf( 'R', p-i, m-q-i+1, x12(i,i), ldx12, tauq2(i),
     $                     x12(i+1,i), ldx12, work )
            END IF
            IF ( m-p .GT. i ) THEN
               CALL clarf( 'R', m-p-i, m-q-i+1, x12(i,i), ldx12,
     $                     tauq2(i), x22(i+1,i), ldx22, work )
            END IF
*
            IF( i .LT. q )
     $         CALL clacgv( q-i, x11(i,i+1), ldx11 )
            CALL clacgv( m-q-i+1, x12(i,i), ldx12 )
*
         END DO
*
*        Reduce columns Q + 1, ..., P of X12, X22
*
         DO i = q + 1, p
*
            CALL cscal( m-q-i+1, cmplx( -z1*z4, 0.0e0 ), x12(i,i),
     $                  ldx12 )
            CALL clacgv( m-q-i+1, x12(i,i), ldx12 )
            IF ( i .GE. m-q ) THEN
               CALL clarfgp( m-q-i+1, x12(i,i), x12(i,i), ldx12,
     $                       tauq2(i) )
            ELSE
               CALL clarfgp( m-q-i+1, x12(i,i), x12(i,i+1), ldx12,
     $                       tauq2(i) )
            END IF
            x12(i,i) = one
*
            IF ( p .GT. i ) THEN
               CALL clarf( 'R', p-i, m-q-i+1, x12(i,i), ldx12, tauq2(i),
     $                     x12(i+1,i), ldx12, work )
            END IF
            IF( m-p-q .GE. 1 )
     $         CALL clarf( 'R', m-p-q, m-q-i+1, x12(i,i), ldx12,
     $                     tauq2(i), x22(q+1,i), ldx22, work )
*
            CALL clacgv( m-q-i+1, x12(i,i), ldx12 )
*
         END DO
*
*        Reduce columns P + 1, ..., M - Q of X12, X22
*
         DO i = 1, m - p - q
*
            CALL cscal( m-p-q-i+1, cmplx( z2*z4, 0.0e0 ),
     $                  x22(q+i,p+i), ldx22 )
            CALL clacgv( m-p-q-i+1, x22(q+i,p+i), ldx22 )
            CALL clarfgp( m-p-q-i+1, x22(q+i,p+i), x22(q+i,p+i+1),
     $                    ldx22, tauq2(p+i) )
            x22(q+i,p+i) = one
            CALL clarf( 'R', m-p-q-i, m-p-q-i+1, x22(q+i,p+i), ldx22,
     $                  tauq2(p+i), x22(q+i+1,p+i), ldx22, work )
*
            CALL clacgv( m-p-q-i+1, x22(q+i,p+i), ldx22 )
*
         END DO
*
      ELSE
*
*        Reduce columns 1, ..., Q of X11, X12, X21, X22
*
         DO i = 1, q
*
            IF( i .EQ. 1 ) THEN
               CALL cscal( p-i+1, cmplx( z1, 0.0e0 ), x11(i,i),
     $                     ldx11 )
            ELSE
               CALL cscal( p-i+1, cmplx( z1*cos(phi(i-1)), 0.0e0 ),
     $                     x11(i,i), ldx11 )
               CALL caxpy( p-i+1, cmplx( -z1*z3*z4*sin(phi(i-1)),
     $                     0.0e0 ), x12(i-1,i), ldx12, x11(i,i), ldx11 )
            END IF
            IF( i .EQ. 1 ) THEN
               CALL cscal( m-p-i+1, cmplx( z2, 0.0e0 ), x21(i,i),
     $                     ldx21 )
            ELSE
               CALL cscal( m-p-i+1, cmplx( z2*cos(phi(i-1)), 0.0e0 ),
     $                     x21(i,i), ldx21 )
               CALL caxpy( m-p-i+1, cmplx( -z2*z3*z4*sin(phi(i-1)),
     $                     0.0e0 ), x22(i-1,i), ldx22, x21(i,i), ldx21 )
            END IF
*
            theta(i) = atan2( scnrm2( m-p-i+1, x21(i,i), ldx21 ),
     $                 scnrm2( p-i+1, x11(i,i), ldx11 ) )
*
            CALL clacgv( p-i+1, x11(i,i), ldx11 )
            CALL clacgv( m-p-i+1, x21(i,i), ldx21 )
*
            CALL clarfgp( p-i+1, x11(i,i), x11(i,i+1), ldx11, taup1(i) )
            x11(i,i) = one
            IF ( i .EQ. m-p ) THEN
               CALL clarfgp( m-p-i+1, x21(i,i), x21(i,i), ldx21,
     $                       taup2(i) )
            ELSE
               CALL clarfgp( m-p-i+1, x21(i,i), x21(i,i+1), ldx21,
     $                       taup2(i) )
            END IF
            x21(i,i) = one
*
            CALL clarf( 'R', q-i, p-i+1, x11(i,i), ldx11, taup1(i),
     $                  x11(i+1,i), ldx11, work )
            CALL clarf( 'R', m-q-i+1, p-i+1, x11(i,i), ldx11, taup1(i),
     $                  x12(i,i), ldx12, work )
            CALL clarf( 'R', q-i, m-p-i+1, x21(i,i), ldx21, taup2(i),
     $                  x21(i+1,i), ldx21, work )
            CALL clarf( 'R', m-q-i+1, m-p-i+1, x21(i,i), ldx21,
     $                  taup2(i), x22(i,i), ldx22, work )
*
            CALL clacgv( p-i+1, x11(i,i), ldx11 )
            CALL clacgv( m-p-i+1, x21(i,i), ldx21 )
*
            IF( i .LT. q ) THEN
               CALL cscal( q-i, cmplx( -z1*z3*sin(theta(i)), 0.0e0 ),
     $                     x11(i+1,i), 1 )
               CALL caxpy( q-i, cmplx( z2*z3*cos(theta(i)), 0.0e0 ),
     $                     x21(i+1,i), 1, x11(i+1,i), 1 )
            END IF
            CALL cscal( m-q-i+1, cmplx( -z1*z4*sin(theta(i)), 0.0e0 ),
     $                  x12(i,i), 1 )
            CALL caxpy( m-q-i+1, cmplx( z2*z4*cos(theta(i)), 0.0e0 ),
     $                  x22(i,i), 1, x12(i,i), 1 )
*
            IF( i .LT. q )
     $         phi(i) = atan2( scnrm2( q-i, x11(i+1,i), 1 ),
     $                  scnrm2( m-q-i+1, x12(i,i), 1 ) )
*
            IF( i .LT. q ) THEN
               CALL clarfgp( q-i, x11(i+1,i), x11(i+2,i), 1, tauq1(i) )
               x11(i+1,i) = one
            END IF
            CALL clarfgp( m-q-i+1, x12(i,i), x12(i+1,i), 1, tauq2(i) )
            x12(i,i) = one
*
            IF( i .LT. q ) THEN
               CALL clarf( 'L', q-i, p-i, x11(i+1,i), 1,
     $                     conjg(tauq1(i)), x11(i+1,i+1), ldx11, work )
               CALL clarf( 'L', q-i, m-p-i, x11(i+1,i), 1,
     $                     conjg(tauq1(i)), x21(i+1,i+1), ldx21, work )
            END IF
            CALL clarf( 'L', m-q-i+1, p-i, x12(i,i), 1, conjg(tauq2(i)),
     $                  x12(i,i+1), ldx12, work )
 
            IF ( m-p .GT. i ) THEN
               CALL clarf( 'L', m-q-i+1, m-p-i, x12(i,i), 1,
     $                     conjg(tauq2(i)), x22(i,i+1), ldx22, work )
            END IF
         END DO
*
*        Reduce columns Q + 1, ..., P of X12, X22
*
         DO i = q + 1, p
*
            CALL cscal( m-q-i+1, cmplx( -z1*z4, 0.0e0 ), x12(i,i), 1 )
            CALL clarfgp( m-q-i+1, x12(i,i), x12(i+1,i), 1, tauq2(i) )
            x12(i,i) = one
*
            IF ( p .GT. i ) THEN
               CALL clarf( 'L', m-q-i+1, p-i, x12(i,i), 1,
     $                     conjg(tauq2(i)), x12(i,i+1), ldx12, work )
            END IF
            IF( m-p-q .GE. 1 )
     $         CALL clarf( 'L', m-q-i+1, m-p-q, x12(i,i), 1,
     $                     conjg(tauq2(i)), x22(i,q+1), ldx22, work )
*
         END DO
*
*        Reduce columns P + 1, ..., M - Q of X12, X22
*
         DO i = 1, m - p - q
*
            CALL cscal( m-p-q-i+1, cmplx( z2*z4, 0.0e0 ),
     $                  x22(p+i,q+i), 1 )
            CALL clarfgp( m-p-q-i+1, x22(p+i,q+i), x22(p+i+1,q+i), 1,
     $                    tauq2(p+i) )
            x22(p+i,q+i) = one
            IF ( m-p-q .NE. i ) THEN
               CALL clarf( 'L', m-p-q-i+1, m-p-q-i, x22(p+i,q+i), 1,
     $                     conjg(tauq2(p+i)), x22(p+i,q+i+1), ldx22,
     $                     work )
            END IF
         END DO
*
      END IF
*
      RETURN
*
*     End of CUNBDB
*
      END