hm_read_eos_gruneisen.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_eos_gruneisen    ../starter/source/materials/eos/hm_read_eos_gruneisen.f
!||--- called by ------------------------------------------------------
!||    hm_read_eos              ../starter/source/materials/eos/hm_read_eos.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||--- uses       -----------------------------------------------------
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_eos_gruneisen(IOUT,PM,UNITAB,IUNIT,LSUBMODEL,IMIDEOS)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE submodel_mod
      USE message_mod      
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C reading parameters for
C   MIE-GRUNEISEN EQUATION OF STATE
C-----------------------------------------------
C   C o m m e n t s
C-----------------------------------------------
C  RHOI = PM(89)   -> provided by /MAT
C  RHOR = PM(01)   -> provided by /MAT (can be erased by EOS if present : obsolete)
C  => MU0 = RHO/RHOR-1.
C  PM(31) = P(MU0,E0) -> will be used to initialize diagonal of stress tensor SIG(1:3,*)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IIN,IOUT,IUNIT
      my_real pm(npropm)
      TYPE(submodel_data), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      INTEGER,INTENT(IN) :: IMIDEOS
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real :: c, s1, s2, s3, gama0, a, e0, rho0,rhoi,rhor
      my_real :: mu,mu2,fac1,dpdmu,pp,bb,aa
      my_real :: mu0, df, ssp0, g0, fac, ff, fg, xx, dff, dfg
      my_real :: psh !< pressure shift
      my_real :: p0  !< initial pressure
      LOGICAL :: IS_ENCRYPTED, IS_AVAILABLE, IS_AVAILABLE_RHO0
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      is_available_rho0 = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('MAT_C', c, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('S1', s1, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('S2', s2, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('S3', s3, is_available,lsubmodel,unitab)
 
      CALL hm_get_floatv('GAMMA',gama0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_A', a, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('R0E0', e0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('P0', p0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('PSH', psh, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Refer_Rho', rho0 ,is_available_rho0,lsubmodel,unitab)
 
      IF(a == zero) a=gama0
 
 
      IF(p0 < zero)THEN
         CALL ancmsg(msgid=67,msgtype=msgerror,anmode=aninfo,i1=imideos,
     .               c1='/EOS/GRUNEISEN',
     .               c2='INITIAL PRESSURE MUST BE STRICTLY POSITIVE (TOTAL PRESSURE). USE PSH PARAMETER TO SHIFT THE PRESSURE')
      ENDIF
 
      IF(p0 > zero .AND. e0 /= zero)THEN
         CALL ancmsg(msgid=67,msgtype=msgerror,anmode=aninfo,i1=imideos,
     .               c1='/EOS/GRUNEISEN',
     .               c2='INITIAL PRESSURE PROVIDED. E0 IS CONSEQUENTLY REDEFINED SUCH AS P(RHO0,E0)=P0')
      ENDIF
 
      rhor = pm(1)
      rhoi = pm(89)
 
      IF(rho0 > zero) THEN
        rhor = rho0
        pm(1)= rho0 
      ELSE
        rho0=rhor                   
      ENDIF
 
      !COMPUTE INITIAL PRESSURE FOR PM(31)->SIG(1:3,*)
      !SSP0
      IF(rhoi == zero)THEN
        mu0 = zero ! error 683 already displayed
      ELSE
        IF(rhor /= zero)THEN
          mu0 = rhoi/rhor-one
        ELSE
          mu0 = zero ! error 683 already displayed
        ENDIF
      ENDIF
      ! Internal Energy (if P0 is provided, calculate E0 consequently)
      IF(p0 > zero)THEN
        if(gama0 /= zero)then
          e0 = (p0-rho0*c*c*mu0)/(gama0+a*mu0)
        endif
      ENDIF
      !Relative volume
      IF(rhoi /= zero)THEN
        df = rhor/rhoi
      ELSE
        df = zero
      ENDIF
      !pressure
      mu2=mu0*mu0
      ssp0 = zero 
      g0 = pm(22)
      rhoi = pm(89) 
      fac=one
      fac1=one
      IF(mu0>0)THEN
       xx= mu0/(one+mu0)
       ff=one+(one-half*gama0)*mu0-half*a*mu2
       fg=one-(s1-one+s2*xx+s3*xx*xx)*mu0
       fac=ff/(fg*fg)
       dff=one-half*gama0-a*mu0
       dfg=one-s1+xx*(-two*s2+xx*(s2-three*s3)+two*s3*xx*xx)
       fac1=fac*(one+mu0*(dff/ff-two*dfg/fg))
      ENDIF
      aa=fac*rhor*c*c*mu0
      bb=gama0+a*mu0
      pp=max(aa+bb*e0,pm(37))
      !derivatives and sound speed
      dpdmu=fac1*rhoi*c*c+pp*df*df*bb+a*e0
      dpdmu=max(zero,dpdmu)
      IF(rhor > zero) ssp0 = sqrt((dpdmu + two_third*g0)/rhor)
 
      ! Storage in Material Buffer PM
      pm(23)  = e0
      pm(32)  = pm(1)*c*c
      pm(33)  = c
      pm(34)  = s1
      pm(35)  = gama0
      pm(36)  = a
      pm(88)  = psh
      pm(160) = s2
      pm(161) = s3
      IF(pm(79)==zero)pm(79)=three100
      pm(27) = ssp0
      pm(31) = pp - psh
      pm(104) = pp - psh
      
      WRITE(iout,1000)
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1500)c,s1,s2,s3,gama0,a,e0,pp,psh,pp-psh
        IF(is_available_rho0)WRITE(iout,1501)pm(1)
      ENDIF
 
      RETURN
      
 1000 FORMAT(
     & 5x,'  MIE-GRUNEISEN EOS     ',/,
     & 5x,'  -----------------     ',/)
 1500 FORMAT(
     & 5x,'C . . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'S1. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'S2. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'S3. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'GAMA0 . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'A . . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'INITIAL INTERNAL ENERGY PER UNIT VOLUME .=',1pg20.13/,
     & 5x,'INITIAL PRESSURE . .  . . . . . . . . . .=',1pg20.13/,
     & 5x,'PRESSURE SHIFT . . .  . . . . . . . . . .=',1pg20.13/,
     & 5x,'INITIAL PRESSURE (SHIFTED)  . . . . . . .=',1pg20.13)
 1501 FORMAT(     
     & 5x,'EOS REFERENCE DENSITY . . . . . . . . . .=',1pg20.13)
 
      RETURN
      END SUBROUTINE hm_read_eos_gruneisen