dlantr.f

Go to the documentation of this file.

*> \brief \b DLANTR returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a trapezoidal or triangular matrix.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download DLANTR + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dlantr.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dlantr.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dlantr.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       DOUBLE PRECISION FUNCTION DLANTR( NORM, UPLO, DIAG, M, N, A, LDA,
*                        WORK )
*
*       .. Scalar Arguments ..
*       CHARACTER          DIAG, NORM, UPLO
*       INTEGER            LDA, M, N
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   A( LDA, * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DLANTR  returns the value of the one norm,  or the Frobenius norm, or
*> the  infinity norm,  or the  element of  largest absolute value  of a
*> trapezoidal or triangular matrix A.
*> \endverbatim
*>
*> \return DLANTR
*> \verbatim
*>
*>    DLANTR = ( max(abs(A(i,j))), NORM = 'M' or 'm'
*>             (
*>             ( norm1(A),         NORM = '1', 'O' or 'o'
*>             (
*>             ( normI(A),         NORM = 'I' or 'i'
*>             (
*>             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
*>
*> where  norm1  denotes the  one norm of a matrix (maximum column sum),
*> normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
*> normF  denotes the  Frobenius norm of a matrix (square root of sum of
*> squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NORM
*> \verbatim
*>          NORM is CHARACTER*1
*>          Specifies the value to be returned in DLANTR as described
*>          above.
*> \endverbatim
*>
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the matrix A is upper or lower trapezoidal.
*>          = 'U':  Upper trapezoidal
*>          = 'L':  Lower trapezoidal
*>          Note that A is triangular instead of trapezoidal if M = N.
*> \endverbatim
*>
*> \param[in] DIAG
*> \verbatim
*>          DIAG is CHARACTER*1
*>          Specifies whether or not the matrix A has unit diagonal.
*>          = 'N':  Non-unit diagonal
*>          = 'U':  Unit diagonal
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >= 0, and if
*>          UPLO = 'U', M <= N.  When M = 0, DLANTR is set to zero.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix A.  N >= 0, and if
*>          UPLO = 'L', N <= M.  When N = 0, DLANTR is set to zero.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (LDA,N)
*>          The trapezoidal matrix A (A is triangular if M = N).
*>          If UPLO = 'U', the leading m by n upper trapezoidal part of
*>          the array A contains the upper trapezoidal matrix, and the
*>          strictly lower triangular part of A is not referenced.
*>          If UPLO = 'L', the leading m by n lower trapezoidal part of
*>          the array A contains the lower trapezoidal matrix, and the
*>          strictly upper triangular part of A is not referenced.  Note
*>          that when DIAG = 'U', the diagonal elements of A are not
*>          referenced and are assumed to be one.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(M,1).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
*>          where LWORK >= M when NORM = 'I'; otherwise, WORK is not
*>          referenced.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup doubleOTHERauxiliary
*
*  =====================================================================
      DOUBLE PRECISION FUNCTION dlantr( NORM, UPLO, DIAG, M, N, A, LDA,
     $                 WORK )
*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, norm, uplo
      INTEGER            lda, m, n
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   a( lda, * ), work( * )
*     ..
*
* =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   one, zero
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            udiag
      INTEGER            i, j
      DOUBLE PRECISION   scale, sum, VALUE
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlassq
*     ..
*     .. External Functions ..
      LOGICAL            lsame, disnan
      EXTERNAL           lsame, disnan
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, min, sqrt
*     ..
*     .. Executable Statements ..
*
      IF( min( m, n ).EQ.0 ) THEN
         VALUE = zero
      ELSE IF( lsame( norm, 'M' ) ) THEN
*
*        Find max(abs(A(i,j))).
*
         IF( lsame( diag, 'U' ) ) THEN
            VALUE = one
            IF( lsame( uplo, 'U' ) ) THEN
               DO 20 j = 1, n
                  DO 10 i = 1, min( m, j-1 )
                     sum = abs( a( i, j ) )
                     IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
   10             CONTINUE
   20          CONTINUE
            ELSE
               DO 40 j = 1, n
                  DO 30 i = j + 1, m
                     sum = abs( a( i, j ) )
                     IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
   30             CONTINUE
   40          CONTINUE
            END IF
         ELSE
            VALUE = zero
            IF( lsame( uplo, 'U' ) ) THEN
               DO 60 j = 1, n
                  DO 50 i = 1, min( m, j )
                     sum = abs( a( i, j ) )
                     IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
   50             CONTINUE
   60          CONTINUE
            ELSE
               DO 80 j = 1, n
                  DO 70 i = j, m
                     sum = abs( a( i, j ) )
                     IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
   70             CONTINUE
   80          CONTINUE
            END IF
         END IF
      ELSE IF( ( lsame( norm, 'O' ) ) .OR. ( norm.EQ.'1' ) ) THEN
*
*        Find norm1(A).
*
         VALUE = zero
         udiag = lsame( diag, 'U' )
         IF( lsame( uplo, 'U' ) ) THEN
            DO 110 j = 1, n
               IF( ( udiag ) .AND. ( j.LE.m ) ) THEN
                  sum = one
                  DO 90 i = 1, j - 1
                     sum = sum + abs( a( i, j ) )
   90             CONTINUE
               ELSE
                  sum = zero
                  DO 100 i = 1, min( m, j )
                     sum = sum + abs( a( i, j ) )
  100             CONTINUE
               END IF
               IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
  110       CONTINUE
         ELSE
            DO 140 j = 1, n
               IF( udiag ) THEN
                  sum = one
                  DO 120 i = j + 1, m
                     sum = sum + abs( a( i, j ) )
  120             CONTINUE
               ELSE
                  sum = zero
                  DO 130 i = j, m
                     sum = sum + abs( a( i, j ) )
  130             CONTINUE
               END IF
               IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
  140       CONTINUE
         END IF
      ELSE IF( lsame( norm, 'I' ) ) THEN
*
*        Find normI(A).
*
         IF( lsame( uplo, 'U' ) ) THEN
            IF( lsame( diag, 'U' ) ) THEN
               DO 150 i = 1, m
                  work( i ) = one
  150          CONTINUE
               DO 170 j = 1, n
                  DO 160 i = 1, min( m, j-1 )
                     work( i ) = work( i ) + abs( a( i, j ) )
  160             CONTINUE
  170          CONTINUE
            ELSE
               DO 180 i = 1, m
                  work( i ) = zero
  180          CONTINUE
               DO 200 j = 1, n
                  DO 190 i = 1, min( m, j )
                     work( i ) = work( i ) + abs( a( i, j ) )
  190             CONTINUE
  200          CONTINUE
            END IF
         ELSE
            IF( lsame( diag, 'U' ) ) THEN
               DO 210 i = 1, min( m, n )
                  work( i ) = one
  210          CONTINUE
               DO 220 i = n + 1, m
                  work( i ) = zero
  220          CONTINUE
               DO 240 j = 1, n
                  DO 230 i = j + 1, m
                     work( i ) = work( i ) + abs( a( i, j ) )
  230             CONTINUE
  240          CONTINUE
            ELSE
               DO 250 i = 1, m
                  work( i ) = zero
  250          CONTINUE
               DO 270 j = 1, n
                  DO 260 i = j, m
                     work( i ) = work( i ) + abs( a( i, j ) )
  260             CONTINUE
  270          CONTINUE
            END IF
         END IF
         VALUE = zero
         DO 280 i = 1, m
            sum = work( i )
            IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
  280    CONTINUE
      ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
*
*        Find normF(A).
*
         IF( lsame( uplo, 'U' ) ) THEN
            IF( lsame( diag, 'U' ) ) THEN
               scale = one
               sum = min( m, n )
               DO 290 j = 2, n
                  CALL dlassq( min( m, j-1 ), a( 1, j ), 1, scale, sum )
  290          CONTINUE
            ELSE
               scale = zero
               sum = one
               DO 300 j = 1, n
                  CALL dlassq( min( m, j ), a( 1, j ), 1, scale, sum )
  300          CONTINUE
            END IF
         ELSE
            IF( lsame( diag, 'U' ) ) THEN
               scale = one
               sum = min( m, n )
               DO 310 j = 1, n
                  CALL dlassq( m-j, a( min( m, j+1 ), j ), 1, scale,
     $                         sum )
  310          CONTINUE
            ELSE
               scale = zero
               sum = one
               DO 320 j = 1, n
                  CALL dlassq( m-j+1, a( j, j ), 1, scale, sum )
  320          CONTINUE
            END IF
         END IF
         VALUE = scale*sqrt( sum )
      END IF
*
      dlantr = VALUE
      RETURN
*
*     End of DLANTR
*
      END