hm_read_ale_link_vel.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_ale_link       ../starter/source/constraints/ale/hm_read_ale_link_vel.F
!||--- called by ------------------------------------------------------
!||    lectur                 ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    hm_get_floatv          ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_intv            ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_read_key     ../starter/source/devtools/hm_reader/hm_option_read_key.F
!||    hm_option_start        ../starter/source/devtools/hm_reader/hm_option_start.F
!||    ngr2usr                ../starter/source/system/nintrr.F
!||    usr2sys                ../starter/source/system/sysfus.F
!||--- uses       -----------------------------------------------------
!||    format_mod             ../starter/share/modules1/format_mod.F90
!||    hm_option_read_mod     ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod            ../starter/share/message_module/message_mod.f
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_ale_link(ICODE, ISKEW, ITAB, ITABM1, IKINE,
     .     IGRNOD, IBCSLAG, LAG_NCF, LAG_NKF, LAG_NHF,
     .     IKINE1LAG, LINALE, LSUBMODEL, UNITAB)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C This subroutine is reading /ALE/LINK/VEL options in user input file
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE groupdef_mod
      USE unitab_mod
      USE hm_option_read_mod
      USE submodel_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharkey, ncharfield
      USE format_mod , ONLY : lfield
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER,INTENT(IN) :: ICODE(NUMNOD), ISKEW(*), ITAB(NUMNOD), ITABM1(*), IKINE(*),IBCSLAG(5,*)
      INTEGER,INTENT(IN) :: LAG_NCF,LAG_NKF,LAG_NHF,IKINE1LAG(*)
      INTEGER,INTENT(INOUT) :: LINALE(*)
      TYPE(submodel_data), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      TYPE(unit_type_), INTENT(IN) :: UNITAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER GRID_DOF, BID, IFORM,  NODE_ID1, NODE_ID2,POS,IAD0,NNOD
      INTEGER I,JJ(12), IC, NC, N, NUSR, IS, IC1, IC2, IC3, IC4, 
     .        nosys, j,j10(10),igr,igrs,isu,ibcale,j3(3),k,
     .        ic0, ic01, ic02, ic03, ic04, id ,ilagm, nbcslag,
     .        flag_fmt,flag_fmt_tmp,ifix_tmp,ikine1(3*numnod),igrns
      CHARACTER(LEN=NCHARKEY) :: KEY,KEY2
      CHARACTER(LEN=NCHARFIELD) :: STRING, CHAR_XYZ
      CHARACTER(LEN=NCHARTITLE) :: TITR
      CHARACTER :: OPT*8,MESS*40
      my_real tstart,tstop
      LOGICAL :: IS_AVAILABLE
      INTEGER :: WX, WY, WZ
C-----------------------------------------------
      TYPE (GROUP_)  ,TARGET, DIMENSION(NGRNOD)  :: IGRNOD
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER USR2SYS,MY_OR,CHECK_NEW,NGR2USR
!
      INTEGER, DIMENSION(:), POINTER :: INGR2USR
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      pos=0
      igrns=0
      tstart=zero
      tstop=zero
      
      WRITE(iout,1000)
      CALL hm_option_start('/ALE/LINK/VEL')
 
      DO i = 1, nalelk
         CALL hm_option_read_key(lsubmodel, option_id = n, option_titr = titr)
         CALL hm_get_intv('node_ID1', node_id1, is_available, lsubmodel)
         CALL hm_get_intv('node_ID2', node_id2, is_available, lsubmodel)
         CALL hm_get_intv('grnod_ID', igr, is_available, lsubmodel)
         CALL hm_get_intv('Wx', wx, is_available, lsubmodel)
         CALL hm_get_intv('Wy', wy, is_available, lsubmodel)
         CALL hm_get_intv('Wz', wz, is_available, lsubmodel)
         CALL hm_get_intv('Iform', iform, is_available, lsubmodel)
         CALL hm_get_floatv('Tstart', tstart, is_available, lsubmodel, unitab)
         CALL hm_get_floatv('Tstop', tstop, is_available, lsubmodel, unitab)
         IF (tstop == zero) tstop = ep30
         ingr2usr => igrnod(1:ngrnod)%ID
         igrs=ngr2usr(igr,ingr2usr,ngrnod)
         IF(igrs==0)THEN
            WRITE(iout,*)  '  -- NODE GROUP',igr,' NOT FOUND'
            WRITE(istdo,*) '  -- NODE GROUP',igr,' NOT FOUND'              
         ENDIF               
         
         j3(1) = wx
         j3(2) = wy
         j3(3) = wz
         ic  = j3(1) * 4 + j3(2) * 2 + j3(3)            
         char_xyz = '          '           
         k=lfield
         IF(j3(3)==1 )THEN
            char_xyz(k:k)='Z'
            k=k-1
         ENDIF
         IF(j3(2)==1 )THEN
            char_xyz(k:k)='Y'
            k=k-1
         ENDIF
         IF(j3(1)==1 )THEN
            char_xyz(k:k)='X'
         ENDIF
!     
         igrns = igrnod(igrs)%SORTED
!     
         IF(iform==0.AND.igrns /= 1)THEN
            CALL ancmsg(msgid=271,anmode=aninfo,msgtype=msgerror,i1=n,i2=iform) 
         ELSE
            WRITE(iout,1100) n,trim(titr),node_id1,node_id2,igr,char_xyz,iform,tstart,tstop
         ENDIF
 
         linale(pos+1)=n
         linale(pos+2)=node_id1   
         linale(pos+3)=node_id2
         linale(pos+4)=-1                    
         linale(pos+5)=ic
         linale(pos+6)=iform 
         linale(pos+7)=igrs
 
         pos = pos+1+6 
         mess=''
         mess(1:10)='ALE  LINKS'
         bid=usr2sys(node_id1,itabm1,mess,n)
         bid=usr2sys(node_id2,itabm1,mess,n)
        ENDDO
C-----------------------------------------------
1000  FORMAT(/
     . '       ALE LINKS DEFINITIONS '/
     . '      ---------------------- '/)
C-----------------------------------------------     
1100  FORMAT( /5x,'ALE LINK ID ',i10,': ',a,
     .       /10x,'MAIN NODE 1 . . . . . . . . . . . . . ',i10
     .       /10x,'MAIN NODE 2 . . . . . . . . . . . . . ',i10
     .       /10x,'GROUP IDENTIFIER FOR SECONDARY NODES. . . . ',i10    
     .       /10x,'GRID VELOCITY DIRECTIONS TO LINK. . . . ',a
     .       /10x,'FORMULATION . . . . . . . . . . . . . . ',i10
     .       /10x,'START TIME. . . . . . . . . . . . . . . ',1pg20.13
     .       /10x,'STOP TIME . . . . . . . . . . . . . . . ',1pg20.13/)
C-----------------------------------------------
      RETURN
      END