s4defo3.F File Reference

#include "implicit_f.inc"
#include "com08_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	s4defo3 (px1, px2, px3, px4, py1, py2, py3, py4, pz1, pz2, pz3, pz4, vx1, vx2, vx3, vx4, vy1, vy2, vy3, vy4, vz1, vz2, vz3, vz4, dxx, dxy, dxz, dyx, dyy, dyz, dzx, dzy, dzz, d4, d5, d6, wxx, wyy, wzz, nel, ismstr)

Function/Subroutine Documentation

s4defo3()

subroutine s4defo3	(		px1,
			px2,
			px3,
			px4,
			py1,
			py2,
			py3,
			py4,
			pz1,
			pz2,
			pz3,
			pz4,
			vx1,
			vx2,
			vx3,
			vx4,
			vy1,
			vy2,
			vy3,
			vy4,
			vz1,
			vz2,
			vz3,
			vz4,
			dxx,
			dxy,
			dxz,
			dyx,
			dyy,
			dyz,
			dzx,
			dzy,
			dzz,
			d4,
			d5,
			d6,
			wxx,
			wyy,
			wzz,
		integer, intent(in)	nel,
		integer, intent(in)	ismstr )

Definition at line 28 of file s4defo3.F.

C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL
      INTEGER, INTENT(IN) :: ISMSTR
      my_real
     .   vx1(*), vx2(*), vx3(*), vx4(*),
     .   vy1(*), vy2(*), vy3(*), vy4(*),
     .   vz1(*), vz2(*), vz3(*), vz4(*),
     .   px1(*), px2(*), px3(*), px4(*),
     .   py1(*), py2(*), py3(*), py4(*),
     .   pz1(*), pz2(*), pz3(*), pz4(*), 
     .   dxx(*), dxy(*), dxz(*),
     .   dyx(*), dyy(*), dyz(*),
     .   dzx(*), dzy(*), dzz(*), d4(*), d5(*), d6(*),
     .   wxx(*), wyy(*), wzz(*)
CMasParINCLUDE 'sdefo3.intmap.inc'
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER  I
C     REAL
      my_real
     .   dt1d2
      my_real 
     .   pxx2,pyy2,pzz2,pxx2p,pyy2p,pzz2p,aaa,bbb,ccc,
     .   exx,exy,exz,eyx,eyy,eyz,ezx,ezy,ezz
C-----------------------------------------------
      DO i=1,nel
        dxx(i)=px1(i)*vx1(i)+px2(i)*vx2(i)+
     .         px3(i)*vx3(i)+px4(i)*vx4(i)
        dyy(i)=py1(i)*vy1(i)+py2(i)*vy2(i)+
     .         py3(i)*vy3(i)+py4(i)*vy4(i)
        dzz(i)=pz1(i)*vz1(i)+pz2(i)*vz2(i)+
     .         pz3(i)*vz3(i)+pz4(i)*vz4(i)
        dxy(i)=py1(i)*vx1(i)+py2(i)*vx2(i)+
     .         py3(i)*vx3(i)+py4(i)*vx4(i)
        dxz(i)=pz1(i)*vx1(i)+pz2(i)*vx2(i)+
     .         pz3(i)*vx3(i)+pz4(i)*vx4(i)
        dyx(i)=px1(i)*vy1(i)+px2(i)*vy2(i)+
     .         px3(i)*vy3(i)+px4(i)*vy4(i)
        dyz(i)=pz1(i)*vy1(i)+pz2(i)*vy2(i)+
     .         pz3(i)*vy3(i)+pz4(i)*vy4(i)
        dzx(i)=px1(i)*vz1(i)+px2(i)*vz2(i)+
     .         px3(i)*vz3(i)+px4(i)*vz4(i)
        dzy(i)=py1(i)*vz1(i)+py2(i)*vz2(i)+
     .         py3(i)*vz3(i)+py4(i)*vz4(i)
      ENDDO
C
      dt1d2=half*dt1
C
      IF(ismstr==2.OR.ismstr==4)THEN
C
C       2nd order correction is needed only w/large strain 
C       since small strain is not objective anyway
        DO i=1,nel
C
         exx=dxx(i)
         eyy=dyy(i)
         ezz=dzz(i)
         exy=dxy(i)
         eyx=dyx(i)
         exz=dxz(i)
         ezx=dzx(i)
         eyz=dyz(i)
         ezy=dzy(i)
C
C        Euler-Almansi A=1/2 [I-Invers(B)], with Left Cauchy-Green tensor B = F.Transp(F) 
C                        Invers(B)=Invers(Transp(F)).Invers(F)
C
C        small perturbation  A ~ (I-Transp(gradU)).(I-gradU)
C                            A ~ 1/2 (gradU + Transp(gradU) - Transp(gradU).gradU)
C
         dxx(i)  = dxx(i)-dt1d2*(exx*exx+eyx*eyx+ezx*ezx)
         dyy(i)  = dyy(i)-dt1d2*(eyy*eyy+ezy*ezy+exy*exy)
         dzz(i)  = dzz(i)-dt1d2*(ezz*ezz+exz*exz+eyz*eyz)
         aaa = dt1d2*(exx*exy+eyx*eyy+ezx*ezy)
         dxy(i)  = dxy(i) -aaa
         dyx(i)  = dyx(i) -aaa
         d4(i)   = dxy(i)+dyx(i)
         bbb = dt1d2*(eyy*eyz+ezy*ezz+exy*exz)
         dyz(i)  = dyz(i) -bbb
         dzy(i)  = dzy(i) -bbb
         d5(i)   = dyz(i)+dzy(i)
         ccc = dt1d2*(ezz*ezx+exz*exx+eyz*eyx)
         dxz(i)  = dxz(i) -ccc
         dzx(i)  = dzx(i) -ccc
         d6(i)   = dxz(i)+dzx(i)
C
C        WZZ(I)=DT1D2*(EYX-EXY)
C        WYY(I)=DT1D2*(EXZ-EZX)
C        WXX(I)=DT1D2*(EZY-EYZ)
C
C        B = F Transp(F) = V^2, F = V.R 
C        => R = [Invers(Transp(F)).F]^1/2
C        small perturbation  => R ~ I + 1/2 ( gradU - Transp(gradU) - Transp(gradU).gradU )
C
C                [ 0     wzz    -wyy ]
C        and R = [ wzz     0    -wxx ]
C                [ wyy   wxx       0 ]
C
         wzz(i)=dt1*(half*(eyx-exy)-aaa)
         wyy(i)=dt1*(half*(exz-ezx)-bbb)
         wxx(i)=dt1*(half*(ezy-eyz)-ccc)
        ENDDO
      ELSE ! ISMSTR==1 or Total Strain Formulation (Approximated Strain Rate)
        DO i=1,nel
         d4(i)   = dxy(i)+dyx(i)
         d5(i)   = dyz(i)+dzy(i)
         d6(i)   = dxz(i)+dzx(i)
         wzz(i)=dt1d2*(dyx(i)-dxy(i))
         wyy(i)=dt1d2*(dxz(i)-dzx(i))
         wxx(i)=dt1d2*(dzy(i)-dyz(i))
        ENDDO
      END IF
C
      RETURN
C