eospolyno.F File Reference

#include "my_real.inc"
#include "param_c.inc"
#include "com04_c.inc"
#include "com06_c.inc"
#include "com08_c.inc"
#include "vect01_c.inc"
#include "scr06_c.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	eospolyno (iflag, nel, pm, off, eint, mu, mu2, espe, dvol, df, vnew, mat, psh, pnew, dpdm, dpde)

Function/Subroutine Documentation

eospolyno()

subroutine eospolyno	(	integer	iflag,
		integer	nel,
			pm,
			off,
			eint,
			mu,
			mu2,
			espe,
			dvol,
			df,
			vnew,
		integer, dimension(nel)	mat,
			psh,
			pnew,
			dpdm,
			dpde )

Definition at line 30 of file eospolyno.F.

C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
        USE constant_mod , ONLY : zero, em15, half, one, two, three, three100
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
!----------------------------------------------------------------------------
!! \details STAGGERED SCHEME IS EXECUTED IN TWO PASSES IN EOSMAIN : IFLG=0 THEN IFLG=1
!! \details COLLOCATED SCHEME IS DOING A SINGLE PASS : IFLG=2
!! \details
!! \details  STAGGERED SCHEME
!! \details     EOSMAIN / IFLG = 0 : DERIVATIVE CALCULATION FOR SOUND SPEED ESTIMATION c[n+1] REQUIRED FOR PSEUDO-VISCOSITY (DPDE:partial derivative, DPDM:total derivative)
!! \details     MQVISCB            : PSEUDO-VISCOSITY Q[n+1]
!! \details     MEINT              : INTERNAL ENERGY INTEGRATION FOR E[n+1] : FIRST PART USING P[n], Q[n], and Q[n+1] CONTRIBUTIONS
!! \details     EOSMAIN / IFLG = 1 : UPDATE P[n+1], T[N+1]
!! \details                          INTERNAL ENERGY INTEGRATION FOR E[n+1] : LAST PART USING P[n+1] CONTRIBUTION
!! \details                            (second order integration dE = -P.dV where P = 0.5(P[n+1] + P[n]) )
!! \details  COLLOCATED SCHEME
!! \details     EOSMAIN / IFLG = 2 : SINGLE PASS FOR P[n+1] AND DERIVATIVES
!----------------------------------------------------------------------------
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
        IMPLICIT NONE
#include      "my_real.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com04_c.inc"
#include      "com06_c.inc"
#include      "com08_c.inc"
#include      "vect01_c.inc"
#include      "scr06_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        INTEGER MAT(NEL), IFLAG, NEL
        my_real pm(npropm,nummat),
     .          off(nel)  ,eint(nel) ,mu(nel)   ,
     .          mu2(nel)  ,espe(nel) ,dvol(nel) ,df(nel)  ,
     .          vnew(nel) ,psh(nel)  ,pnew(nel) ,dpdm(nel),
     .          dpde(nel)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        INTEGER :: I, MX
        my_real :: aa, bb, dvv, pp
        my_real :: c0,c1,c2,c3,c4,c5,pc,sph
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
        IF(iflag == 0) THEN
          mx         = mat(1)
          c0         = pm(104,mx)
          c1         = pm( 32,mx)
          c2         = pm( 33,mx)
          c3         = pm( 34,mx)
          c4         = pm( 35,mx)
          c5         = pm( 36,mx)
          sph        = pm( 69,mx)
          psh(1:nel) = pm( 88,mx)
          pc         = pm( 37,mx)
          DO i=1,nel
            pp      = c0 +(c1 +c3 *mu(i)*mu(i))*mu(i)+c2 *mu2(i) + (c4 +c5 *mu(i))*espe(i)
            dpdm(i) = c1 + two*c2 *max(zero,mu(i))+three*c3 *mu(i)*mu(i) + c5 *espe(i)+(c4 +c5 *mu(i))*df(i)*df(i)*(pp+psh(i) )
            dpde(i) = c4 +c5 *mu(i)
            pnew(i) = max(pp,pc)*off(i)! P(mu[n+1],E[n])
          ENDDO
 
        ELSEIF(iflag == 1) THEN
          mx  = mat(1)
          c0  = pm(104,mx)
          c1  = pm( 32,mx)
          c2  = pm( 33,mx)
          c3  = pm( 34,mx)
          c4  = pm( 35,mx)
          c5  = pm( 36,mx)
          pc  = pm( 37,mx)
          psh(1:nel) = pm(88,mx)
          DO i=1,nel
            aa      = c0 +mu(i)*(c1 +c3 *mu(i)*mu(i))+c2 *mu2(i)
            bb      = c4 +c5 *mu(i)
            dvv     = half*dvol(i)*df(i) / max(em15,vnew(i))
            pnew(i) = (aa+bb*(espe(i)-psh(i) *dvv))/(one+bb*dvv)
            pnew(i) = max(pnew(i),pc )*off(i) ! P(mu[n+1],E[n+1])
            eint(i) = eint(i) - half*dvol(i)*(pnew(i)+psh(i))
            dpde(i) = c4 +c5 *mu(i)
          ENDDO
 
        ELSEIF(iflag == 2) THEN
          mx  = mat(1)
          c0  = pm(104,mx)
          c1  = pm( 32,mx)
          c2  = pm( 33,mx)
          c3  = pm( 34,mx)
          c4  = pm( 35,mx)
          c5  = pm( 36,mx)
          sph = pm( 69,mx)
          psh(1:nel) = pm(88,mx)
          pc  = pm(37,mx)
          DO i=1, nel
            IF (vnew(i) > zero) THEN
              pnew(i) = c0 +(c1 +c3 *mu(i)*mu(i))*mu(i)+c2 *mu2(i) + (c4 +c5 *mu(i))*espe(i)
              dpdm(i) = c1 + two*c2 *max(zero,mu(i))+three*c3 *mu(i)*mu(i) +
     .             c5 *espe(i)+(c4 +c5 *mu(i))*df(i)*df(i)*(pnew(i)+psh(i) )
              dpde(i) = c4 +c5 *mu(i)
              pnew(i) = max(pnew(i),pc )*off(i)
            ENDIF
          ENDDO
        ENDIF
C------------------------
        RETURN