fail_emc.F File Reference

#include "implicit_f.inc"
#include "units_c.inc"
#include "param_c.inc"
#include "scr17_c.inc"
#include "comlock.inc"
#include "lockon.inc"
#include "lockoff.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	fail_emc (nel, nuvar, time, timestep, uparam, ngl, signxx, signyy, signzz, signxy, signyz, signzx, plas, dpla, epsp, uvar, off, dfmax, tdele)

Function/Subroutine Documentation

fail_emc()

subroutine fail_emc	(	integer	nel,
		integer	nuvar,
			time,
			timestep,
			uparam,
		integer, dimension(nel)	ngl,
			signxx,
			signyy,
			signzz,
			signxy,
			signyz,
			signzx,
			plas,
			dpla,
			epsp,
			uvar,
			off,
			dfmax,
			tdele )

Definition at line 32 of file fail_emc.F.

C---------+---------+---+---+--------------------------------------------
c---------+---------+---+---+--------------------------------------------
C   /FAIL/EMC - tabulated rupture criteria for solids
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C---------+---------+---+---+--------------------------------------------
C VAR     | SIZE    |TYP| RW| DEFINITION
C---------+---------+---+---+--------------------------------------------
C NEL     |  1      | I | R | SIZE OF THE ELEMENT GROUP NEL 
C NUPARAM |  1      | I | R | SIZE OF THE USER PARAMETER ARRAY
C NUVAR   |  1      | I | R | NUMBER OF FAILURE ELEMENT VARIABLES
C---------+---------+---+---+--------------------------------------------
C TIME    |  1      | F | R | CURRENT TIME
C TIMESTEP|  1      | F | R | CURRENT TIME STEP
C UPARAM  | NUPARAM | F | R | USER FAILURE PARAMETER ARRAY
C---------+---------+---+---+--------------------------------------------
C SIGNXX  | NEL     | F | W | NEW ELASTO PLASTIC STRESS XX
C SIGNYY  | NEL     | F | W | NEW ELASTO PLASTIC STRESS YY
C ...     |         |   |   |
C ...     |         |   |   |
C---------+---------+---+---+--------------------------------------------
C UVAR    |NEL*NUVAR| F |R/W| USER ELEMENT VARIABLE ARRAY
C OFF     | NEL     | F |R/W| DELETED ELEMENT FLAG (=1. ON, =0. OFF)
C---------+---------+---+---+--------------------------------------------
#include "units_c.inc"
#include "param_c.inc"
#include "scr17_c.inc"
#include "comlock.inc"
C-----------------------------------------------
C   I N P U T   A r g u m e n t s
C-----------------------------------------------
      INTEGER NEL,NUVAR
      INTEGER NGL(NEL)
c
      my_real time,timestep,uparam(*),
     .   signxx(nel),signyy(nel),signzz(nel),
     .   signxy(nel),signyz(nel),signzx(nel),
     .   plas(nel),dpla(nel),epsp(nel)
C-----------------------------------------------
C   O U T P U T   A r g u m e n t s
C-----------------------------------------------
cc      my_real
C-----------------------------------------------
C   I N P U T   O U T P U T   A r g u m e n t s 
C-----------------------------------------------
      my_real 
     .   uvar(nel,nuvar), off(nel),dfmax(nel),tdele(nel)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,JJ,K,IR,IADBUF,NINDX,IFAIL
      INTEGER, DIMENSION(NEL) :: 
     .   INDX
C
      my_real 
     .    seq,inv2,eta,sigm,xi,epsf,
     .    devxx,devyy,devzz,bcoef,lode,dam,
     .    bfrac,gama,cfrac,deps0,
     .    plap,f1,f2,f3,afrac,nfrac
      my_real :: df12, df23, df13
C=======================================================================
C     INITIALIZATIONS
C-----------------------------------------------
      afrac  = uparam(1)
      bfrac  = uparam(2)
      gama   = uparam(3)
      cfrac  = uparam(4)
      nfrac  = uparam(5)
      deps0  = uparam(6)
      plap   = 0
C-----------------------------------------------
      indx = 0                                  
      nindx  = 0  
C-------------------------------------------------------------------
c     Failure strain value - function interpolation
C-------------------------------------------------------------------
       DO i=1,nel
        
        dam = uvar(i,2)
        IF (off(i) < 0.1) off(i)=zero
        IF (off(i) < one)  off(i)=off(i)*four_over_5
 
        IF (plas(i) > zero .and. off(i) == one) THEN
C---      failure strain interpolation
 
          plap = dpla(i)/timestep
          
          sigm  = (signxx(i)+signyy(i)+signzz(i))*third
          devxx = signxx(i) - sigm
          devyy = signyy(i) - sigm
          devzz = signzz(i) - sigm
          seq   = sqrt(three_half*(devxx*devxx 
     .                       +devyy*devyy
     .                       +devzz*devzz
     .                + two*(signxy(i)*signxy(i)
     .                       +signyz(i)*signyz(i)
     .                       +signzx(i)*signzx(i))))
 
            ! determinant du deviateur des contraintes
          inv2 = devxx * devyy * devzz 
     .         + two*signxy(i)*signzx(i)*signyz(i)
     .         - devxx*signyz(i)**2 - devyy*signzx(i)**2
     .         - devzz*signxy(i)**2
 
          IF (seq == zero) THEN
            eta = third
            xi  = zero
          ELSE    
            eta = sigm/seq
            xi  = one/seq**3
            xi  = half*twenty7*inv2*xi
          ENDIF
          
          IF (xi < -one) xi =-one
          IF (xi >  one) xi = one
 
          lode = one - two*acos(xi)/pi
          
          f1 = two_third*cos((one   -lode)*pi/six)
          f2 = two_third*cos((three+lode)*pi/six)
          f3 =-two_third*cos((one   +lode)*pi/six)
          plap  = max(plap,deps0)
          bcoef = bfrac*(one+gama*log(plap/deps0))
 
          IF (eta < -third) THEN
            epsf = ep02
          ELSE
            df12 = max(em20,f1-f2)
            df23 = max(em20,f2-f3)
            df13 = max(em20,f1-f3)
            epsf = bcoef*(one+cfrac)**(one/nfrac)
     .           * ((half*(df12**afrac  
     .                      +df23**afrac
     .                      +df13**afrac))**(one/afrac)
     .           +   cfrac*(two*eta+f1+f3))**(-one/nfrac)
 
          ENDIF
 
          dam = uvar(i,2) + (plas(i) - uvar(i,1))/epsf
 
          uvar(i,1) = plas(i)
          uvar(i,2) = dam  
          dfmax(i)  = min(one,max(dfmax(i),dam ))        
c
          IF (dam >= one) THEN
            off(i) = four_over_5
            nindx  = nindx+1
            indx(nindx)=i
            tdele(i) = time                
          ENDIF         
        ENDIF
        ! EPSF(I) = YY
c
       ENDDO
c-----------------------------
       IF (nindx > 0 )THEN
         DO j=1,nindx
#include "lockon.inc"
           WRITE(iout, 1000) ngl(indx(j))
           WRITE(istdo,1100) ngl(indx(j)),time
#include "lockoff.inc"
         ENDDO
      
      ENDIF
c-----------------------------------------------
 1000 FORMAT(1x,'DELETE SOLID ELEMENT NUMBER ',i10)
 1100 FORMAT(1x,'DELETE SOLID ELEMENT NUMBER ',i10,
     .          ' AT TIME :',1pe12.4)
c-----------           
      RETURN