hm_read_imptemp.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_imptemp        ../starter/source/constraints/thermic/hm_read_imptemp.F
!||--- called by ------------------------------------------------------
!||    lectur                 ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    hm_get_floatv          ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_floatv_dim      ../starter/source/devtools/hm_reader/hm_get_floatv_dim.F
!||    hm_get_intv            ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_read_key     ../starter/source/devtools/hm_reader/hm_option_read_key.F
!||    hm_option_start        ../starter/source/devtools/hm_reader/hm_option_start.F
!||    nodgrnr5               ../starter/source/starter/freform.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod     ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_imptemp(IBFT   ,FAC   ,NUM   ,ITABM1,
     .                     IGRNOD ,NWORK ,ITAB  ,UNITAB,LSUBMODEL,
     .                     NIMTEMP,NIFT,LFACTHER)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE message_mod
      USE groupdef_mod
      USE submodel_mod
      USE hm_option_read_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "units_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER NUM
      INTEGER ,INTENT(IN)  :: NIMTEMP
      INTEGER ,INTENT(IN)  :: NIFT
      INTEGER ,INTENT(IN)  :: LFACTHER
      INTEGER IBFT(NIFT,*), ITAB(*), ITABM1(*), NWORK(*)
      my_real :: fac(lfacther,*)
      TYPE(submodel_data),INTENT(IN)::LSUBMODEL(*)
      TYPE (GROUP_)  , DIMENSION(NGRNOD)  :: IGRNOD
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I, NOD, NCUR, SENS_ID, ID, UID
      INTEGER :: K, IGU, IGRS, NN, J, NUM0, IFLAGUNIT
      my_real :: fac1,fac2,facx,facy,fac2_dim,facx_dim,facy_dim
      CHARACTER MESS*40
      CHARACTER(LEN=NCHARTITLE) :: TITR
      LOGICAL IS_AVAILABLE
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER NODGRNR5
      DATA MESS/'IMPOSED TEMPERATURE DEFINITION  '/
C======================================================================|
      is_available = .false. 
      num = 0    
      i = 0
C--------------------------------------------------
C START BROWSING MODEL IMPTEMP
C--------------------------------------------------
      CALL hm_option_start('/IMPTEMP')
C--------------------------------------------------
C BROWSING /IMPTEMP OPTIONS 1->NIMTEMP 
C--------------------------------------------------
      DO k=1,nimtemp
        titr = ''
        CALL hm_option_read_key(lsubmodel,
     .                       unit_id = uid,
     .                       option_id = id,
     .                       option_titr = titr) 
        iflagunit = 0                                           
        DO j=1,unitab%NUNITS                           
          IF (unitab%UNIT_ID(j) == uid) THEN                     
            iflagunit = 1                       
            EXIT                                
          ENDIF                                 
        ENDDO                                  
        IF (uid /= 0.AND.iflagunit == 0) THEN
          CALL ancmsg(msgid=659,anmode=aninfo,msgtype=msgerror,
     .                i2=uid,i1=id,c1='IMPOSED TEMPERATURE',
     .                c2='IMPOSED TEMPERATURE',
     .                c3=titr)                              
        ENDIF 
C--------------------------------------------------
C EXTRACT DATAS (INTEGER VALUES)
C--------------------------------------------------
        CALL hm_get_intv('curveid',ncur,is_available,lsubmodel)
        CALL hm_get_intv('rad_sensor_id',sens_id,is_available,lsubmodel)
        CALL hm_get_intv('entityid',igu,is_available,lsubmodel)    
C--------------------------------------------------
C EXTRACT DATAS (REAL VALUES)
C--------------------------------------------------
        CALL hm_get_floatv('xscale',facx,is_available,lsubmodel,unitab)
        CALL hm_get_floatv_dim('xscale',facx_dim,is_available,lsubmodel,unitab)
        CALL hm_get_floatv('magnitude',facy,is_available,lsubmodel,unitab)
        CALL hm_get_floatv_dim('magnitude',facy_dim,is_available,lsubmodel,unitab)
        CALL hm_get_floatv('rad_tstart',fac1,is_available,lsubmodel,unitab)
        CALL hm_get_floatv('rad_tstop',fac2,is_available,lsubmodel,unitab)
        CALL hm_get_floatv_dim('rad_tstop',fac2_dim,is_available,lsubmodel,unitab)
C--------------------------------------------------
        IF (facy == zero) facy=facy_dim
        IF (facx == zero) facx=facx_dim
        IF (fac2 == zero) fac2=ep30 * fac2_dim
        facx = one / facx
C--------------------------------------------------
        num0 = num
        nn = nodgrnr5(igu    ,igrs   ,nwork(1+nift*num0),igrnod ,
     .                itabm1 ,mess   )
        num = num + nn
C
        DO j=nn,1,-1
C       !!  IBFV AND NWORK HAVE THE SAME ADDRESS
C       !!  IBFV ECRASE PROGRESSIVEMENT NWORK
C            IBFV(1,I+J)=NWORK(J+5*NUM0)
            nwork(1+nift*(i+j-1))=nwork(j+nift*num0)
        ENDDO
C        
        IF(nn > 0 )WRITE(iout, 2001)
        DO j=1,nn
            i=i+1
            nod = itab(iabs(ibft(1,i)))
            ibft(2,i)= ncur
            ibft(3,i)= sens_id
            ibft(4,i) = 0
C            
            fac(1,i)= fac1
            fac(2,i)= fac2
            fac(3,i)= facx
            fac(4,i)= facy
C
            WRITE (iout,'(3X,I10,3X,I10,3X,I10,2X,
     .       1PG20.13,2X,1PG20.13,2X,G20.13,2X,G20.13)')
     .       itab(iabs(ibft(1,i))),
     .       ibft(2,i),sens_id,fac(4,i),1/facx,fac(1,i),fac(2,i)
C
        ENDDO
      ENDDO  
C
      RETURN
C          
 2001 FORMAT(//
     .'     IMPOSED TEMPERATURE   '/
     .'     -------------------   '/
     . 9x,'NODE   LOAD_CURVE       SENSOR            FSCALE       ',
     . 9x,'ASCALE                START_TIME             STOP_TIME ')
      END