hm_read_eos_linear.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_eos_linear       ../starter/source/materials/eos/hm_read_eos_linear.F
!||--- called by ------------------------------------------------------
!||    hm_read_eos              ../starter/source/materials/eos/hm_read_eos.F
!||--- calls      -----------------------------------------------------
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||--- uses       -----------------------------------------------------
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_eos_linear(IOUT,PM,UNITAB,IUNIT,LSUBMODEL,IMIDEOS,MAT_PARAM)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE submodel_mod
      USE message_mod
      USE matparam_def_mod, ONLY : matparam_struct_
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C reading parameters for
C   LINEAR EQUATION OF STATE
C-----------------------------------------------
C   C o m m e n t s
C-----------------------------------------------
C  RHOI = PM(89)   -> provided by /MAT
C  RHOR = PM(01)   -> provided by /MAT (can be erased by EOS if present : obsolete)
C  => MU0 = RHO/RHOR-1.
C  PM(31) = P(MU0,E0) -> will be used to initialize diagonal of stress tensor SIG(1:3,*)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IOUT, IUNIT
      my_real pm(npropm)
      TYPE(submodel_data), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      TYPE(matparam_struct_),INTENT(INOUT) :: MAT_PARAM
      INTEGER,INTENT(IN) :: IMIDEOS
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real c0, c1, psh, rho0,rhor,mu0, fac_l,fac_t,fac_m,fac_c,rhoi,g0,ssp0,dpdmu
      LOGICAL :: IS_ENCRYPTED, IS_AVAILABLE , IS_AVAILABLE_RHO0    
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      is_available_rho0 = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('LAW5_P0', c0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('mat_bulk', C1, IS_AVAILABLE,LSUBMODEL,UNITAB)
      CALL HM_GET_FLOATV('law5_psh', PSH, IS_AVAILABLE,LSUBMODEL,UNITAB)
      CALL HM_GET_FLOATV('refer_rho', RHO0, IS_AVAILABLE_RHO0,LSUBMODEL,UNITAB)
 
      RHOR = PM(1)
      RHOI = PM(89)
 
      IF(RHO0 > ZERO) THEN
        RHOR = RHO0
        PM(1)= RHO0 
        MAT_PARAM%RHO = RHO0
      ELSE
        RHO0=RHOR                   
      ENDIF
 
      PM(23) =ZERO
      PM(104)=C0-PSH
      PM(32) =C1
      PM(88) =PSH
 
      MAT_PARAM%EOS%NUPARAM = 2
      MAT_PARAM%EOS%NIPARAM = 0
      MAT_PARAM%EOS%NFUNC = 0
      MAT_PARAM%EOS%NTABLE = 0
      CALL MAT_PARAM%EOS%CONSTRUCT() !allocations
 
      MAT_PARAM%EOS%UPARAM(1) = C0-PSH
      MAT_PARAM%EOS%UPARAM(2) = C1
      MAT_PARAM%EOS%PSH = PSH
      MAT_PARAM%EOS%E0 = ZERO
      IF (MAT_PARAM%THERM%TINI == ZERO) THEN
        MAT_PARAM%THERM%TINI =THREE100
        PM(79) = THREE100
      END IF
 
      !initial pressure for stress tensor
      IF(RHOI == ZERO)THEN
        MU0 = ZERO ! error 683 already displayed
      ELSE
        IF(RHOR /= ZERO)THEN
          MU0 = RHOI/RHOR-ONE
        ELSE
          MU0 = ZERO ! error 683 already displayed
        ENDIF
      ENDIF
      
      PM(31)=C0-PSH+C1*MU0
      
      !SSP0
      SSP0 = ZERO 
      G0 = PM(22)
      RHOI = PM(89)
      DPDMU = C1
 
      DPDMU=MAX(ZERO,DPDMU)
      IF(RHOR > ZERO) SSP0 = SQRT((DPDMU + TWO_THIRD*G0)/RHOR) 
      PM(27)=SSP0
 
      WRITE(IOUT,1000)
      IF(IS_ENCRYPTED)THEN
        WRITE(IOUT,'(5x,a,//)')'confidential data'
      ELSE
        WRITE(IOUT,1500)C0,C1,PSH
        IF(IS_AVAILABLE_RHO0)WRITE(IOUT,1501)PM(1)
      ENDIF
 
      RETURN
 1000 FORMAT(
     & 5X,'  linear eos     ',/,
     & 5X,'  ----------     ',/)
 1500 FORMAT(
     & 5X,'initial pressure. . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'bulk modulus. . . . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'pressure shift. . . . . . . . . . . . . .=',1PG20.13)
 1501 FORMAT(     
     & 5X,'eos reference density . . . . . . . . . .=',1PG20.13) 
     
      RETURN
      END