hm_read_inter_lagmul_type07.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_inter_lagmul_type07   ../starter/source/interfaces/int07/hm_read_inter_lagmul_type07.f
!||--- called by ------------------------------------------------------
!||    hm_read_inter_lagmul          ../starter/source/interfaces/reader/hm_read_inter_lagmul.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                        ../starter/source/output/message/message.F
!||    hm_get_floatv                 ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_intv                   ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    ngr2usr                       ../starter/source/system/nintrr.F
!||--- uses       -----------------------------------------------------
!||    message_mod                   ../starter/share/message_module/message_mod.f
!||    submodel_mod                  ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_inter_lagmul_type07(
     1        IPARI      ,STFAC      ,FRIGAP     ,NOINT     ,
     2        IGRNOD     ,IGRSURF    ,TITR       ,UNITAB     ,LSUBMODEL  )
C============================================================================
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE groupdef_mod
      USE submodel_mod
      USE unitab_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "scr06_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ISU1,ISU2,NOINT,NI
      INTEGER IPARI(*)
      my_real
     .   frigap(*), stfac
      CHARACTER(LEN=NCHARTITLE)::TITR
C-----------------------------------------------
      TYPE (GROUP_)  ,TARGET, DIMENSION(NGRNOD)  :: IGRNOD
      TYPE (SURF_)   ,TARGET , DIMENSION(NSURF)   :: IGRSURF
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      TYPE(submodel_data) LSUBMODEL(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,L, NTYP,MULTIMP,FLAGREMNOD,
     .    IREM7I2,IS1,IS2
      my_real
     .   startt,bumult,stopt,gapmax,gap
      CHARACTER MESS*40
!
      INTEGER, DIMENSION(:), POINTER :: INGR2USR
      LOGICAL IS_AVAILABLE
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER NGR2USR
C=======================================================================
C    /INTER/LAGMUL/TYPE2 reading 
C=======================================================================
      is1=0
      is2=0
      multimp = 0
      irem7i2=0
C
      ntyp = 7 
      ipari(15)=noint
      ipari(7)=ntyp
C
      is_available = .false.
C------------------------------------------------------------
C  Card1
C------------------------------------------------------------
      CALL hm_get_intv('secondaryentityids',isu1,is_available,lsubmodel)
      CALL hm_get_intv('mainentityids',isu2,is_available,lsubmodel)
C
       IF(isu2==0) THEN
          CALL ancmsg(msgid=119,
     .                msgtype=msgerror,
     .                anmode=aninfo,
     .                i1=noint,
     .                c1=titr)
       ENDIF
C
       is2=1
       ingr2usr => igrsurf(1:nsurf)%ID
       isu2=ngr2usr(isu2,ingr2usr,nsurf)
       IF(isu1/=0)THEN
          ingr2usr => igrnod(1:ngrnod)%ID
          isu1=ngr2usr(isu1,ingr2usr,ngrnod)
          is1 =2
       ENDIF
       IF(isu1==0)THEN
         isu1=isu2
         is1 =1
       ENDIF
C------------------------------------------------------------
       IF(frigap(16)==zero)THEN
           gapmax=ep30
           frigap(16)=gapmax
       END IF
C------------------------------------------------------------
       flagremnod = 0
       IF (flagremnod == 0) flagremnod = 1
       ipari(63) = flagremnod
C
       IF (irem7i2==0) THEN
          IF (iimplicit>0) irem7i2=1
       END IF
       ipari(54) = irem7i2
C------------------------------------------------------------
C  Card4
C------------------------------------------------------------
        CALL hm_get_floatv('Gapmin',gap,is_available,lsubmodel,unitab)
        frigap(2)=gap
C
C       STARTT & STOPT are actually working but not documented
C       IF (STOPT == ZERO) STOPT = EP30
C
        startt = zero
        stopt = ep30
        frigap(3)=startt
        frigap(11)=stopt
C
        IF(stfac==zero) THEN
           stfac=one
        ENDIF 
C
C------------------------------------------------------------
C  Card5
C------------------------------------------------------------
        CALL hm_get_floatv('BUMULT',bumult,is_available,lsubmodel,unitab)
 
        IF(bumult==zero) THEN
          bumult = bmul0
C bmult augmente pour les tres gros modeles et interface 7 ou 20
           IF(ntyp==7)THEN
             IF(numnod > 2500000) THEN
               bumult = bmul0*two
             ELSEIF(numnod > 1500000) THEN
               bumult = bmul0*three/two
             END IF
           END IF
        END IF
        frigap(4)=bumult
 
C FRIGAP(10) is initialized but used only in engine for storing number of couples candidates  
        frigap(10)=float(0)
        multimp = 4
        ipari(23)=multimp
 
        ipari(13)=is1*10+is2
 
        ipari(15)=noint
 
        ipari(45)=isu1
        ipari(46)=isu2
C
C------------------------------------------------------------
C     PRINTOUT
C------------------------------------------------------------
C
      WRITE(iout,1527)       
C
      IF(is1==0)THEN
        WRITE(iout,'(6X,A)')'NO SECONDARY SURFACE INPUT'
      ELSEIF(is1==1)THEN
        WRITE(iout,'(6X,A)')'SECONDARY SURFACE INPUT BY SEGMENTS'
      ELSEIF(is1==2)THEN
        WRITE(iout,'(6X,A)')'SECONDARY SURFACE INPUT BY NODES'
      ELSEIF(is1==3)THEN
        WRITE(iout,'(6X,A)')'SECONDARY SURFACE INPUT BY SEGMENTS'
      ELSEIF(is1==4 )THEN
        WRITE(iout,'(6X,A)')'SECONDARY SIDE INPUT BY BRICKS'
      ELSEIF(is1==5 )THEN
        WRITE(iout,'(6X,A)')'SECONDARY SIDE INPUT BY SOLID ELEMENTS'        
      ENDIF
      IF(is2==0)THEN
        WRITE(iout,'(6X,A)')'NO MAIN SURFACE INPUT'
      ELSEIF(is2==1)THEN
        WRITE(iout,'(6X,A)')'MAIN SURFACE INPUT BY SEGMENTS'
      ELSEIF(is2==2)THEN
        WRITE(iout,'(6X,A)')'MAIN SURFACE INPUT BY NODES'
      ELSEIF(is2==3)THEN
        WRITE(iout,'(6X,A)')'MAIN SURFACE INPUT BY SEGMENTS'
      ELSEIF(is2==4)THEN
        WRITE(iout,'(6X,A)')'MAIN SURFACE REFERS ',
     .                      'TO HYPER-ELLIPSOIDAL SURFACE'
      ENDIF
C  
C--------------------------------------------------------------
      RETURN
 1527 FORMAT(//
     .    '    TYPE==7   PARALLEL/AUTO IMPACTING           ' /,
     .    '    LAGRANGE MULTIPLIER FORMULATION               ' //)  
      END