hm_read_eos_tillotson.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_eos_tillotson    ../starter/source/materials/eos/hm_read_eos_tillotson.F
!||--- called by ------------------------------------------------------
!||    hm_read_eos              ../starter/source/materials/eos/hm_read_eos.f
!||--- calls      -----------------------------------------------------
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod             ../starter/share/modules1/elbuftag_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_eos_tillotson(IOUT,PM,UNITAB,IUNIT,LSUBMODEL,IMIDEOS,EOS_TAG,IEOS)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE submodel_mod
      USE message_mod      
      USE elbuftag_mod       
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C reading parameters for
C   TILLOTSON EQUATION OF STATE
C-----------------------------------------------
C   C o m m e n t s
C-----------------------------------------------
C  RHOI = PM(89)   -> provided by /MAT
C  RHOR = PM(01)   -> provided by /MAT (can be erased by EOS if present : obsolete)
C  => MU0 = RHO/RHOR-1.
C  PM(31) = P(MU0,E0) -> will be used to initialize diagonal of stress tensor SIG(1:3,*)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IIN,IOUT,IUNIT
      INTEGER,INTENT(IN) :: IEOS
      my_real pm(npropm)
      TYPE(submodel_data), DIMENSION(NSUBMOD), INTENT(IN) :: LSUBMODEL
      INTEGER,INTENT(IN) :: IMIDEOS
      TYPE(eos_tag_),DIMENSION(0:MAXEOS) ,INTENT(INOUT) :: EOS_TAG
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      my_real :: c1, c2, a, b, er, es, vs, e0, rho0,rhoi,rhor, alpha, beta,
     .           fac_l,fac_t,fac_m,fac_c,facc1,facc2,facpb,mu0,mu2,df,eta,
     .           omega,aa,bb,pp,xx,expa,expb,dpdmu, ssp0, g0
      LOGICAL :: IS_ENCRYPTED,IS_AVAILABLE,IS_AVAILABLE_RHO0
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      is_available_rho0 = .false.
 
      eos_tag(ieos)%NVAR = 1  !saving Region id for H2D and ANIM output                         
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('EOS_C1', c1, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('EOS_C2', c2, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_A', a, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_B', b, is_available,lsubmodel,unitab)
 
      CALL hm_get_floatv('E_R',er, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('E_S', es, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Vs', vs, is_available,lsubmodel,unitab)
      CALL hm_get_floatv('MAT_EA', e0 ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Refer_Rho', rho0 ,is_available_rho0,lsubmodel,unitab)
 
      CALL hm_get_floatv('Alpha', alpha ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('Beta', beta ,is_available,lsubmodel,unitab)
 
      rhor = pm(1)
      rhoi = pm(89)
 
      IF(rho0 > zero) THEN
        rhor = rho0
        pm(1)= rho0 
      ELSE
        rho0=rhor                   
      ENDIF
 
      pm(23)  = e0
      pm(32)  = c1
      pm(33)  = c2
      pm(34)  = a
      pm(35)  = b
      pm(36)  = er
      IF(pm(79)==zero)pm(79)=three100
      pm(160) = es
      pm(161) = vs
      pm(162) = alpha
      pm(163) = beta
 
      !COMPUTING INITIAL PRESSURE FOR PM(31) -> SIG(1:3,*)
      
      IF(rhoi == zero)THEN
        mu0 = zero ! error 683 already displayed
      ELSE
        IF(rhor /= zero)THEN
          mu0 = rhoi/rhor-one
        ELSE
          mu0 = zero ! error 683 already displayed
        ENDIF
      ENDIF
      
      IF(rhoi /= zero)THEN
        df = rhor/rhoi
      ELSE
        df = zero
      ENDIF
 
      mu2   = mu0*mu0
      facc1 = one
      facc2 = one
      facpb = one
      IF(mu0<zero) THEN
        facc2=zero
        IF(df>vs .OR. (df<=vs .AND. e0>=es) ) THEN
         xx    = mu0/(one+mu0)
         expa  = exp(-alpha*xx*xx)
         expb  = exp(beta*xx)
         facc1 = expa*expb
         facpb = expa
        ENDIF
      ENDIF      
      eta   = one+mu0       
      omega = one+e0/(er*eta**2)
      aa    = facc1*c1*mu0+facc2*c2*mu2
      bb    = a+facpb*b/omega
      pp    = max(aa+bb*eta*e0,pm(37))
      pm(31)= pp
        
      !SSP0
      ssp0 = zero 
      g0 = pm(22)
      rhoi = pm(89)
      
      dpdmu=facc1*c1+two*facc2*c2*mu0+bb*eta*pp*df*df
     .         +e0*( bb+(two*e0/eta-pp*df*df)
     .         *b*facpb/(er*eta*omega**2) )
      dpdmu=max(zero,dpdmu)
      IF(rhor > zero) ssp0 = sqrt((dpdmu + two_third*g0)/rhor) 
      pm(27)=ssp0      
 
      WRITE(iout,1000)
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1500)c1,c2,a,b,er,es,vs,e0,pm(31),alpha,beta
        IF(is_available_rho0)WRITE(iout,1501)pm(1)
      ENDIF
 
      RETURN
      
 1000 FORMAT(
     & 5x,'  TILLOTSON EOS     ',/,
     & 5x,'  --------------     ',/)
 1500 FORMAT(
     & 5x,'C1. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'C2. . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'A . . . . . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'b . . . . . . . . . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'ref internal energy (per unit volume) . .=',1PG20.13/,
     & 5X,'sublimation energy(per unit volume) . .=',1PG20.13/,
     & 5X,'sublimation relative volume . . . . . . .=',1PG20.13/,
     & 5X,'initial internal energy(per unit volume).=',1PG20.13/,
     & 5X,'initial pressure. . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'alpha . . . . . . . . . . . . . . . . . .=',1PG20.13/,
     & 5X,'beta. . . . . . . . . . . . . . . . . . .=',1PG20.13)
 1501 FORMAT(     
     & 5X,'eos reference density . . . . . . . . . .=',1PG20.13)     
 
      RETURN
      END