fail_rtcl_s.F File Reference

#include "implicit_f.inc"
#include "mvsiz_p.inc"
#include "scr17_c.inc"
#include "units_c.inc"
#include "comlock.inc"
#include "lockon.inc"
#include "lockoff.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	fail_rtcl_s (nel, nuparam, nuvar, time, timestep, uparam, signxx, signyy, signzz, signxy, signyz, signzx, ngl, dpla, uvar, off, dfmax, tdele)

Function/Subroutine Documentation

fail_rtcl_s()

subroutine fail_rtcl_s	(	integer	nel,
		integer	nuparam,
		integer	nuvar,
			time,
			timestep,
			uparam,
			signxx,
			signyy,
			signzz,
			signxy,
			signyz,
			signzx,
		integer, dimension(nel)	ngl,
			dpla,
			uvar,
			off,
			dfmax,
			tdele )

Definition at line 32 of file fail_rtcl_s.F.

C!-----------------------------------------------
C!   I m p l i c i t   T y p e s
C!-----------------------------------------------
#include "implicit_f.inc"
C!---------+---------+---+---+-------------------
#include "mvsiz_p.inc"
#include "scr17_c.inc"
#include "units_c.inc"
#include "comlock.inc"
C!-----------------------------------------------
      INTEGER NEL, NUPARAM, NUVAR,NGL(NEL)
      my_real time,timestep,uparam(*),
     .   signxx(nel),signyy(nel),signzz(nel),
     .   signxy(nel),signyz(nel),signzx(nel),uvar(nel,nuvar),
     .   dpla(nel),off(nel),dfmax(nel),tdele(nel)
C!-----------------------------------------------
C!   L o c a l   V a r i a b l e s
C!-----------------------------------------------
      INTEGER I,J,INDX(MVSIZ),NINDX
      my_real 
     .        p,triaxs,svm,sxx,syy,szz,eps_cr,f_rtcl
C!--------------------------------------------------------------
      !=======================================================================
      ! - INITIALISATION OF COMPUTATION ON TIME STEP
      !=======================================================================
      ! Recovering model parameters
      eps_cr = uparam(1)
c
      ! Checking element failure and recovering user variable
      DO i=1,nel
       IF (off(i) < em01) off(i) = zero
       IF (off(i) < one .AND. off(i) > zero) off(i) = off(i)*four_over_5
      END DO
C
      ! Initialization of variable
      nindx = 0  
c      
      !====================================================================
      ! - LOOP OVER THE ELEMENT TO COMPUTE THE DAMAGE VARIABLE
      !====================================================================       
      DO i=1,nel
c
        ! If the element is not broken
        IF (off(i) ==  one .AND. dpla(i) /= zero) THEN
c        
          ! Computation of hydrostatic stress, Von Mises stress, and stress triaxiality
          p   = third*(signxx(i) + signyy(i) + signzz(i))
          sxx = signxx(i) - p
          syy = signyy(i) - p
          szz = signzz(i) - p
          svm = half*(sxx**2 + syy**2 + szz**2)
     .          + signxy(i)**2 + signzx(i)**2 + signyz(i)**2
          svm = sqrt(three*svm)
          triaxs = p/max(em20,svm)
          IF (triaxs > one)  triaxs = one
          IF (triaxs < -one) triaxs = -one
c
          ! Computing the plastic strain at failure according to stress triaxiality
          IF (triaxs < -third) THEN 
            f_rtcl = zero
          ELSEIF ((triaxs >= -third).AND.(triaxs < third)) THEN
            f_rtcl = two*((one+triaxs*sqrt(twelve-twenty7*(triaxs**2)))/
     .                  (three*triaxs+sqrt(twelve-twenty7*(triaxs**2))))
          ELSE
            f_rtcl = exp(-half)*exp(three_half*triaxs)
          ENDIF
c
          ! Computation of damage variables
          dfmax(i) = dfmax(i) + f_rtcl*dpla(i)/max(eps_cr,em6)
          dfmax(i) = min(one,dfmax(i))
c
          ! Checking element failure using global damage
          IF (dfmax(i) >= one .AND. off(i) == one) THEN
            off(i)      = four_over_5
            nindx       = nindx + 1
            indx(nindx) = i
            tdele(i)    = time    
          ENDIF
        ENDIF 
      ENDDO
c------------------------
c------------------------
      IF (nindx > 0) THEN
        DO j=1,nindx
          i = indx(j)     
#include "lockon.inc"
          WRITE(iout, 1000) ngl(i),time
          WRITE(istdo,1100) ngl(i),time
#include "lockoff.inc"
        END DO
      END IF         
c------------------------
 1000 FORMAT(1x,'DELETE SOLID ELEMENT NUMBER (RTCL) el#',i10,
     .          ' AT TIME :',1pe12.4)     
 1100 FORMAT(1x,'DELETE SOLID ELEMENT NUMBER (RTCL) el#',i10,
     .          ' AT TIME :',1pe12.4)