hm_get_floatv.F File Reference

#include "implicit_f.inc"

Go to the source code of this file.

Functions/Subroutines
subroutine	hm_get_floatv (name, rval, is_available, lsubmodel, unitab)

Function/Subroutine Documentation

hm_get_floatv()

subroutine hm_get_floatv	(	character*(*), intent(in)	name,
		intent(out)	rval,
		logical, intent(out)	is_available,
		type(submodel_data), dimension(nsubmod), intent(in)	lsubmodel,
		type (unit_type_), intent(in)	unitab )

Definition at line 417 of file hm_get_floatv.F.

C-----------------------------------------------
C   ROUTINE DESCRIPTION :
C   ===================
C   REQUEST DATA INTO MODEL NEUTRAL OBJECT DATABASE USING HM_READER
C   PICK VALUE
C   ASK (REAL) VALUE OF 'NAME' FIELD DEFINED IN .cfg FILE 
C   APPLY AUTOMATICALLY UNIT SYSTEM USING DIMENSION DEFINED IN .cfg FILE
C-----------------------------------------------
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME         DESCRIPTION              
C
C     NAME         FIELD NAME         
C     RVAL         REAL VALUE OF THE FIELD 
C     IS_AVAILABLE VALUE AVAILABLE IN MODEL OR NOT
C     LSUBMODEL    SUBMODEL STRUCTURE       
C     UNITAB       UNIT ARRAY       
C============================================================================
C   M o d u l e s
C-----------------------------------------------
      use, INTRINSIC :: iso_c_binding, only: c_bool
      USE message_mod       
      USE submodel_mod , ONLY : submodel_data, nsubmod
      USE unitab_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C----------------------------------------------- 
C INPUT ARGUMENTS
      TYPE (UNIT_TYPE_),INTENT(IN) :: UNITAB
      CHARACTER*(*),INTENT(IN) :: NAME
      TYPE(SUBMODEL_DATA),INTENT(IN) :: LSUBMODEL(NSUBMOD)
C OUTPUT ARGUMENTS
      my_real,INTENT(OUT) :: rval
      LOGICAL,INTENT(OUT) :: IS_AVAILABLE
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: J,SUB_ID,IFLAGUNIT,UID
      my_real :: fac_l,fac_m,fac_t,fac
      real*8 :: dval,length_dim,mass_dim,time_dim
      LOGICAL(KIND=C_BOOL) :: C_IS_AVAILABLE
C-----------------------------------------------
        c_is_available = .false.
        length_dim = zero
        mass_dim = zero
        time_dim = zero
        fac = one
C--------------------------------------------------
        CALL cpp_get_floatv_floatd(name(1:len_trim(name)),len_trim(name),dval,c_is_available,
     .                    length_dim,mass_dim,time_dim,uid,sub_id)
        is_available = c_is_available
C--------------------------------------------------
C      ID OFFSETS FOR //SUBMODEL 
C--------------------------------------------------
        IF(sub_id /= 0 .AND. uid == 0)THEN
          IF(lsubmodel(sub_id)%UID /= 0)THEN
            uid = lsubmodel(sub_id)%UID
          ENDIF
        ENDIF
C--------------------------------------------------
c      APPLY UNIT SYSTEM
C--------------------------------------------------
        iflagunit = 0 
        fac_m = zero
        fac_l = zero
        fac_t = zero         
        DO j=1,unitab%NUNITS                         
          IF (unitab%UNIT_ID(j) == uid) THEN    
            fac_m = unitab%FAC_M(j)
            fac_l = unitab%FAC_L(j)
            fac_t = unitab%FAC_T(j)
            iflagunit = 1                      
            EXIT                              
          ENDIF        
        ENDDO
        IF (fac_m  /= zero) fac = fac * (fac_m ** mass_dim  )
        IF (fac_l  /= zero) fac = fac * (fac_l ** length_dim)
        IF (fac_t  /= zero) fac = fac * (fac_t ** time_dim  )     
C-------------------------------------------------- 
        rval  = dval *  fac
c        print *,'real value=',NAME(1:LEN_TRIM(NAME)),RVAL,LENGTH_DIM,MASS_DIM,TIME_DIM
C--------------------------------------------------                             
      RETURN
C