eospolyno.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    eospolyno_mod   ../common_source/eos/eospolyno.F
!||--- called by ------------------------------------------------------
!||    eosmain         ../common_source/eos/eosmain.F
!||    eosmain51       ../engine/source/materials/mat/mat051/eosmain51.F90
!||====================================================================
      MODULE eospolyno_mod
      IMPLICIT NONE
      CONTAINS
!||====================================================================
!||    eospolyno       ../common_source/eos/eospolyno.F
!||--- called by ------------------------------------------------------
!||    eosmain         ../common_source/eos/eosmain.F
!||    eosmain51       ../engine/source/materials/mat/mat051/eosmain51.F90
!||--- uses       -----------------------------------------------------
!||    constant_mod    ../common_source/modules/constant_mod.F
!||    eos_param_mod   ../common_source/modules/mat_elem/eos_param_mod.F90
!||====================================================================
      SUBROUTINE eospolyno(
     1                     IFLAG,NEL  ,PMIN ,OFF  ,EINT ,MU   ,MU2 ,
     2                     ESPE ,DVOL ,DF   ,VNEW ,PSH ,
     3                     PNEW ,DPDM ,DPDE ,EOS_STRUCT)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
        USE constant_mod , ONLY : zero, em15, half, one, two, three, three100
        USE eos_param_mod , ONLY : eos_param_
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
!----------------------------------------------------------------------------
!! \details STAGGERED SCHEME IS EXECUTED IN TWO PASSES IN EOSMAIN : IFLG=0 THEN IFLG=1
!! \details COLLOCATED SCHEME IS DOING A SINGLE PASS : IFLG=2
!! \details
!! \details  STAGGERED SCHEME
!! \details     EOSMAIN / IFLG = 0 : DERIVATIVE CALCULATION FOR SOUND SPEED ESTIMATION c[n+1] REQUIRED FOR PSEUDO-VISCOSITY (DPDE:partial derivative, DPDM:total derivative)
!! \details     MQVISCB            : PSEUDO-VISCOSITY Q[n+1]
!! \details     MEINT              : INTERNAL ENERGY INTEGRATION FOR E[n+1] : FIRST PART USING P[n], Q[n], and Q[n+1] CONTRIBUTIONS
!! \details     EOSMAIN / IFLG = 1 : UPDATE P[n+1], T[N+1]
!! \details                          INTERNAL ENERGY INTEGRATION FOR E[n+1] : LAST PART USING P[n+1] CONTRIBUTION
!! \details                            (second order integration dE = -P.dV where P = 0.5(P[n+1] + P[n]) )
!! \details  COLLOCATED SCHEME
!! \details     EOSMAIN / IFLG = 2 : SINGLE PASS FOR P[n+1] AND DERIVATIVES
!----------------------------------------------------------------------------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        IMPLICIT NONE
#include      "my_real.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER :: IFLAG, NEL
      my_real,INTENT(INOUT) :: PNEW(NEL), DPDM(NEL), DPDE(NEL), PSH(NEL), EINT(NEL)
      my_real,INTENT(IN) :: OFF(NEL), MU(NEL), MU2(NEL), ESPE(NEL), DVOL(NEL), DF(NEL), VNEW(NEL), PMIN
      type(eos_param_),intent(in) :: eos_struct !< data structure for EoS parameters
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I
      my_real :: AA, BB, DVV, PP
      my_real :: C0,C1,C2,C3,C4,C5,C6
      my_real :: mu_pos
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
        c0         = eos_struct%UPARAM(1)
        c1         = eos_struct%UPARAM(2)
        c2         = eos_struct%UPARAM(3)
        c3         = eos_struct%UPARAM(4)
        c4         = eos_struct%UPARAM(5)
        c5         = eos_struct%UPARAM(6)
        c6         = eos_struct%UPARAM(7)
        psh(1:nel) = eos_struct%PSH
 
      IF(iflag == 0) THEN
        DO i=1,nel
          mu_pos  = max(zero,mu(i))
          pp      = c0 +(c1+c3*mu(i)*mu(i))*mu(i)+c2*mu2(i) + (c4 +c5 *mu(i) + c6*mu2(i))*espe(i)
          dpdm(i) = c1+two*c2*mu_pos+three*c3*mu(i)*mu(i) +(c5+c6*mu_pos)*espe(i) + (c4+c5*mu(i)+c6*mu2(i))*df(i)*df(i)*(pp+psh(i))
          dpde(i) = c4 + c5*mu(i) + c6*mu2(i)
          pnew(i) = max(pp,pmin)*off(i)! P(mu[n+1],E[n])
        ENDDO
 
      ELSEIF(iflag == 1) THEN
        DO i=1,nel
          aa      = c0 +mu(i)*(c1 +c3 *mu(i)*mu(i))+c2*mu2(i)
          bb      = c4 +c5*mu(i) + c6*mu2(i)
          dvv     = half*dvol(i)*df(i) / max(em15,vnew(i))
          pnew(i) = (aa+bb*(espe(i)-psh(i) *dvv))/(one+bb*dvv)
          pnew(i) = max(pnew(i),pmin )*off(i) ! P(mu[n+1],E[n+1])
          eint(i) = eint(i) - half*dvol(i)*(pnew(i)+psh(i))
          dpde(i) = bb
        ENDDO
 
      ELSEIF(iflag == 2) THEN
         DO i=1, nel
           IF (vnew(i) > zero) THEN
             mu_pos  = max(zero,mu(i))
             pnew(i) = c0 + (c1 +c3*mu(i)*mu(i))*mu(i) + c2*mu2(i) + (c4 +c5 *mu(i) + c6*mu2(i))*espe(i)
             dpde(i) = c4+c5*mu(i)+c6*mu2(i)
             dpdm(i) = c1 + two*c2*mu_pos + three*c3*mu(i)*mu(i) + (c5+c6*mu_pos)*espe(i) + (dpde(i))*df(i)*df(i)*(pnew(i)+psh(i))
             pnew(i) = max(pnew(i),pmin )*off(i)
           ENDIF
         ENDDO
       ENDIF
C------------------------
      RETURN
      END SUBROUTINE eospolyno
      END MODULE eospolyno_mod