hm_read_fail_tsaihill.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_fail_tsaihill    ../starter/source/materials/fail/tsaihill/hm_read_fail_tsaihill.f
!||--- called by ------------------------------------------------------
!||    hm_read_fail             ../starter/source/materials/fail/hm_read_fail.F
!||--- calls      -----------------------------------------------------
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.f
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod             ../starter/share/modules1/elbuftag_mod.F
!||    hm_option_read_mod       ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.f
!||====================================================================
      SUBROUTINE hm_read_fail_tsaihill(FAIL   ,
     .           MAT_ID   ,FAIL_ID  ,IRUPT    ,LSUBMODEL,UNITAB   ,
     .           FAIL_TAG )
C-----------------------------------------------
c    ROUTINE DESCRIPTION :
c    Read Tsai-Hill failure model parameters
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE fail_param_mod
      USE unitab_mod
      USE message_mod 
      USE submodel_mod
      USE hm_option_read_mod 
      USE elbuftag_mod            
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER             ,INTENT(IN) :: FAIL_ID       !< failure model ID
      INTEGER             ,INTENT(IN) :: MAT_ID        !< material law ID
      INTEGER             ,INTENT(IN) :: IRUPT         !< failure model number
      TYPE (UNIT_TYPE_)   ,INTENT(IN) :: UNITAB        !< table of input units
      TYPE (SUBMODEL_DATA),INTENT(IN) :: LSUBMODEL(*)  !< submodel table 
      TYPE (FAIL_PARAM_)  ,INTENT(INOUT) :: FAIL       !< failure model data structure
      TYPE (FAIL_TAG_)    ,INTENT(INOUT) :: FAIL_TAG   !< failure model tag for buffer allocation
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: IFAIL_SH,IFAIL_SO,NUVAR
      my_real :: X11,X22,S12,TMAX,FCUT,PTHKF
      LOGICAL :: IS_AVAILABLE,IS_ENCRYPTED
C--------------------------------------------------
C   S o u r c e   L i n e s
C--------------------------------------------------
      is_encrypted = .false.
      is_available = .false.
      
      CALL hm_option_is_encrypted(is_encrypted)
 
      ! 1st line of the card
      CALL hm_get_floatv('X11'      ,x11      ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('X22'      ,x22      ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('S12'      ,s12      ,is_available,lsubmodel,unitab)
      CALL hm_get_intv  ('IFAIL_SH' ,ifail_sh ,is_available,lsubmodel)
      CALL hm_get_intv  ('IFAIL_SO' ,ifail_so ,is_available,lsubmodel)
 
      ! 2nd line of the card
      CALL hm_get_floatv('TAU_MAX'  ,tmax     ,is_available,lsubmodel,unitab)
      CALL hm_get_floatv('FCUT'     ,fcut     ,is_available,lsubmodel,unitab)
      
      ! Check parameters and set defaults value
      IF (x11 == zero)  x11  = infinity
      IF (x22 == zero)  x22  = infinity
      IF (s12 == zero)  s12  = infinity
      IF (tmax == zero) tmax = infinity
      ifail_sh = min(ifail_sh,2)
      ifail_sh = max(0,ifail_sh)
      ifail_so = min(ifail_so,2)
      ifail_so = max(0,ifail_so)
      fcut = max(zero,fcut)  
c
      ! Shell element deletion flag
      IF (ifail_sh == 1) THEN
        pthkf = em06
      ELSEIF (ifail_sh == 2) THEN 
        pthkf = one
      ENDIF
c---------------------------
      IF (fcut > zero) THEN 
        nuvar = 7
      ELSE
        nuvar = 1
      ENDIF
c---------------------------
      fail%KEYWORD = 'TSAI-HILL' 
      fail%IRUPT   = irupt 
      fail%FAIL_ID = fail_id 
      fail%NUPARAM = 7
      fail%NIPARAM = 0
      fail%NUVAR   = nuvar
      fail%NFUNC   = 0
      fail%NTABLE  = 0
      fail%NMOD    = 1
      fail%PTHK    = pthkf
c            
      ALLOCATE (fail%UPARAM(fail%NUPARAM))
      ALLOCATE (fail%IPARAM(fail%NIPARAM))
      ALLOCATE (fail%IFUNC (fail%NFUNC))
      ALLOCATE (fail%TABLE (fail%NTABLE))
c
      ! Modes of failure
      fail_tag%LF_DAMMX = fail_tag%LF_DAMMX + fail%NMOD
      ALLOCATE (fail%MODE(fail%NMOD))
      fail%MODE(1) = "Reserve factor"
c
      fail%NUPARAM   = 7
      fail%UPARAM(1) = x11
      fail%UPARAM(2) = x22
      fail%UPARAM(3) = s12
      fail%UPARAM(4) = tmax
      fail%UPARAM(5) = fcut  
      fail%UPARAM(6) = ifail_sh
      fail%UPARAM(7) = ifail_so
c---------------------------
C
      ! Print parameter in 0.out file
      IF (is_encrypted) THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1000)
        WRITE(iout,1100) x11,x22,s12
        IF (ifail_sh > 0 .OR. ifail_so > 0) THEN 
          WRITE(iout,1200) tmax
        ENDIF
        IF (fcut > zero) THEN 
          WRITE(iout,1300) fcut 
        ENDIF 
        WRITE(iout,1400) ifail_sh
        WRITE(iout,1500) ifail_so   
      ENDIF
c----------- 
 1000 FORMAT(
     & 5x,'  ----------------------------------------------------   ',/
     & 5x,'            FAILURE CRITERION : TSAI-HILL                ',/,
     & 5x,'  ----------------------------------------------------   ',/)
 1100 FORMAT(
     & 5x,'CRITICAL STRENGTH IN DIRECTION 1 X11  . . . . . . . . . =',1pg20.13/
     & 5x,'CRITICAL STRENGTH IN DIRECTION 2 X22  . . . . . . . . . =',1pg20.13/
     & 5x,'CRITICAL SHEAR STRENGTH S12 . . . . . . . . . . . . . . =',1pg20.13/)
 1200 FORMAT(
     & 5x,'STRESS SOFTENING ACTIVATED:                              ',/,
     & 5x,'RELAXATION TIME TAU_MAX . . . . . . . . . . . . . . . . =',1pg20.13/)
 1300 FORMAT(
     & 5x,'STRESS TENSOR FILTERING ACTIVATED:                       ',/,
     & 5x,'FILTERING FREQUENCY FCUT  . . . . . . . . . . . . . . . =',1pg20.13/)
 1400 FORMAT(
     & 5x,'SHELL DELETION FLAG IFAIL_SH  . . . . . . . . . . . . . =',i10,/
     & 5x,'    = 0: SHELL NEVER DELETED AND NO STRESS SOFTENING      ',/,
     & 5x,'    = 1: SHELL DELETED IF DAMAGE IS REACHED FOR ONE LAYER ',/,
     & 5x,'    = 2: SHELL DELETED IF DAMAGE IS REACHED FOR ALL LAYERS',/) 
 1500 FORMAT(
     & 5x,'SOLID DELETION FLAG IFAIL_SO  . . . . . . . . . . . . . =',i10,/
     & 5x,'    = 0: SOLID NEVER DELETED AND NO STRESS SOFTENING                  ',/,
     & 5x,'    = 1: SOLID DELETED IF DAMAGE IS REACHED FOR ONE INTEGRATION POINT ',/,
     & 5x,'    = 2: SOLID DELETED IF DAMAGE IS REACHED FOR ALL INTEGRATION POINTS',/)   
c----------- 
      RETURN
      END