hm_read_mat59.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_mat59                  ../starter/source/materials/mat/mat059/hm_read_mat59.F
!||--- called by ------------------------------------------------------
!||    hm_read_mat                    ../starter/source/materials/mat/hm_read_mat.F90
!||--- calls      -----------------------------------------------------
!||    ancmsg                         ../starter/source/output/message/message.F
!||    hm_get_float_array_index       ../starter/source/devtools/hm_reader/hm_get_float_array_index.F
!||    hm_get_float_array_index_dim   ../starter/source/devtools/hm_reader/hm_get_float_array_index_dim.F
!||    hm_get_floatv                  ../starter/source/devtools/hm_reader/hm_get_floatv.f
!||    hm_get_floatv_dim              ../starter/source/devtools/hm_reader/hm_get_floatv_dim.F
!||    hm_get_int_array_index         ../starter/source/devtools/hm_reader/hm_get_int_array_index.F
!||    hm_get_intv                    ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted         ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||    init_mat_keyword               ../starter/source/materials/mat/init_mat_keyword.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod                   ../starter/share/modules1/elbuftag_mod.F
!||    message_mod                    ../starter/share/message_module/message_mod.F
!||    submodel_mod                   ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_mat59(UPARAM ,MAXUPARAM,NUPARAM  ,ISRATE   , IMATVIS  ,
     .                         NUVAR  ,IFUNC    ,MAXFUNC  ,NFUNC    , PARMAT   , 
     .                         UNITAB ,ID       ,TITR     ,MTAG     , LSUBMODEL,
     .                         PM     ,MATPARAM )
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C   READ MAT LAW151 WITH HM READER ( TO BE COMPLETED )
C
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME            DESCRIPTION                         
C
C     IPM             MATERIAL ARRAY(INTEGER)
C     PM              MATERIAL ARRAY(REAL)
C     UNITAB          UNITS ARRAY
C     ID              MATERIAL ID(INTEGER)
C     TITR            MATERIAL TITLE
C     LSUBMODEL       SUBMODEL STRUCTURE   
C
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE elbuftag_mod            
      USE message_mod      
      USE submodel_mod
      USE matparam_def_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      my_real, DIMENSION(NPROPM) ,INTENT(INOUT)   :: PM     
      my_real, DIMENSION(100)    ,INTENT(INOUT)     :: PARMAT
      my_real, DIMENSION(MAXUPARAM) ,INTENT(INOUT)  :: uparam
      INTEGER, DIMENSION(MAXFUNC)   ,INTENT(INOUT)  :: IFUNC
      INTEGER, INTENT(INOUT)          :: ISRATE,IMATVIS,NFUNC,MAXFUNC,MAXUPARAM,NUPARAM,NUVAR
      TYPE(mlaw_tag_),INTENT(INOUT)   :: MTAG
      INTEGER,INTENT(IN)              :: ID
      CHARACTER(LEN=NCHARTITLE) ,INTENT(IN) :: TITR
      TYPE(submodel_data),INTENT(IN)  :: LSUBMODEL(NSUBMOD)
      TYPE(matparam_struct_) ,INTENT(INOUT) :: MATPARAM
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: NBMAT  ! Number of declared materials
      INTEGER :: I,J
      INTEGER :: RHOFLAG,ICOMP,NRATE,IFILTR,IFUNN(MAXFUNC),IFUNT(MAXFUNC)
      my_real :: rho0, rhor,e,g,ecomp,fcut,rate0,yfac(maxfunc)
      my_real :: rate(maxfunc),nu,fcut_unit,yfac_unit(maxfunc),rate_unit(maxfunc)
      LOGICAL :: IS_AVAILABLE,IS_ENCRYPTED
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      is_encrypted = .false.
      is_available = .false.
 
      CALL hm_option_is_encrypted(is_encrypted)
 
      CALL hm_get_floatv('MAT_RHO'  ,rho0     ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('Refer_Rho',rhor     ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_E'    ,e        ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv('MAT_G0'   ,g        ,is_available, lsubmodel, unitab)
      CALL hm_get_intv  ('MAT_IMASS',rhoflag  ,is_available, lsubmodel) 
      CALL hm_get_intv  ('COMP_OPT' ,icomp    ,is_available, lsubmodel) 
      CALL hm_get_floatv('Ecomp'    ,ecomp    ,is_available, lsubmodel, unitab) 
      CALL hm_get_intv  ('NFUNC'    ,nrate    ,is_available, lsubmodel) 
      CALL hm_get_intv  ('Fsmooth'  ,ifiltr   ,is_available, lsubmodel) 
      CALL hm_get_floatv('Fcut'     ,fcut     ,is_available, lsubmodel, unitab)
      CALL hm_get_floatv_dim('Fcut' ,fcut_unit,is_available, lsubmodel, unitab)
      
      DO i=1,nrate 
        CALL hm_get_int_array_index  ('ABG_IPt'  ,ifunn(i)      ,i ,is_available, lsubmodel)
        CALL hm_get_int_array_index  ('ABG_IPdel',ifunt(i)      ,i ,is_available, lsubmodel)        
        CALL hm_get_float_array_index('Fp1'      ,rate(i)       ,i ,is_available, lsubmodel, unitab)   
        CALL hm_get_float_array_index_dim('Fp1'  ,rate_unit(i)  ,i ,is_available, lsubmodel, unitab)    
        CALL hm_get_float_array_index('Fp2'      ,yfac(i)       ,i ,is_available, lsubmodel, unitab)    
        CALL hm_get_float_array_index_dim('Fp2'  ,yfac_unit(i)  ,i ,is_available, lsubmodel, unitab)      
      ENDDO                                                                              
 
      IF (icomp /= 1 .OR. ecomp <= 0) THEN
        ecomp = e
      ENDIF      
      IF (icomp /= 1) icomp = 0
      
      IF (fcut == zero) fcut = one * fcut_unit
      
      nfunc = nrate*2          
      DO i=1,nrate             
        j = (i-1)*2            
        ifunc(j+1) = ifunn(i)  
        ifunc(j+2) = ifunt(i)  
      ENDDO                    
C---
      DO i=1,nfunc
        IF (ifunc(i) == 0) THEN
           CALL ancmsg(msgid=126,
     .                 msgtype=msgerror,
     .                 anmode=aninfo_blind_1,
     .                 i1=id,
     .                 c1=titr,
     .                 i2=ifunc(i))
        ENDIF
      ENDDO
      IF(nrate > 1 .AND. ifiltr == 0) THEN  
           CALL ancmsg(msgid=1220,
     .                msgtype=msgwarning,
     .                anmode=aninfo_blind_1,
     .                i1=id,
     .                c1=titr)
      ENDIF      
      DO i=1,nrate     
        IF (yfac(i) == zero) yfac(i) = one * yfac_unit(i)
      ENDDO
      rate0 = rate(1)
      DO i=2,nrate     
        IF (rate(i) < rate0) THEN
c         error
        ENDIF
        rate0 = rate(i)
      ENDDO
C----------------
      IF (rhor == zero) rhor=rho0
      pm(1) = rhor
      pm(89)= rho0
C----------------
      uparam(1)=e
      uparam(2)=g
      uparam(3)=nrate
      uparam(4)=ifiltr
      uparam(5)=fcut
      uparam(6)=ecomp*icomp
      uparam(7)=rhoflag
      DO i=1,nrate
        uparam(7+i)=yfac(i)
        uparam(7+nrate+i)=rate(i)
      ENDDO
C----------------
      nuparam = 7 + nrate*2
      nuvar   = 0
C----------------
      parmat(1) = e/three
      parmat(2) = max(e,g)
      parmat(5) = fcut
C----------------
C     Formulation for solid elements time step computation.
!!      G= HALF*E/(ONE + NU)
!!      RBULK = THIRD*E/(ONE - TWO*NU)
      nu = half*e/g  - one
      parmat(16) = 2
      parmat(17) =  (one - two*nu)/(one - nu)
C-----------
      israte = 1
      mtag%G_GAMA=9
      mtag%G_EPSD=1
      mtag%G_EINS=2
      mtag%L_EPE =3
      mtag%L_PLA =2
C-----------------------  
      ! MATPARAM keyword
      CALL init_mat_keyword(matparam,"HOOK")
c
      ! Properties compatibility       
      CALL init_mat_keyword(matparam,"SOLID_COHESIVE") 
C-----------------------  
      WRITE(iout,1010) trim(titr),id,59  
      WRITE(iout,1000)          
      IF (is_encrypted)THEN                                     
        WRITE(iout,'(5X,A,//)')'CONFIDENTIAL DATA'
      ELSE        
        WRITE(iout,1100)rho0                                            
        WRITE(iout,1002) e,ecomp,g,icomp,rhoflag,nrate      
        IF (nrate > 0) THEN                                                   
          WRITE(iout,1001)ifiltr,fcut
          WRITE(iout,1200)(rate(j),ifunn(j),ifunt(j),yfac(j),j=1,nrate)
        ENDIF                                                  
      ENDIF
C-----------        
      RETURN
C-----------
 1000 FORMAT(
     & 5x,40h  connection material law 59            ,/,
     & 5x,40h  --------------------------            ,//)
 1010 FORMAT(/
     & 5x,a,/,
     & 5x,'MATERIAL NUMBER. . . . . . . . . . . . . . . . .=',i10/,
     & 5x,'MATERIAL LAW . . . . . . . . . . . . . . . . . .=',i10/)
 1002 FORMAT(     
     & 5x,'YOUNG MODULUS PER THICKNESS UNIT IN TENSION     =',1pg20.13/,
     & 5x,'YOUNG MODULUS PER THICKNESS UNIT IN COMPRESSION =',1pg20.13/,
     & 5x,'SHEAR MODULUS PER THICKNESS UNIT . . . .        =',1pg20.13/,
     & 5x,'LINEAR BEHAVIOUR IN COMPRESSION (FLAG) . . . . .=',i10/,
     & 5x,'DENSITY UNIT FLAG . . . . . . . . . . . . . .   =',i10/,
     & 5x,'             = 0 => VOLUME  DENSITY              '/,
     & 5x,'             = 1 => SURFACE DENSITY              '/,
     & 5x,'NUMBER OF YIELD(STRAIN RATE) FUNCTIONS .        =',i10/)
 1001 FORMAT(
     & 5x,'STRAIN RATE FILTERING FLAG . . . . . . . . .    =',i10/,
     & 5x,'CUT FREQ FOR STRAIN RATE FILTERING . . . . .    =',1pg20.13/)
 1100 FORMAT(
     & 5x,'INITIAL DENSITY . . . . . . . . . . . . . . . . =',1pg20.13/)  
 1200 FORMAT(
     & 5x,'STRAIN RATE . . . . . . . . . . . . . .         =',1pg20.13/,
     &10x,'YIELD STRESS FUNCTION IN NORMAL DIRECTION  .    =',i10/,
     &10x,'YIELD STRESS FUNCTION IN TANGENT DIRECTION .    =',i10/,
     &10x,'SCALE FACTOR. . . . . . . . . . . . . .         =',1pg20.13)
C--------
 
      END SUBROUTINE hm_read_mat59