hm_read_mat32.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_mat32            ../starter/source/materials/mat/mat032/hm_read_mat32.F
!||--- called by ------------------------------------------------------
!||    hm_read_mat              ../starter/source/materials/mat/hm_read_mat.F90
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||    init_mat_keyword         ../starter/source/materials/mat/init_mat_keyword.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod             ../starter/share/modules1/elbuftag_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_mat32(UPARAM ,MAXUPARAM,NUPARAM  ,ISRATE   , IMATVIS  ,
     .                         NUVAR  ,IFUNC    ,MAXFUNC  ,NFUNC    , PARMAT   , 
     .                         UNITAB ,MAT_ID   ,TITR     ,MTAG     , LSUBMODEL,
     .                         PM     ,IPM      ,MATPARAM )
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C   READ MAT LAW32 WITH HM READER ( TO BE COMPLETED )
C
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME            DESCRIPTION                         
C
C     IPM             MATERIAL ARRAY(INTEGER)
C     PM              MATERIAL ARRAY(REAL)
C     UNITAB          UNITS ARRAY
C     MAT_ID          MATERIAL ID(INTEGER)
C     TITR            MATERIAL TITLE
C     LSUBMODEL       SUBMODEL STRUCTURE   
C
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE elbuftag_mod            
      USE message_mod      
      USE submodel_mod
      USE matparam_def_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER,INTENT(INOUT)                         :: IPM(NPROPMI)
      my_real, DIMENSION(NPROPM) ,INTENT(INOUT)     :: PM     
      my_real, DIMENSION(100)    ,INTENT(INOUT)     :: parmat
      my_real, DIMENSION(MAXUPARAM) ,INTENT(INOUT)  :: uparam
      INTEGER, DIMENSION(MAXFUNC)   ,INTENT(INOUT)  :: IFUNC
      INTEGER, INTENT(INOUT)          :: ISRATE,IMATVIS,NFUNC,MAXFUNC,MAXUPARAM,NUPARAM,NUVAR
      TYPE(mlaw_tag_),INTENT(INOUT)   :: MTAG
      INTEGER,INTENT(IN)              :: MAT_ID
      CHARACTER(LEN=NCHARTITLE) ,INTENT(IN) :: TITR
      TYPE(submodel_data),INTENT(IN)  :: LSUBMODEL(*)
      TYPE(matparam_struct_) ,INTENT(INOUT) :: MATPARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER ICC,IR0
 
      my_real
     .   young, anu, ca, ce, cn, epsm, sigm, cm, eps0, g, e0, c0, c1,
     .   e1mn2, en1n2, sdsp, epst1, epsm1, epst2, epsm2, dmax1, dmax2,
     .   amu, r00, r45, r90, r, h, a11, a22, a1122, a12, rho0, rhor
      
      LOGICAL :: IS_ENCRYPTED,IS_AVAILABLE
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      nfunc=0
      nuvar=0
      is_encrypted = .false.
      is_available = .false.
      israte=0
      imatvis=1
 
      CALL hm_option_is_encrypted(is_encrypted)
      !line-1
      CALL hm_get_floatv('MAT_RHO'      ,rho0     ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('Refer_Rho'    ,rhor     ,is_available, lsubmodel, unitab)
      !line-2
      CALL hm_get_floatv('MAT_E'        ,young    ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_NU'       ,anu      ,is_available, lsubmodel, unitab)
      !line-3
      CALL hm_get_floatv('MAT_SIGY'     ,ca       ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_BETA'     ,ce       ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_HARD'     ,cn       ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_EPS'      ,epsm     ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_SIG'      ,sigm     ,is_available, lsubmodel, unitab)
      !line-4
      CALL hm_get_floatv('MAT_SRP'      ,eps0     ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_SRC'      ,cm       ,is_available, lsubmodel, unitab)
      !line-5
      CALL hm_get_floatv('MAT_R00'      ,r00      ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_R45'      ,r45      ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_R90'      ,r90      ,is_available, lsubmodel, unitab)
      CALL hm_get_intv  ('MAT_Iyield'   ,ir0      ,is_available, lsubmodel)
 
      IF(rhor==zero)rhor=rho0
      pm(01)=rhor
      pm(89)=rho0
 
      IF(anu==half)anu=zep499
      IF(r00==zero) r00   = one
      IF(r45==zero) r45   = one
      IF(r90==zero) r90   = one
      IF(ca==zero)  ca    = infinity
      IF(cn==zero)  cn    = one
      IF(epsm==zero) epsm  = infinity
      IF(sigm==zero) sigm  = infinity
      IF(cm==zero)  eps0  = one
C
      g=young/(two*(one + anu))
      e0=zero
      c0=zero
      c1=young/(three*(one  - two*anu))
      e1mn2=young/(one-anu**2)      
      en1n2=anu*e1mn2
      sdsp =sqrt(young/max(pm(1),em20))
      amu=pm(17)
      r = fourth * (r00 + two*r45 + r90)
      h = r / (one + r)
      a11   = h * (one + one/r00)
      a22   = h * (one + one/r90)
      a1122 = h * two
      a12   = h * two * (r45 + half) * (one/r00 + one/r90)
      IF (ir0 > 0) THEN
       a22=a22/a11
       a1122=a1122/a11
       a12=a12/a11
       a11=one
      END IF
      icc = 0
C
      pm(20)=young
      pm(21)=anu
      pm(22)=g
      pm(23)=e0
      pm(24)=e1mn2
      pm(25)=en1n2
      pm(26)=five_over_6
      pm(27)=sdsp
      pm(28)=one/young
      pm(29)=-anu*pm(28)
      pm(30)=one/g
      pm(31)=c0
      pm(32)=c1
      pm(38)=ca
      pm(39)=ce
      pm(40)=cn
      pm(41)=epsm
      pm(42)=sigm
      pm(43)=cm
      pm(44)=eps0
      pm(45)=a11
      pm(46)=a22
      pm(47)=a1122
      pm(48)=a12
      pm(49)=icc
      pm(52)=onep414*amu*pm(1)*sdsp
CCC-----------
C     Formulation for solid elements time step computation.
      ipm(252)= 2
      pm(105) = (one -two*anu)/(one - anu)
      
      mtag%G_SEQ = 1
C      
      WRITE(iout,1001) trim(titr),mat_id,32
      WRITE(iout,1000)
 
      IF(is_encrypted)THEN
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE
        WRITE(iout,1002)rho0
        WRITE(iout,1300)young,anu,g
        WRITE(iout,1400)ca,ce,cn,epsm,sigm
        WRITE(iout,1600)eps0,cm
        WRITE(iout,1700)r00,r45,r90
        IF (ir0 >0) WRITE(iout,1110)
      ENDIF
C.....ERRORS
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7--
      IF(cn>1.) THEN
         CALL ancmsg(msgid=213,
     .               msgtype=msgerror,
     .               anmode=aninfo)
      ENDIF
      IF(eps0<=zero) THEN
         CALL ancmsg(msgid=207,
     .               msgtype=msgerror,
     .               anmode=aninfo,
     .               i1=32,
     .               i2=mat_id,
     .               c1=titr)
      ENDIF
C
C---- Definition des variables internes (stockage elementaire)
c
      mtag%G_PLA   = 1
      mtag%G_EPSD  = 1
c
      mtag%LY_DIRA = 2
c
      mtag%L_PLA   = 1
      mtag%L_EPSD  = 1
c
      mtag%G_SEQ   = 1
      mtag%L_SEQ   = 1
c
      ! MATPARAM keywords
      CALL init_mat_keyword(matparam,"ELASTO_PLASTIC")
      CALL init_mat_keyword(matparam,"ORTHOTROPIC")
c
      ! Properties compatibility
      CALL init_mat_keyword(matparam,"SHELL_ORTHOTROPIC")
c          
c-------------------
      RETURN
c-------------------
 1000 FORMAT(
     & 5x,'  HILL ANISOTROPIC PLASTICITY            '/,
     & 5x,'  ---------------------------            '//)
 1001 FORMAT(
     & 5x,a,/,
     & 5x,'MATERIAL NUMBER . . . . . . . . . . . .=',i10/,
     & 5x,'MATERIAL LAW. . . . . . . . . . . . . .=',i10/)
 1002 FORMAT(
     & 5x,'INITIAL DENSITY . . . . . . . . . . . .=',1pg20.13/)
 1300 FORMAT(
     & 5x,'YOUNG   MODULUS . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'POISSON RATIO . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'SHEAR MODULUS . . . . . . . . . . . . .=',1pg20.13//)
 1400 FORMAT(
     & 5x,'YIELD COEFFICIENT A . . . . . . . . . .=',1pg20.13/,
     & 5x,'YIELD COEFFICIENT CE. . . . . . . . . .=',1pg20.13/,
     & 5x,'YIELD COEFFICIENT CN. . . . . . . . . .=',1pg20.13/,
     & 5x,'EPS-MAX . . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'SIG-MAX . . . . . . . . . . . . . . . .=',1pg20.13//)
 1600 FORMAT(
     & 5x,'REFERENCE STRAIN RATE . . . . . . . . .=',1pg20.13/,
     & 5x,'STRAIN RATE COEFFICIENT CM. . . . . . .=',1pg20.13//)
 1700 FORMAT(
     & 5x,'LANKFORD COEFFICIENT R00. . . . . . . .=',1pg20.13/,
     & 5x,'LANKFORD COEFFICIENT R45. . . . . . . .=',1pg20.13/,
     & 5x,'LANKFORD COEFFICIENT R90. . . . . . . .=',1pg20.13/)
 1110 FORMAT(
     & 5x,'YIELD STRESS IN ORTHOTROPIC DIR. 1 IS SUPPOSSD '/)
c-----------
      RETURN
      END