double

Functions
subroutine	dptcon (n, d, e, anorm, rcond, work, info)
	DPTCON
subroutine	dpteqr (compz, n, d, e, z, ldz, work, info)
	DPTEQR
subroutine	dptrfs (n, nrhs, d, e, df, ef, b, ldb, x, ldx, ferr, berr, work, info)
	DPTRFS
subroutine	dpttrf (n, d, e, info)
	DPTTRF
subroutine	dpttrs (n, nrhs, d, e, b, ldb, info)
	DPTTRS
subroutine	dptts2 (n, nrhs, d, e, b, ldb)
	DPTTS2 solves a tridiagonal system of the form AX=B using the L D LH factorization computed by spttrf.

Detailed Description

This is the group of double computational functions for PT matrices

Function Documentation

dptcon()

subroutine dptcon	(	integer	n,
		double precision, dimension( * )	d,
		double precision, dimension( * )	e,
		double precision	anorm,
		double precision	rcond,
		double precision, dimension( * )	work,
		integer	info )

DPTCON

Download DPTCON + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DPTCON computes the reciprocal of the condition number (in the
!> 1-norm) of a real symmetric positive definite tridiagonal matrix
!> using the factorization A = L*D*L**T or A = U**T*D*U computed by
!> DPTTRF.
!>
!> Norm(inv(A)) is computed by a direct method, and the reciprocal of
!> the condition number is computed as
!>              RCOND = 1 / (ANORM * norm(inv(A))).
!> 

Parameters

