fail_tbutcher_c.F File Reference

#include "implicit_f.inc"
#include "units_c.inc"
#include "comlock.inc"
#include "lockon.inc"
#include "lockoff.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	fail_tbutcher_c (nel, nuparam, nuvar, uparam, uvar, time, timestep, ipg, ilay, ipt, signxx, signyy, signxy, signyz, signzx, ngl, off, foff, dfmax, tdel)

Function/Subroutine Documentation

fail_tbutcher_c()

subroutine fail_tbutcher_c	(	integer, intent(in)	nel,
		integer, intent(in)	nuparam,
		integer, intent(in)	nuvar,
		intent(in)	uparam,
		intent(inout)	uvar,
		intent(in)	time,
		intent(in)	timestep,
		integer, intent(in)	ipg,
		integer, intent(in)	ilay,
		integer, intent(in)	ipt,
		intent(in)	signxx,
		intent(in)	signyy,
		intent(in)	signxy,
		intent(in)	signyz,
		intent(in)	signzx,
		integer, dimension(nel), intent(in)	ngl,
		intent(in)	off,
		integer, dimension(nel), intent(inout)	foff,
		intent(inout)	dfmax,
		intent(out)	tdel )

Definition at line 29 of file fail_tbutcher_c.F.

C---------+---------+---+---+--------------------------------------------
c    Tuler Butcher Failure model
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C---------+---------+---+---+--------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include  "units_c.inc"
#include  "comlock.inc"
C-----------------------------------------------
C VAR     | SIZE    |TYP| RW| DEFINITION
C---------+---------+---+---+--------------------------------------------
C NEL     |  1      | I | R | SIZE OF THE ELEMENT GROUP NEL 
C NUPARAM |  1      | I | R | SIZE OF THE USER PARAMETER ARRAY
C UPARAM  | NUPARAM | F | R | USER MATERIAL PARAMETER ARRAY
C NUVAR   |  1      | I | R | NUMBER OF USER ELEMENT VARIABLES
C UVAR    |NEL*NUVAR| F |R/W| USER ELEMENT VARIABLE ARRAY
C---------+---------+---+---+--------------------------------------------
C TIME    |  1      | F | R | CURRENT TIME
C TIMESTEP|  1      | F | R | CURRENT TIME STEP
C---------+---------+---+---+--------------------------------------------
C SIGNXX  | NEL     | F | R | NEW ELASTO PLASTIC STRESS XX
C SIGNYY  | NEL     | F | R | NEW ELASTO PLASTIC STRESS YY
C ...     |         |   |   |
C---------+---------+---+---+--------------------------------------------
C OFF     | NEL     | F | R | DELETED ELEMENT FLAG (=1. ON, =0. OFF)
C FOFF    | NEL     | I |R/W| DELETED INTEGRATION POINT FLAG (=1 ON, =0 OFF)
C DFMAX   | NEL     | F |R/W| MAX DAMAGE FACTOR 
C TDEL    | NEL     | F | W | FAILURE TIME
C---------+---------+---+---+--------------------------------------------
C NGL                         ELEMENT ID
C IPG                         CURRENT GAUSS POINT (in plane)
C ILAY                        CURRENT LAYER
C IPT                         CURRENT INTEGRATION POINT IN THE LAYER (FOR OUTPUT ONLY)
C-----------------------------------------------
C   I N P U T   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(IN) :: NEL,NUPARAM,NUVAR,IPG,ILAY,IPT
      INTEGER ,DIMENSION(NEL), INTENT(IN) :: NGL
      my_real ,INTENT(IN) :: time
      my_real ,DIMENSION(NEL), INTENT(IN) :: timestep,off,
     .   signxx,signyy,signxy,signyz,signzx
      my_real,DIMENSION(NUPARAM), INTENT(IN) :: uparam
C-----------------------------------------------
C   I N P U T   O U T P U T   A r g u m e n t s 
C-----------------------------------------------
      INTEGER ,DIMENSION(NEL), INTENT(INOUT) :: FOFF
      my_real ,DIMENSION(NEL), INTENT(INOUT) :: dfmax
      my_real ,DIMENSION(NEL), INTENT(OUT)   :: tdel
      my_real ,DIMENSION(NEL,NUVAR) ,INTENT(INOUT) :: uvar
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,J,NINDX
      INTEGER ,DIMENSION(NEL) ::  INDX
      my_real :: tba,tbk,kk,sigmax,sigr_ini,sig1,sig2,s1,s2
C=======================================================================
      tba      = uparam(1)                           
      tbk      = uparam(2)                           
      sigr_ini = uparam(3)                        
      nindx  = 0  
C-----------------------------------------------
      DO i=1,nel                                             
        IF (off(i) == one .and. foff(i) == 1) THEN                               
          s1 = half*(signxx(i) + signyy(i))                
          s2 = half*(signxx(i) - signyy(i))                
          sig1 = s1 + sqrt(s2**2 + signxy(i)**2)            
          sig2 = s1 - sqrt(s2**2 + signxy(i)**2)            
          sigmax = max(sig1,sig2)                            
          IF (sigmax > sigr_ini) uvar(i,1) = uvar(i,1)               
     .        + timestep(i)*(sigmax - sigr_ini)**tba         
          IF (uvar(i,1) >= tbk) THEN                         
            nindx = nindx + 1
            indx(nindx) = i
            foff(i) = 0
            tdel(i) = time
          ENDIF                                              
        ENDIF                                                
      ENDDO                                                  
c
c---  Maximum Damage storing for output : 0 < DFMAX < 1
      DO i=1,nel
        dfmax(i) = min(one, max(dfmax(i),uvar(i,1)/tbk))
      ENDDO
c------------------------
      IF (nindx > 0) THEN
        DO j=1,nindx
          i = indx(j)
#include  "lockon.inc"
          WRITE(iout, 2000) ngl(i),ipg,ilay,ipt
          WRITE(istdo,2100) ngl(i),ipg,ilay,ipt,time
#include  "lockoff.inc"
        END DO
      END IF              
c------------------------
 2000 FORMAT(1x,'failure(tb) of shell element ',I10,1X,',gauss pt',
     .       I2,1X,',layer',I3,1X,',integration pt',I3)
 2100 FORMAT(1X,'failure(tb) of shell element ',I10,1X,',gauss pt',
     .       I2,1X,',layer',I3,1X,',integration pt',I3,1X,'at time :',1PE12.4)
c------------------------
      RETURN