dsrgnor.F File Reference

#include "implicit_f.inc"
#include "com04_c.inc"
#include "task_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	dsrgnor (igrsurf, bufsf)

Function/Subroutine Documentation

dsrgnor()

subroutine dsrgnor	(	type (surf_), dimension(nsurf)	igrsurf,
			bufsf )

Definition at line 32 of file dsrgnor.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE groupdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real
     .     bufsf(*)
      TYPE (SURF_)   , DIMENSION(NSURF)   :: IGRSURF
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I3000
      INTEGER N,ADRBUF
      INTEGER INOE, I, J, K, DGR
      my_real xg,yg,zg,a,b,c,rot(9),
     1        an,bn,cn
      my_real
     1   ncor(3,384),
     2   nnor(3,384),
     3
     4 xl,yl,zl,e,
     5   xln,yln,zln,nxl,nyl,nzl,nx,ny,nz,normn
      my_real
     1   xx0,yy0,zz0,
     2   x0(6),y0(6),z0(6),dx0(6),dy0(6),dz0(6),dx1(6),dy1(6),dz1(6)
      DATA dx0/ 0., 0., 0., 0., 0., 0./
      DATA dy0/ 1.,-1., 0., 0., 0., 0./
      DATA dz0/ 0., 0.,-1., 1., 1.,-1./
      DATA dx1/ 1., 1., 1., 1., 0., 0./
      DATA dy1/ 0., 0., 0., 0., 1., 1./
      DATA dz1/ 0., 0., 0., 0., 0., 0./
      DATA x0 /-3.5,-3.5,-3.5,-3.5,-3.5, 3.5/
      DATA y0 /-3.5, 3.5,-3.5, 3.5,-3.5,-3.5/
      DATA z0 /-3.5, 3.5, 3.5,-3.5,-3.5, 3.5/
C-----------------------------------------------
      i3000 = 3000
      IF (ispmd/=0) GOTO 100
C
      DO 200 n=1,nsurf
       IF (igrsurf(n)%TYPE/=101) GOTO 200
       adrbuf=igrsurf(n)%IAD_BUFR
C-------------------------------------------------------
c      ellipsoid parameters
C-------------------------------------------------------
       dgr=bufsf(adrbuf+36)
       xg=bufsf(adrbuf+4)
       yg=bufsf(adrbuf+5)
       zg=bufsf(adrbuf+6)
       a =bufsf(adrbuf+1)
       b =bufsf(adrbuf+2)
       c =bufsf(adrbuf+3)
       DO i=1,9
        rot(i)=bufsf(adrbuf+7+i-1)
       END DO
C-------------------------------------------------------
C      compute nodes on the A,B,C cube
C-------------------------------------------------------
       inoe=0
       DO i = 1,6
        xx0 = x0(i)
        yy0 = y0(i)
        zz0 = z0(i)
        DO j = 1,8
          xl = xx0
          yl = yy0
          zl = zz0
          DO k = 1,8
            inoe=inoe+1
            ncor(1,inoe) = a*xl * third
            ncor(2,inoe) = b*yl * third
            ncor(3,inoe) = c*zl * third            
            xl = xl + dx0(i)
            yl = yl + dy0(i)
            zl = zl + dz0(i)
          ENDDO
          xx0 = xx0 + dx1(i)
          yy0 = yy0 + dy1(i)
          zz0 = zz0 + dz1(i)
        ENDDO
       ENDDO
C-------------------------------------------------------
C      compute the normal: radial projection
C-------------------------------------------------------
       an=a**dgr
       bn=b**dgr
       cn=c**dgr
       inoe=0
       DO i=1,384
        inoe=inoe+1
        xl=ncor(1,inoe)
        yl=ncor(2,inoe)
        zl=ncor(3,inoe)
C
        xln=xl**dgr
        yln=yl**dgr
        zln=zl**dgr
        e=abs(xln)/an+abs(yln)/bn+abs(zln)/cn
        e=exp(log(e)/dgr)
        xl=xl/e
        yl=yl/e
        zl=zl/e
C
        nxl=xl**(dgr-1)/an
        IF (xl*nxl<zero) nxl=-nxl
        nyl=yl**(dgr-1)/bn
        IF (yl*nyl<zero) nyl=-nyl
        nzl=zl**(dgr-1)/cn
        IF (zl*nzl<zero) nzl=-nzl
        nx  =rot(1)*nxl+rot(4)*nyl+rot(7)*nzl
        ny  =rot(2)*nxl+rot(5)*nyl+rot(8)*nzl
        nz  =rot(3)*nxl+rot(6)*nyl+rot(9)*nzl
        normn  =sqrt(nx*nx+ny*ny+nz*nz)
        nx  =nx/normn
        ny  =ny/normn
        nz  =nz/normn
        nnor(1,inoe)=three1000*nx
        nnor(2,inoe)=three1000*ny
        nnor(3,inoe)=three1000*nz        
       END DO
C-------------------------------------------------------
C      Writing normal to nodes.
C-------------------------------------------------------
       inoe=0
       DO i=1,384
        inoe=inoe+1
        nx = nnor(1,inoe)
        CALL write_s_c(nint(nx),1)
        ny = nnor(2,inoe)
        CALL write_s_c(nint(ny),1)
        nz = nnor(3,inoe)
        CALL write_s_c(nint(nz),1)
       END DO
C-------------------------------------------------------
 200   CONTINUE
 100  CONTINUE
      RETURN