[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	D	!> D is DOUBLE PRECISION array, dimension (N) !> The n diagonal elements of the diagonal matrix D from the !> factorization of A, as computed by DPTTRF. !>
[in]	E	!> E is DOUBLE PRECISION array, dimension (N-1) !> The (n-1) off-diagonal elements of the unit bidiagonal factor !> U or L from the factorization of A, as computed by DPTTRF. !>
[in]	ANORM	!> ANORM is DOUBLE PRECISION !> The 1-norm of the original matrix A. !>
[out]	RCOND	!> RCOND is DOUBLE PRECISION !> The reciprocal of the condition number of the matrix A, !> computed as RCOND = 1/(ANORM * AINVNM), where AINVNM is the !> 1-norm of inv(A) computed in this routine. !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Further Details:

!>
!>  The method used is described in Nicholas J. Higham, , SIAM J. Sci. Stat. Comput., Vol. 7, No. 1, January 1986.
!> 

Definition at line 117 of file dptcon.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, N
      DOUBLE PRECISION   ANORM, RCOND
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D( * ), E( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IX
      DOUBLE PRECISION   AINVNM
*     ..
*     .. External Functions ..
      INTEGER            IDAMAX
      EXTERNAL           idamax
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments.
*
      info = 0
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( anorm.LT.zero ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DPTCON', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      rcond = zero
      IF( n.EQ.0 ) THEN
         rcond = one
         RETURN
      ELSE IF( anorm.EQ.zero ) THEN
         RETURN
      END IF
*
*     Check that D(1:N) is positive.
*
      DO 10 i = 1, n
         IF( d( i ).LE.zero )
     $      RETURN
   10 CONTINUE
*
*     Solve M(A) * x = e, where M(A) = (m(i,j)) is given by
*
*        m(i,j) =  abs(A(i,j)), i = j,
*        m(i,j) = -abs(A(i,j)), i .ne. j,
*
*     and e = [ 1, 1, ..., 1 ]**T.  Note M(A) = M(L)*D*M(L)**T.
*
*     Solve M(L) * x = e.
*
      work( 1 ) = one
      DO 20 i = 2, n
         work( i ) = one + work( i-1 )*abs( e( i-1 ) )
   20 CONTINUE
*
*     Solve D * M(L)**T * x = b.
*
      work( n ) = work( n ) / d( n )
      DO 30 i = n - 1, 1, -1
         work( i ) = work( i ) / d( i ) + work( i+1 )*abs( e( i ) )
   30 CONTINUE
*
*     Compute AINVNM = max(x(i)), 1<=i<=n.
*
      ix = idamax( n, work, 1 )
      ainvnm = abs( work( ix ) )
*
*     Compute the reciprocal condition number.
*
      IF( ainvnm.NE.zero )
     $   rcond = ( one / ainvnm ) / anorm
*
      RETURN
*
*     End of DPTCON
*

dpteqr()

subroutine dpteqr	(	character	compz,
		integer	n,
		double precision, dimension( * )	d,
		double precision, dimension( * )	e,
		double precision, dimension( ldz, * )	z,
		integer	ldz,
		double precision, dimension( * )	work,
		integer	info )

DPTEQR

Download DPTEQR + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DPTEQR computes all eigenvalues and, optionally, eigenvectors of a
!> symmetric positive definite tridiagonal matrix by first factoring the
!> matrix using DPTTRF, and then calling DBDSQR to compute the singular
!> values of the bidiagonal factor.
!>
!> This routine computes the eigenvalues of the positive definite
!> tridiagonal matrix to high relative accuracy.  This means that if the
!> eigenvalues range over many orders of magnitude in size, then the
!> small eigenvalues and corresponding eigenvectors will be computed
!> more accurately than, for example, with the standard QR method.
!>
!> The eigenvectors of a full or band symmetric positive definite matrix
!> can also be found if DSYTRD, DSPTRD, or DSBTRD has been used to
!> reduce this matrix to tridiagonal form. (The reduction to tridiagonal
!> form, however, may preclude the possibility of obtaining high
!> relative accuracy in the small eigenvalues of the original matrix, if
!> these eigenvalues range over many orders of magnitude.)
!> 

Parameters

[in]	COMPZ	!> COMPZ is CHARACTER*1 !> = 'N': Compute eigenvalues only. !> = 'V': Compute eigenvectors of original symmetric !> matrix also. Array Z contains the orthogonal !> matrix used to reduce the original matrix to !> tridiagonal form. !> = 'I': Compute eigenvectors of tridiagonal matrix also. !>
[in]	N	!> N is INTEGER !> The order of the matrix. N >= 0. !>
[in,out]	D	!> D is DOUBLE PRECISION array, dimension (N) !> On entry, the n diagonal elements of the tridiagonal !> matrix. !> On normal exit, D contains the eigenvalues, in descending !> order. !>
[in,out]	E	!> E is DOUBLE PRECISION array, dimension (N-1) !> On entry, the (n-1) subdiagonal elements of the tridiagonal !> matrix. !> On exit, E has been destroyed. !>
[in,out]	Z	!> Z is DOUBLE PRECISION array, dimension (LDZ, N) !> On entry, if COMPZ = 'V', the orthogonal matrix used in the !> reduction to tridiagonal form. !> On exit, if COMPZ = 'V', the orthonormal eigenvectors of the !> original symmetric matrix; !> if COMPZ = 'I', the orthonormal eigenvectors of the !> tridiagonal matrix. !> If INFO > 0 on exit, Z contains the eigenvectors associated !> with only the stored eigenvalues. !> If COMPZ = 'N', then Z is not referenced. !>
[in]	LDZ	!> LDZ is INTEGER !> The leading dimension of the array Z. LDZ >= 1, and if !> COMPZ = 'V' or 'I', LDZ >= max(1,N). !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (4*N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit. !> < 0: if INFO = -i, the i-th argument had an illegal value. !> > 0: if INFO = i, and i is: !> <= N the Cholesky factorization of the matrix could !> not be performed because the i-th principal minor !> was not positive definite. !> > N the SVD algorithm failed to converge; !> if INFO = N+i, i off-diagonal elements of the !> bidiagonal factor did not converge to zero. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 144 of file dpteqr.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          COMPZ
      INTEGER            INFO, LDZ, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D( * ), E( * ), WORK( * ), Z( LDZ, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           dbdsqr, dlaset, dpttrf, xerbla
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   C( 1, 1 ), VT( 1, 1 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, ICOMPZ, NRU
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
*
      IF( lsame( compz, 'N' ) ) THEN
         icompz = 0
      ELSE IF( lsame( compz, 'V' ) ) THEN
         icompz = 1
      ELSE IF( lsame( compz, 'I' ) ) THEN
         icompz = 2
      ELSE
         icompz = -1
      END IF
      IF( icompz.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( ( ldz.LT.1 ) .OR. ( icompz.GT.0 .AND. ldz.LT.max( 1,
     $         n ) ) ) THEN
         info = -6
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DPTEQR', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( n.EQ.1 ) THEN
         IF( icompz.GT.0 )
     $      z( 1, 1 ) = one
         RETURN
      END IF
      IF( icompz.EQ.2 )
     $   CALL dlaset( 'Full', n, n, zero, one, z, ldz )
*
*     Call DPTTRF to factor the matrix.
*
      CALL dpttrf( n, d, e, info )
      IF( info.NE.0 )
     $   RETURN
      DO 10 i = 1, n
         d( i ) = sqrt( d( i ) )
   10 CONTINUE
      DO 20 i = 1, n - 1
         e( i ) = e( i )*d( i )
   20 CONTINUE
*
*     Call DBDSQR to compute the singular values/vectors of the
*     bidiagonal factor.
*
      IF( icompz.GT.0 ) THEN
         nru = n
      ELSE
         nru = 0
      END IF
      CALL dbdsqr( 'Lower', n, 0, nru, 0, d, e, vt, 1, z, ldz, c, 1,
     $             work, info )
*
*     Square the singular values.
*
      IF( info.EQ.0 ) THEN
         DO 30 i = 1, n
            d( i ) = d( i )*d( i )
   30    CONTINUE
      ELSE
         info = n + info
      END IF
*
      RETURN
*
*     End of DPTEQR
*

dptrfs()

subroutine dptrfs	(	integer	n,
		integer	nrhs,
		double precision, dimension( * )	d,
		double precision, dimension( * )	e,
		double precision, dimension( * )	df,
		double precision, dimension( * )	ef,
		double precision, dimension( ldb, * )	b,
		integer	ldb,
		double precision, dimension( ldx, * )	x,
		integer	ldx,
		double precision, dimension( * )	ferr,
		double precision, dimension( * )	berr,
		double precision, dimension( * )	work,
		integer	info )

DPTRFS

Download DPTRFS + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DPTRFS improves the computed solution to a system of linear
!> equations when the coefficient matrix is symmetric positive definite
!> and tridiagonal, and provides error bounds and backward error
!> estimates for the solution.
!> 

Parameters

[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrix B. NRHS >= 0. !>
[in]	D	!> D is DOUBLE PRECISION array, dimension (N) !> The n diagonal elements of the tridiagonal matrix A. !>
[in]	E	!> E is DOUBLE PRECISION array, dimension (N-1) !> The (n-1) subdiagonal elements of the tridiagonal matrix A. !>
[in]	DF	!> DF is DOUBLE PRECISION array, dimension (N) !> The n diagonal elements of the diagonal matrix D from the !> factorization computed by DPTTRF. !>
[in]	EF	!> EF is DOUBLE PRECISION array, dimension (N-1) !> The (n-1) subdiagonal elements of the unit bidiagonal factor !> L from the factorization computed by DPTTRF. !>
[in]	B	!> B is DOUBLE PRECISION array, dimension (LDB,NRHS) !> The right hand side matrix B. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[in,out]	X	!> X is DOUBLE PRECISION array, dimension (LDX,NRHS) !> On entry, the solution matrix X, as computed by DPTTRS. !> On exit, the improved solution matrix X. !>
[in]	LDX	!> LDX is INTEGER !> The leading dimension of the array X. LDX >= max(1,N). !>
[out]	FERR	!> FERR is DOUBLE PRECISION array, dimension (NRHS) !> The forward error bound for each solution vector !> X(j) (the j-th column of the solution matrix X). !> If XTRUE is the true solution corresponding to X(j), FERR(j) !> is an estimated upper bound for the magnitude of the largest !> element in (X(j) - XTRUE) divided by the magnitude of the !> largest element in X(j). !>
[out]	BERR	!> BERR is DOUBLE PRECISION array, dimension (NRHS) !> The componentwise relative backward error of each solution !> vector X(j) (i.e., the smallest relative change in !> any element of A or B that makes X(j) an exact solution). !>
[out]	WORK	!> WORK is DOUBLE PRECISION array, dimension (2*N) !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -i, the i-th argument had an illegal value !>

Internal Parameters:

!>  ITMAX is the maximum number of steps of iterative refinement.
!> 

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 161 of file dptrfs.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDB, LDX, N, NRHS
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   B( LDB, * ), BERR( * ), D( * ), DF( * ),
     $                   E( * ), EF( * ), FERR( * ), WORK( * ),
     $                   X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            ITMAX
      parameter( itmax = 5 )
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d+0 )
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d+0 )
      DOUBLE PRECISION   TWO
      parameter( two = 2.0d+0 )
      DOUBLE PRECISION   THREE
      parameter( three = 3.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            COUNT, I, IX, J, NZ
      DOUBLE PRECISION   BI, CX, DX, EPS, EX, LSTRES, S, SAFE1, SAFE2,
     $                   SAFMIN
*     ..
*     .. External Subroutines ..
      EXTERNAL           daxpy, dpttrs, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. External Functions ..
      INTEGER            IDAMAX
      DOUBLE PRECISION   DLAMCH
      EXTERNAL           idamax, dlamch
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( nrhs.LT.0 ) THEN
         info = -2
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -8
      ELSE IF( ldx.LT.max( 1, n ) ) THEN
         info = -10
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DPTRFS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 ) THEN
         DO 10 j = 1, nrhs
            ferr( j ) = zero
            berr( j ) = zero
   10    CONTINUE
         RETURN
      END IF
*
*     NZ = maximum number of nonzero elements in each row of A, plus 1
*
      nz = 4
      eps = dlamch( 'Epsilon' )
      safmin = dlamch( 'Safe minimum' )
      safe1 = nz*safmin
      safe2 = safe1 / eps
*
*     Do for each right hand side
*
      DO 90 j = 1, nrhs
*
         count = 1
         lstres = three
   20    CONTINUE
*
*        Loop until stopping criterion is satisfied.
*
*        Compute residual R = B - A * X.  Also compute
*        abs(A)*abs(x) + abs(b) for use in the backward error bound.
*
         IF( n.EQ.1 ) THEN
            bi = b( 1, j )
            dx = d( 1 )*x( 1, j )
            work( n+1 ) = bi - dx
            work( 1 ) = abs( bi ) + abs( dx )
         ELSE
            bi = b( 1, j )
            dx = d( 1 )*x( 1, j )
            ex = e( 1 )*x( 2, j )
            work( n+1 ) = bi - dx - ex
            work( 1 ) = abs( bi ) + abs( dx ) + abs( ex )
            DO 30 i = 2, n - 1
               bi = b( i, j )
               cx = e( i-1 )*x( i-1, j )
               dx = d( i )*x( i, j )
               ex = e( i )*x( i+1, j )
               work( n+i ) = bi - cx - dx - ex
               work( i ) = abs( bi ) + abs( cx ) + abs( dx ) + abs( ex )
   30       CONTINUE
            bi = b( n, j )
            cx = e( n-1 )*x( n-1, j )
            dx = d( n )*x( n, j )
            work( n+n ) = bi - cx - dx
            work( n ) = abs( bi ) + abs( cx ) + abs( dx )
         END IF
*
*        Compute componentwise relative backward error from formula
*
*        max(i) ( abs(R(i)) / ( abs(A)*abs(X) + abs(B) )(i) )
*
*        where abs(Z) is the componentwise absolute value of the matrix
*        or vector Z.  If the i-th component of the denominator is less
*        than SAFE2, then SAFE1 is added to the i-th components of the
*        numerator and denominator before dividing.
*
         s = zero
         DO 40 i = 1, n
            IF( work( i ).GT.safe2 ) THEN
               s = max( s, abs( work( n+i ) ) / work( i ) )
            ELSE
               s = max( s, ( abs( work( n+i ) )+safe1 ) /
     $             ( work( i )+safe1 ) )
            END IF
   40    CONTINUE
         berr( j ) = s
*
*        Test stopping criterion. Continue iterating if
*           1) The residual BERR(J) is larger than machine epsilon, and
*           2) BERR(J) decreased by at least a factor of 2 during the
*              last iteration, and
*           3) At most ITMAX iterations tried.
*
         IF( berr( j ).GT.eps .AND. two*berr( j ).LE.lstres .AND.
     $       count.LE.itmax ) THEN
*
*           Update solution and try again.
*
            CALL dpttrs( n, 1, df, ef, work( n+1 ), n, info )
            CALL daxpy( n, one, work( n+1 ), 1, x( 1, j ), 1 )
            lstres = berr( j )
            count = count + 1
            GO TO 20
         END IF
*
*        Bound error from formula
*
*        norm(X - XTRUE) / norm(X) .le. FERR =
*        norm( abs(inv(A))*
*           ( abs(R) + NZ*EPS*( abs(A)*abs(X)+abs(B) ))) / norm(X)
*
*        where
*          norm(Z) is the magnitude of the largest component of Z
*          inv(A) is the inverse of A
*          abs(Z) is the componentwise absolute value of the matrix or
*             vector Z
*          NZ is the maximum number of nonzeros in any row of A, plus 1
*          EPS is machine epsilon
*
*        The i-th component of abs(R)+NZ*EPS*(abs(A)*abs(X)+abs(B))
*        is incremented by SAFE1 if the i-th component of
*        abs(A)*abs(X) + abs(B) is less than SAFE2.
*
         DO 50 i = 1, n
            IF( work( i ).GT.safe2 ) THEN
               work( i ) = abs( work( n+i ) ) + nz*eps*work( i )
            ELSE
               work( i ) = abs( work( n+i ) ) + nz*eps*work( i ) + safe1
            END IF
   50    CONTINUE
         ix = idamax( n, work, 1 )
         ferr( j ) = work( ix )
*
*        Estimate the norm of inv(A).
*
*        Solve M(A) * x = e, where M(A) = (m(i,j)) is given by
*
*           m(i,j) =  abs(A(i,j)), i = j,
*           m(i,j) = -abs(A(i,j)), i .ne. j,
*
*        and e = [ 1, 1, ..., 1 ]**T.  Note M(A) = M(L)*D*M(L)**T.
*
*        Solve M(L) * x = e.
*
         work( 1 ) = one
         DO 60 i = 2, n
            work( i ) = one + work( i-1 )*abs( ef( i-1 ) )
   60    CONTINUE
*
*        Solve D * M(L)**T * x = b.
*
         work( n ) = work( n ) / df( n )
         DO 70 i = n - 1, 1, -1
            work( i ) = work( i ) / df( i ) + work( i+1 )*abs( ef( i ) )
   70    CONTINUE
*
*        Compute norm(inv(A)) = max(x(i)), 1<=i<=n.
*
         ix = idamax( n, work, 1 )
         ferr( j ) = ferr( j )*abs( work( ix ) )
*
*        Normalize error.
*
         lstres = zero
         DO 80 i = 1, n
            lstres = max( lstres, abs( x( i, j ) ) )
   80    CONTINUE
         IF( lstres.NE.zero )
     $      ferr( j ) = ferr( j ) / lstres
*
   90 CONTINUE
*
      RETURN
*
*     End of DPTRFS
*

dpttrf()

subroutine dpttrf	(	integer	n,
		double precision, dimension( * )	d,
		double precision, dimension( * )	e,
		integer	info )

DPTTRF

Download DPTTRF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DPTTRF computes the L*D*L**T factorization of a real symmetric
!> positive definite tridiagonal matrix A.  The factorization may also
!> be regarded as having the form A = U**T*D*U.
!> 

Parameters

[in]	N	!> N is INTEGER !> The order of the matrix A. N >= 0. !>
[in,out]	D	!> D is DOUBLE PRECISION array, dimension (N) !> On entry, the n diagonal elements of the tridiagonal matrix !> A. On exit, the n diagonal elements of the diagonal matrix !> D from the L*D*L**T factorization of A. !>
[in,out]	E	!> E is DOUBLE PRECISION array, dimension (N-1) !> On entry, the (n-1) subdiagonal elements of the tridiagonal !> matrix A. On exit, the (n-1) subdiagonal elements of the !> unit bidiagonal factor L from the L*D*L**T factorization of A. !> E can also be regarded as the superdiagonal of the unit !> bidiagonal factor U from the U**T*D*U factorization of A. !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -k, the k-th argument had an illegal value !> > 0: if INFO = k, the leading minor of order k is not !> positive definite; if k < N, the factorization could not !> be completed, while if k = N, the factorization was !> completed, but D(N) <= 0. !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 90 of file dpttrf.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D( * ), E( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, I4
      DOUBLE PRECISION   EI
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          mod
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( n.LT.0 ) THEN
         info = -1
         CALL xerbla( 'DPTTRF', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Compute the L*D*L**T (or U**T*D*U) factorization of A.
*
      i4 = mod( n-1, 4 )
      DO 10 i = 1, i4
         IF( d( i ).LE.zero ) THEN
            info = i
            GO TO 30
         END IF
         ei = e( i )
         e( i ) = ei / d( i )
         d( i+1 ) = d( i+1 ) - e( i )*ei
   10 CONTINUE
*
      DO 20 i = i4 + 1, n - 4, 4
*
*        Drop out of the loop if d(i) <= 0: the matrix is not positive
*        definite.
*
         IF( d( i ).LE.zero ) THEN
            info = i
            GO TO 30
         END IF
*
*        Solve for e(i) and d(i+1).
*
         ei = e( i )
         e( i ) = ei / d( i )
         d( i+1 ) = d( i+1 ) - e( i )*ei
*
         IF( d( i+1 ).LE.zero ) THEN
            info = i + 1
            GO TO 30
         END IF
*
*        Solve for e(i+1) and d(i+2).
*
         ei = e( i+1 )
         e( i+1 ) = ei / d( i+1 )
         d( i+2 ) = d( i+2 ) - e( i+1 )*ei
*
         IF( d( i+2 ).LE.zero ) THEN
            info = i + 2
            GO TO 30
         END IF
*
*        Solve for e(i+2) and d(i+3).
*
         ei = e( i+2 )
         e( i+2 ) = ei / d( i+2 )
         d( i+3 ) = d( i+3 ) - e( i+2 )*ei
*
         IF( d( i+3 ).LE.zero ) THEN
            info = i + 3
            GO TO 30
         END IF
*
*        Solve for e(i+3) and d(i+4).
*
         ei = e( i+3 )
         e( i+3 ) = ei / d( i+3 )
         d( i+4 ) = d( i+4 ) - e( i+3 )*ei
   20 CONTINUE
*
*     Check d(n) for positive definiteness.
*
      IF( d( n ).LE.zero )
     $   info = n
*
   30 CONTINUE
      RETURN
*
*     End of DPTTRF
*

dpttrs()

subroutine dpttrs	(	integer	n,
		integer	nrhs,
		double precision, dimension( * )	d,
		double precision, dimension( * )	e,
		double precision, dimension( ldb, * )	b,
		integer	ldb,
		integer	info )

DPTTRS

Download DPTTRS + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DPTTRS solves a tridiagonal system of the form
!>    A * X = B
!> using the L*D*L**T factorization of A computed by DPTTRF.  D is a
!> diagonal matrix specified in the vector D, L is a unit bidiagonal
!> matrix whose subdiagonal is specified in the vector E, and X and B
!> are N by NRHS matrices.
!> 

Parameters

[in]	N	!> N is INTEGER !> The order of the tridiagonal matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrix B. NRHS >= 0. !>
[in]	D	!> D is DOUBLE PRECISION array, dimension (N) !> The n diagonal elements of the diagonal matrix D from the !> L*D*L**T factorization of A. !>
[in]	E	!> E is DOUBLE PRECISION array, dimension (N-1) !> The (n-1) subdiagonal elements of the unit bidiagonal factor !> L from the L*D*L**T factorization of A. E can also be regarded !> as the superdiagonal of the unit bidiagonal factor U from the !> factorization A = U**T*D*U. !>
[in,out]	B	!> B is DOUBLE PRECISION array, dimension (LDB,NRHS) !> On entry, the right hand side vectors B for the system of !> linear equations. !> On exit, the solution vectors, X. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>
[out]	INFO	!> INFO is INTEGER !> = 0: successful exit !> < 0: if INFO = -k, the k-th argument had an illegal value !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 108 of file dpttrs.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDB, N, NRHS
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   B( LDB, * ), D( * ), E( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            J, JB, NB
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      EXTERNAL           ilaenv
*     ..
*     .. External Subroutines ..
      EXTERNAL           dptts2, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments.
*
      info = 0
      IF( n.LT.0 ) THEN
         info = -1
      ELSE IF( nrhs.LT.0 ) THEN
         info = -2
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -6
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DPTTRS', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 )
     $   RETURN
*
*     Determine the number of right-hand sides to solve at a time.
*
      IF( nrhs.EQ.1 ) THEN
         nb = 1
      ELSE
         nb = max( 1, ilaenv( 1, 'DPTTRS', ' ', n, nrhs, -1, -1 ) )
      END IF
*
      IF( nb.GE.nrhs ) THEN
         CALL dptts2( n, nrhs, d, e, b, ldb )
      ELSE
         DO 10 j = 1, nrhs, nb
            jb = min( nrhs-j+1, nb )
            CALL dptts2( n, jb, d, e, b( 1, j ), ldb )
   10    CONTINUE
      END IF
*
      RETURN
*
*     End of DPTTRS
*

dptts2()

subroutine dptts2	(	integer	n,
		integer	nrhs,
		double precision, dimension( * )	d,
		double precision, dimension( * )	e,
		double precision, dimension( ldb, * )	b,
		integer	ldb )

DPTTS2 solves a tridiagonal system of the form AX=B using the L D LH factorization computed by spttrf.

Download DPTTS2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

!>
!> DPTTS2 solves a tridiagonal system of the form
!>    A * X = B
!> using the L*D*L**T factorization of A computed by DPTTRF.  D is a
!> diagonal matrix specified in the vector D, L is a unit bidiagonal
!> matrix whose subdiagonal is specified in the vector E, and X and B
!> are N by NRHS matrices.
!> 

Parameters

[in]	N	!> N is INTEGER !> The order of the tridiagonal matrix A. N >= 0. !>
[in]	NRHS	!> NRHS is INTEGER !> The number of right hand sides, i.e., the number of columns !> of the matrix B. NRHS >= 0. !>
[in]	D	!> D is DOUBLE PRECISION array, dimension (N) !> The n diagonal elements of the diagonal matrix D from the !> L*D*L**T factorization of A. !>
[in]	E	!> E is DOUBLE PRECISION array, dimension (N-1) !> The (n-1) subdiagonal elements of the unit bidiagonal factor !> L from the L*D*L**T factorization of A. E can also be regarded !> as the superdiagonal of the unit bidiagonal factor U from the !> factorization A = U**T*D*U. !>
[in,out]	B	!> B is DOUBLE PRECISION array, dimension (LDB,NRHS) !> On entry, the right hand side vectors B for the system of !> linear equations. !> On exit, the solution vectors, X. !>
[in]	LDB	!> LDB is INTEGER !> The leading dimension of the array B. LDB >= max(1,N). !>

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 101 of file dptts2.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDB, N, NRHS
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   B( LDB, * ), D( * ), E( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, J
*     ..
*     .. External Subroutines ..
      EXTERNAL           dscal
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.1 ) THEN
         IF( n.EQ.1 )
     $      CALL dscal( nrhs, 1.d0 / d( 1 ), b, ldb )
         RETURN
      END IF
*
*     Solve A * X = B using the factorization A = L*D*L**T,
*     overwriting each right hand side vector with its solution.
*
      DO 30 j = 1, nrhs
*
*           Solve L * x = b.
*
         DO 10 i = 2, n
            b( i, j ) = b( i, j ) - b( i-1, j )*e( i-1 )
   10    CONTINUE
*
*           Solve D * L**T * x = b.
*
         b( n, j ) = b( n, j ) / d( n )
         DO 20 i = n - 1, 1, -1
            b( i, j ) = b( i, j ) / d( i ) - b( i+1, j )*e( i )
   20    CONTINUE
   30 CONTINUE
*
      RETURN
*
*     End of DPTTS2
*