hm_read_eos_noble_abel.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_eos_noble_abel   ../starter/source/materials/eos/hm_read_eos_noble_abel.F
!||--- called by ------------------------------------------------------
!||    hm_read_eos              ../starter/source/materials/eos/hm_read_eos.F
!||--- calls      -----------------------------------------------------
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.f
!||--- uses       -----------------------------------------------------
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_eos_noble_abel(IOUT,PM,UNITAB,IUNIT,LSUBMODEL,IMIDEOS)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE submodel_mod
      USE message_mod      
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C reading parameters for
C   NOBLE-ABEL EQUATION OF STATE
C-----------------------------------------------
C   C o m m e n t s
C-----------------------------------------------
C  RHOI = PM(89)   -> provided by /MAT
C  RHOR = PM(01)   -> provided by /MAT (can be erased by EOS if present : obsolete)
C  => MU0 = RHO/RHOR-1.
C  PM(31) = P(MU0,E0) -> will be used to initialize diagonal of stress tensor SIG(1:3,*)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IIN,IOUT,IUNIT
      my_real pm(npropm)
      TYPE(submodel_data), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      INTEGER,INTENT(IN) :: IMIDEOS
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real
     .   c0, c1, c2, c3, c4, c5, e0, psh, rho0,
     .   fac_l,fac_t,fac_m,fac_c,bb,gamma,aa,pp,denom,mu,rhoi,rhor,dpdmu,dpde
      my_real mu0,mu2,df,ssp0,g0
      LOGICAL :: IS_ENCRYPTED, IS_AVAILABLE, IS_AVAILABLE_RHO0
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      is_available_rho0 = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
      CALL hm_get_floatv('b_Covolume',bb, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Gamma_Constant', gamma, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('E0', e0, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('LAW5_PSH', psh ,is_available,lsubmodel,unitab)      
      CALL hm_get_floatv('Refer_Rho', rho0 ,is_available_rho0,lsubmodel,unitab)
 
      rhor = pm(1)
      rhoi = pm(89)
 
      IF(rho0 > zero) THEN
        rhor = rho0
        pm(1)= rho0 
      ELSE
        rho0=rhor                   
      ENDIF
 
      pm( 23) =  e0
      pm( 32) =  bb
      pm( 33) =  gamma-one     
      pm( 34) =  rho0         
      pm( 88) =  psh
      IF(pm(79)==zero)pm(79)=three100
 
      !COMPUTING INITIAL PRESSURE : PM(31) -> SIG(1:3,*)
      mu=rhoi/rhor-one
      denom   = one-bb*rhor*(one+mu)
      bb      = (gamma-one)*(one+mu)/denom
      pp      = bb*e0
      pm(31)  = pp - psh
      pm(104)  = pp - psh      
      
      !SSP0
      IF(rhoi == zero)THEN
        mu0 = zero ! error 683 already displayed
      ELSE
        IF(rhor /= zero)THEN
          mu0 = rhoi/rhor-one
        ELSE
          mu0 = zero ! error 683 already displayed
        ENDIF
      ENDIF
      
      IF(rhoi /= zero)THEN
        df = rhor/rhoi
      ELSE
        df = zero
      ENDIF
      
      mu2 = mu0*mu0
      pp = pm(31)+psh
      ssp0 = zero 
      g0 = pm(22)
      rhoi = pm(89)
      dpde = (gamma-one)*(one+mu0)/denom                                               
      dpdmu = (gamma-one)*e0/denom + pp/denom*bb*rhoi + pp*df*df*dpde
        
      dpdmu=max(zero,dpdmu)
      IF(rhor > zero) ssp0 = sqrt((dpdmu + two_third*g0)/rhor) 
      pm(27)=ssp0       
 
      WRITE(iout,1000)
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1500)bb,gamma,pm(31),e0,psh
        IF(is_available_rho0)WRITE(iout,1501)pm(1)
      ENDIF
 
      RETURN
 1000 FORMAT(
     & 5x,'  NOBLE-ABEL EOS     ',/,
     & 5x,'  --------------     ',/)
 1500 FORMAT(
     & 5x,'COVOLUME. . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'gamma gas constant. . . . . . . . . . . .=',1PG20.13/,
     & 5X,'initial pressure. . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'initial internal energy per unit volume .=',1PG20.13/,
     & 5X,'pressure shift. . . . . . . . . . . . . .=',1PG20.13)
 1501 FORMAT(     
     & 5X,'eos reference density . . . . . . . . . .=',1PG20.13)     
 
      RETURN
      END