drzt02.f

Go to the documentation of this file.

*> \brief \b DRZT02
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       DOUBLE PRECISION FUNCTION DRZT02( M, N, AF, LDA, TAU, WORK,
*                        LWORK )
*
*       .. Scalar Arguments ..
*       INTEGER            LDA, LWORK, M, N
*       ..
*       .. Array Arguments ..
*       DOUBLE PRECISION   AF( LDA, * ), TAU( * ), WORK( LWORK )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DRZT02 returns
*>      || I - Q'*Q || / ( M * eps)
*> where the matrix Q is defined by the Householder transformations
*> generated by DTZRZF.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix AF.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix AF.
*> \endverbatim
*>
*> \param[in] AF
*> \verbatim
*>          AF is DOUBLE PRECISION array, dimension (LDA,N)
*>          The output of DTZRZF.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array AF.
*> \endverbatim
*>
*> \param[in] TAU
*> \verbatim
*>          TAU is DOUBLE PRECISION array, dimension (M)
*>          Details of the Householder transformations as returned by
*>          DTZRZF.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          length of WORK array. LWORK >= N*N+N*NB.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup double_lin
*
*  =====================================================================
      DOUBLE PRECISION FUNCTION drzt02( M, N, AF, LDA, TAU, WORK,
     $                 LWORK )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   af( lda, * ), tau( * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, one
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, info
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   rwork( 1 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dlamch, dlange
      EXTERNAL           dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlaset, dormrz, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max
*     ..
*     .. Executable Statements ..
*
      drzt02 = zero
*
      IF( lwork.LT.n*n+n ) THEN
         CALL xerbla( 'DRZT02', 7 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
*
*     Q := I
*
      CALL dlaset( 'Full', n, n, zero, one, work, n )
*
*     Q := P(1) * ... * P(m) * Q
*
      CALL dormrz( 'Left', 'No transpose', n, n, m, n-m, af, lda, tau,
     $             work, n, work( n*n+1 ), lwork-n*n, info )
*
*     Q := P(m) * ... * P(1) * Q
*
      CALL dormrz( 'Left', 'Transpose', n, n, m, n-m, af, lda, tau,
     $             work, n, work( n*n+1 ), lwork-n*n, info )
*
*     Q := Q - I
*
      DO 10 i = 1, n
         work( ( i-1 )*n+i ) = work( ( i-1 )*n+i ) - one
   10 CONTINUE
*
      drzt02 = dlange( 'One-norm', n, n, work, n, rwork ) /
     $         ( dlamch( 'Epsilon' )*dble( max( m, n ) ) )
      RETURN
*
*     End of DRZT02
*
      END